AHK: "Затемнение" Рабочего Стола

Indomito, было бы проще, если бы написал, какие цели преследуешь сим действием, а то возникает ряд вопросов:
- Нужно ли затемнить только рабочий стол с иконками, виджетами или окна открытых программ тоже.
- Разрешено ли взаимодействие с запущенными приложениями.
Возможны еще вопросы по мере конкретизации темы.
Вот пример скрипта, затемняющего все и блокирующего взаимодействие с запущенными программами.
F12 - вкл/выкл, Escape - выход

Gui +LastFound +AlwaysOnTop -Caption +ToolWindow
Gui, Color, 0
WinSet, Transparent, 200
Gui, Show, x0 y0 NoActivate W%A_ScreenWidth% H%A_ScreenHeight%
return

Esc:: ExitApp
F12::
   s := s = "Hide" ? "Show" : "Hide"
   Gui, %s%
return

Не вижу никаких проблем:

Gui +LastFound +AlwaysOnTop -Caption +ToolWindow
Gui, Color, 0
WinSet, Transparent, 200
Gui, Show, x0 y0 NoActivate W%A_ScreenWidth% H%A_ScreenHeight%
RunWait, choice.ahk
ExitApp

Вместо choice.ahk - имя твоего скрипта.

Этот вариант позволит обойтись без лишних скриптов:

Gui Gray:New, +LastFound +AlwaysOnTop -Caption +ToolWindow +HwndMyGuiHwnd
Gui, Gray:Default
Gui , Color, 0
WinSet, Transparent, 200
Gui, Show, x0 y0 NoActivate W%A_ScreenWidth% H%A_ScreenHeight%
Gui, Default
Gui, New , -caption +AlwaysOnTop  ;,Windows 7
Gui, Margin , 0, 0 ; без caption
Gui, Add, Picture, x0 y0 w750 h563 , C:\AHK\IMG\Fon_s_knopkami.png ;C:\AHK\IMG\Fon_s_dyrkami.png
;Gui, Color, EEAA99 ;  background color Example values: Silver, FFFFAA, 0xFFFFAA, Default
Gui, Show, xCenter yCenter
return
GuiClose:
GuiEscape:
ExitApp

Можно и так, лишь бы выполняло свою задачу

Из справки:
Label [v1.0.44.09+]: Sets custom names for this window's special labels. For example, Gui MyGui:+LabelMyGui_On would use the labels MyGui_OnClose and MyGui_OnSize (if they exist) instead of MyGuiGuiClose and MyGuiGuiSize. In other words, the string "MyGuiGui" is replaced by "MyGui_On" in the names of all special labels. This can also be used to make multiple windows share the same set of labels (in which case the script may consult A_Gui to determine which window launched the subroutine).

Офф: Коллега, будь точен в составлении названия темы и написании вопроса, ибо правильно заданный вопрос - это уже половина ответа.
Набранный в поисковике запрос "Затемнение рабочего стола" привел меня на форум Дельфи, где пост про полупрозрачную форму без контролов на весь экран и сподвиг на данный скрипт. Вряд ли "притухание рабочего стола" даст хоть одну вменяемую ссылку

В скрипте

Gui Gray:New, +LastFound +AlwaysOnTop -Caption +ToolWindow +HwndMyGuiHwnd
Gui, Gray:Default
Gui , Color, 0
WinSet, Transparent, 200
Gui, Show, x0 y0 NoActivate W%A_ScreenWidth% H%A_ScreenHeight%
Gui, Default
Gui, New , -caption +AlwaysOnTop  ;,Windows 7
Gui, Margin , 0, 0 ; без caption
Gui, Add, Picture, x0 y0 w750 h563 , C:\AHK\IMG\Fon_s_knopkami.png ;C:\AHK\IMG\Fon_s_dyrkami.png
;Gui, Color, EEAA99 ;  background color Example values: Silver, FFFFAA, 0xFFFFAA, Default
Gui, Show, xCenter yCenter
return
GuiClose:
GuiEscape:
ExitApp

есть неточность/баг - клик мышкой вне окна блокирует всё, т.е. и окно запроса помогает только снятие задачи через диспетчер.
Есть простой метод ограничить мышку пределами окна?
Конечно это можно сделать через проверку, но как я помню это можно реализовать через модальность, только я не уверен что я прав.

Сенкс, сейчас проверим.

Всё ОК, только меня смущает вот что

Lbutton::
   MouseGetPos,,,OutputVarWin
   if (MyFocus = OutputVarWin)
   Click
return

Какая "область видимости" для Lbutton::? Не хотелось что бы возникли коллизии по нажатию на ЛКМ.

Я понимаю что она сработает по условию, но может стоит её объявить на время действия/существования окна через HotKey, а потом через тот же HotKey перевести в состояние Off ?

Я лучше выберу первое

+ надо и ПКМ дописывать - такая жа ситуация.

Правда можно по таймеру переводить это окно в активное.

B ещё я посмотрел реализацию этой функции в TLB (от куда и позаимствовал идею). Так там это окно можно обойти если по Alt-Tab переключится на полноэкранное приложение, скажем на игрушку, а на остальное не переключается даже по тому же Alt-Tab.
Может быть это внутрисистемная функция?

Как вариант, пойдет. Разве что при зажатии Alt+Tab проскакивает-таки выбор окон. Но на это и внимания можно не обращать.
А можно и... обратить. После Gui, New , +OwnDialogs -caption +AlwaysOnTop +HwndMyFocus , %vWinName%    вставить

Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *!Tab, TabPressed

а в конце скрипта

TabPressed:
return

(Хотя эту метку можно поставить перед любым return)

Чтоб не мигало, можно таким же способом "укротить" все клавиши мыши:

Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *!Tab, TabPressed
Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *LButton, LBpressed
Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *XButton1, TabPressed
Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *XButton2, TabPressed
Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *MButton, TabPressed
Hotkey, IfWinExist, ahk_id %MyFocus%
Hotkey, *RButton, TabPressed
...
...
LBpressed:
   MouseGetPos,,,OutputVarWin
   if (MyFocus = OutputVarWin)
   Click
return

Насчет своих хоткеев... Не знаю, единственное, что приходит на ум - завести флаг при показе Gui, например
NoKeys  := 1, а первой строкой в своих хоткеях прописать

if NoKeys
return

Естесственно, после того как Gui отработает, пишем
NoKeys  := 0

Так он и включается в одном месте - перед показом затемненного окна

На мой взгляд, без разницы - окно уже создано и имеет id, только невидимо. Конечно, если между New и Show есть большой (по времени) кусок кода,
предполагающий работу с блокированными клавишами, то лучше после Show

Нет конечно, они имеют все стандартную проверку, вот например:

FireFox:
if (fnWinClose(arrayKey[fnRetIndexOfHotkey(A_ThisHotkey),cAhkC_WinT]))
  return
Run, %ProgSysPath32%Mozilla Firefox\firefox.exe
return

один if стоит, ну а где один там и второй будет... скоро придётся функцию писать (для обощения)

Или просто дополнить этот IF

FireFox:
if (fnWinClose(arrayKey[fnRetIndexOfHotkey(A_ThisHotkey),cAhkC_WinT]) and NoKeys )
  return
Run, %ProgSysPath32%Mozilla Firefox\firefox.exe
return

аналогично

ShortCircuit
Если «настроиться» на правильный лад, неочевидность отсутствует