1 Тема от Hydrogenium (изменено: ypppu, 2013-07-10 17:21:44)

  • Hydrogenium
  • Участник
  • Неактивен

Тема: CMD/BAT: Как игнорировать файлы при удалении?

Удаляю файлы так: 

del /f /q *.cfg

как мне удалить все файлы *.cfg, но не удалять файлы 1.cfg, 2.cfg, 3.cfg

2 Ответ от shiz

  • shiz
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

Как то так (для пакетного файла "%" надо удвоить):

for %i in (*.cfg) do if not "%~ni"=="1" if not "%~ni"=="2" if not "%~ni"=="3" del /f /q "%~i"
Забыл пароль и потерял e-mail.

3 Ответ от Hydrogenium (изменено: Hydrogenium, 2013-07-10 10:55:35)

  • Hydrogenium
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

shiz пишет:
for %i in (*.cfg) do if not "%~ni"=="1" if not "%~ni"=="2" if not "%~ni"=="3" del /f /q "%~i"

добавил строку в *.bat
чё-то не фурычит
))

4 Ответ от shiz

  • shiz
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

shiz пишет:

(для пакетного файла "%" надо удвоить)

Забыл пароль и потерял e-mail.

5 Ответ от alexii

  • alexii
  • Разработчик
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

Ekklesiast пишет:

добавил строку в *.bat

чё-то не фурычит

«Подымите мне очи…»:

shiz пишет:

для пакетного файла "%" надо удвоить

6 Ответ от Hydrogenium

  • Hydrogenium
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

спасиб ))

7 Ответ от ypppu

  • ypppu
  • Разработчик
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

Ekklesiast, напишите заголовок темы по-русски.

Правила  Поиск  Русский язык  Слова-паразиты
AHK: [ENG] [RUS]

8 Ответ от Hydrogenium (изменено: Hydrogenium, 2013-07-10 13:38:54)

  • Hydrogenium
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

del

9 Ответ от rost

  • rost
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

добрый день!
если задание изменим: удалить все файлы *.cfg, кроме самого "старого" *.cfg
как теперь будет выглядеть батник?

10 Ответ от shiz (изменено: shiz, 2013-07-13 16:51:04)

  • shiz
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

rost, попробуйте на свой страх и риск:

for /f "skip=1 delims=" %%i in ('dir /b /o:-d *.cfg') do del "%%~i"
Забыл пароль и потерял e-mail.

11 Ответ от rost (изменено: rost, 2013-07-13 19:44:27)

  • rost
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

зачет

12 Ответ от Smitis

  • Smitis
  • Разработчик
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

Ещё способ исключить файлы при удалении - поставить исключаемым файлам атрибуты скрытый и/или системный в любой комбинации командой attrib. После команды del снять атрибуты.
Можно наоборот - удаляемым файлам поставить нужные атрибуты, а в команде del использовать ключ /a

13 Ответ от Hydrogenium (изменено: Hydrogenium, 2013-12-29 20:36:58)

  • Hydrogenium
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

След. задача:

Есть папка, мне там нужно удалить все файлы кроме файлов с расширением *.cfg и *.txt
Также нужна возможность задавать переменный путь и маски (*.cfg и *.txt), типа так:


set FILEMASK= *.cfg and *.txt
set FILEPATH= 1

for %%i in ('dir /b /s "%FILEPATH%\*.*"') do if not "%%~ni"==%FILEMASK% del /f /q "%%~i"

Подскажите как сделать

14 Ответ от wisgest

  • wisgest
  • Разработчик
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

После проверки замени ECHO на DEL:

set "FILEMASK=.*\.cfg$ .*\.txt$"
set "FILEPATH=P:\subdir"

pushd "%FILEPATH%"
for /f "delims=" %%i in ('dir /a:-d /b^|findstr /v /i "%FILEMASK%"') do echo "%%i"
popd
http://wisgest.name

15 Ответ от Hydrogenium (изменено: Hydrogenium, 2013-12-30 00:44:37)

  • Hydrogenium
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

wisgest, Спасиб



След. задача:


set "FILEMASK=.*\a3dapi.dll$"
set "FILEMASK=%FILEMASK% .*\voice_tweak.exe$"
set "FILEMASK=%FILEMASK% .*\Mssv12.asi$"
set "FILEMASK=%FILEMASK% .*\.wad$"
set "FILEPATH=1"
pushd "%FILEPATH%"
for /f "delims=" %%i in ('dir /a:-d /b^|findstr /v /i "%FILEMASK%"') do del /f /q /a "%%i"
popd

Как-то неудобно сделал список игнорируемых файлов (их будет штук 20)  в столбик.

Хотелось бы как-то так:


set "FILEMASK=
.*\a3dapi.dll$
.*\voice_tweak.exe$
.*\Mssv12.asi$
.*\.wad$"

Заранее огромное спасибо.

16 Ответ от wisgest (изменено: wisgest, 2013-12-30 03:20:34)

  • wisgest
  • Разработчик
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

Ekklesiast пишет:

Хотелось бы как-то так:

Это элементарно:

set FILEMASK=^
.*\a3dapi.dll$ ^
.*\voice_tweak.exe$ ^
.*\Mssv12.asi$ ^
.*\.wad$

Только что-то меня берёт сомнение, правильно ли в данном случае составлен шаблон для FINDSTR.
По-моему, должно быть так (не проверял):

set FILEMASK=^
^^a3dapi\.dll$ ^
^^voice_tweak\.exe$ ^
^^Mssv12\.asi$ ^
.*\.wad$

~~~~~~~~~~~~~~~~~~~~
По поводу последнего примера до правки:

Ekklesiast пишет:

для удобства надо как-то разместить список игнорируемых файлов в столбик, т.к. в строчку оч. неудобно.

for %%i in (bin\*.cfg) do ^
  if not "%%~ni"=="auto" ^
  if not "%%~ni"=="config" ^
  if not "%%~ni"=="default" ^
  if not "%%~ni"=="lang" ^
  if not "%%~ni"=="listen" ^
  if not "%%~ni"=="server" ^
  if not "%%~ni"=="skill" ^
  if not "%%~ni"=="violence" ^
    del /f /q "%%~i"

setlocal enabledelayedexpansion
set IF=auto\config\default\lang\listen\server\skill\violence
set IF=\%IF:\=" \%"
set IF=!IF:\=if not "%%~ni"=="!
for %%i in (bin\*.cfg) do %IF% del /f /q "%%~i"

setlocal enabledelayedexpansion
set IF=auto^
\config^
\default^
\lang^
\listen^
\server^
\skill^
\violence
set IF=\%IF:\=" \%"
set IF=!IF:\=if not "%%~ni"=="!
for %%i in (bin\*.cfg) do %IF% del /f /q "%%~i"

(В двух последних примерах исправил «*» на «bin\*.cfg».)

http://wisgest.name

17 Ответ от Hydrogenium (изменено: Hydrogenium, 2013-12-30 01:28:27)

  • Hydrogenium
  • Участник
  • Неактивен

Re: CMD/BAT: Как игнорировать файлы при удалении?

wisgest, спасиб