1 Тема от Gabe_#33

  • Gabe_#33
  • Участник
  • Неактивен

Тема: AHK: Вывод на экран значения переменной

Есть скрипт

SetTimer,AUTOaD,20
Return

AUTOaD:
{
	Global a4c1

 WinGet, BF2, id, BF2
 DllCall("GetWindowThreadProcessId" , "int", BF2
 , "UInt *", PID
 , "UInt") 

 ProcessHandle := DllCall("OpenProcess" , "int", 2035711
 , "char", 3
 , "UInt", PID
 , "UInt") 
 
 	SetFormat, Integer, H

 DllCall("ReadProcessMemory" , "UInt", ProcessHandle
 , "UInt", 0x009903F0
 , "Uint*", a4c1
 , "Uint", 8
 , "Uint*", 0)

  DllCall("CloseHandle" , "int", ProcessHandle)
}
Return

Как сделать так что бы значение переменной - "a4c1" выводилось на экран?
Что бы фон окна был прозрачным и было только содержимое переменной.
Шрифт,размер текста и цвет что бы можно было настраивать.
И главно что бы оно было поверх всех окон.

2 Ответ от Irbis

  • Irbis
  • Разработчик
  • Неактивен

Re: AHK: Вывод на экран значения переменной

Из справки  AHK_L:

CustomColor = EEAA99  ; Can be any RGB color (it will be made transparent below).
Gui +LastFound +AlwaysOnTop -Caption +ToolWindow  ; +ToolWindow avoids a taskbar button and an alt-tab menu item.
Gui, Color, %CustomColor%
Gui, Font, s32  ; Set a large font size (32-point).
Gui, Add, Text, vMyText cLime, XXXXX YYYYY  ; XX & YY serve to auto-size the window.
; Make all pixels of this color transparent and make the text itself translucent (150):
WinSet, TransColor, %CustomColor% 150
SetTimer, UpdateOSD, 200
Gosub, UpdateOSD  ; Make the first update immediate rather than waiting for the timer.
Gui, Show, x0 y400 NoActivate  ; NoActivate avoids deactivating the currently active window.
return

UpdateOSD:
MouseGetPos, MouseX, MouseY
GuiControl,, MyText, X%MouseX%, Y%MouseY%
return
Feci quod potui faciant meliora potentes

3 Ответ от Gabe_#33

  • Gabe_#33
  • Участник
  • Неактивен

Re: AHK: Вывод на экран значения переменной

Огромное спасибки.
Никогда не приходилось работать с "GUI".Думаю ещё возникнет масса вопросов на этот счёт;)