VBScript: Как отформатировать текстовый файл в нужный формат

Option Explicit

Const ForReading   = 1

Dim objFSO
Dim objRegExp

Dim strValue
Dim strOrganization
Dim strAddress


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(WScript.Arguments.Item(0)) Then
    Set objRegExp = WScript.CreateObject("VBScript.RegExp")
    
    objRegExp.IgnoreCase = True
    
    With objFSO.OpenTextFile(WScript.Arguments.Item(0), ForReading)
        Do Until .AtEndOfStream
            strValue = .ReadLine()
            
            If Len(strValue) <> 0 Then
                strOrganization   = strValue
                objRegExp.Pattern = "\d{6}.*"
                
                Do
                    strValue = .ReadLine()
                    
                    If objRegExp.Test(strValue) Then
                        Exit Do
                    Else
                        strOrganization = strOrganization & " " & strValue
                    End If
                Loop
                
                strAddress        = strValue
                objRegExp.Pattern = "Руководителю"
                
                Do
                    strValue = .ReadLine()
                    
                    If objRegExp.Test(strValue) Then
                        Exit Do
                    Else
                        strAddress = strAddress & " " & strValue
                    End If
                Loop
                
                WScript.Echo _
                    strOrganization & vbCrLf & _
                    strAddress & vbCrLf & _
                    strValue
            Else
                WScript.Echo
            End If
        Loop
    End With
    
    Set objRegExp = Nothing
Else
    WScript.Echo "File [" & WScript.Arguments.Item(0) & "] not found"
End If

Set objFSO = Nothing

WScript.Quit 0

cscript.exe "E:\Песочница\0067\Script.vbs" "E:\Песочница\0067\In.txt" >"E:\Песочница\0067\Out.txt"