AHK: Оповещение о завершении синхронизации Google Drive (Страница 1) — AutoHotkey — Общение

1 Тема от becauseim 2016-03-28 12:06:56

becauseim
Участник
Неактивен

Рейтинг : [2|0]

Тема: AHK: Оповещение о завершении синхронизации Google Drive

#SingleInstance Force
DetectHiddenWindows, On
SetTitleMatchMode 2

ControlGetText, SyncStatus, wxWindowNR16, ahk_exe googledrivesync.exe 

Loop
{
if (SyncStatus = "Sync complete")
{
	MsgBox Sync Complete!
	return
}
}
return

По задумке, должно выходить оповещающее сообщение о завершении синхронизации файлов посредством клиента Google Drive. В таком виде не работает. Исправьте, пожалуйста.

2 Ответ от mafckz 2016-03-28 12:57:02 (изменено: mafckz, 2016-03-28 13:16:52)

mafckz
Участник
Неактивен

Рейтинг : [12|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

С помощью библиотеки TrayIcon.ahk (https://autohotkey.com/boards/viewtopic.php?t=1229) можно получить Tip-cooбщение иконки, а там как раз и пишется статус синхронизации.

Вот скрипт с добавленным в конце кодом библиотеки

#SingleInstance Force

#Persistent
SetTimer checkSync, 10000  ; милисекунды

checkSync:
Icons := TrayIcon_GetInfo()
Loop, % Icons.MaxIndex()
    if (Icons[A_Index].process = "googledrivesync.exe")
        if (InStr(Icons[A_Index].tooltip, "Sync complete") || InStr(Icons[A_Index].tooltip, "Синхронизация завершена"))
            MsgBox Sync Complete! Синхронизация завершена!
return



;// ниже идет сама библиотека

; ----------------------------------------------------------------------------
TrayIcon_GetInfo(sExeName:="") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On   

    oTrayInfo := Object()
	For key, sTrayP in ["Shell_TrayWnd", "NotifyIconOverflowWindow"]
    {	
        idxTB := TrayIcon_GetTrayBar()
        WinGet, pidTaskbar, PID, ahk_class %sTrayP%

        hProc := DllCall( "OpenProcess",    UInt,0x38, Int,0, UInt,pidTaskbar                       )
        pRB   := DllCall( "VirtualAllocEx", Ptr,hProc, Ptr,0, UInt,20,        UInt,0x1000, UInt,0x4 )

        szBtn := VarSetCapacity( btn, (A_Is64bitOS) ? 32 : 24, 0 )
        szNfo := VarSetCapacity( nfo, (A_Is64bitOS) ? 32 : 24, 0 )
        szTip := VarSetCapacity( tip, 128 * 2,                 0 )

        SendMessage, 0x418, 0, 0, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_BUTTONCOUNT
        Loop, %ErrorLevel%
        {
            SendMessage, 0x417, A_Index - 1, pRB, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_GETBUTTON

            DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,pRB, Ptr,&btn, UInt,szBtn, UInt,0 )

            iBitmap	:= NumGet( btn, 0                       )
            idCmd   := NumGet( btn, 4                       )
            Statyle := NumGet( btn, 8                       )
            dwData	:= NumGet( btn, (A_Is64bitOS) ? 16 : 12 )
            iString	:= NumGet( btn, (A_Is64bitOS) ? 24 : 16 )

            DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,dwData, Ptr,&nfo, UInt,szNfo, UInt,0 )

            hWnd  := NumGet( nfo, 0                       )
            uID	  := NumGet( nfo, (A_Is64bitOS) ? 8  : 4  )
            nMsg  := NumGet( nfo, (A_Is64bitOS) ? 12 : 8  )
            hIcon := NumGet( nfo, (A_Is64bitOS) ? 24 : 20 )

            WinGet,      pid,      PID,         ahk_id %hWnd%
            WinGet,      sProcess, ProcessName, ahk_id %hWnd%
            WinGetClass, sClass,                ahk_id %hWnd%

            If ( !sExeName || (sExeName == sProcess) || (sExeName == pid) )
                DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,iString, Ptr,&tip, UInt,szTip, UInt,0 )
              , oTrayInfo.Insert({ "idx": A_Index-1, "idcmd": idCmd, "pid": pid, "uid": uID, "msgid": nMsg
                                 , "hicon": hIcon, "hwnd": hWnd, "class": sClass, "process": sProcess
                                 , "tooltip": StrGet(&tip, "UTF-16"), "place": sTrayP })
        }
        
        DllCall( "VirtualFreeEx", Ptr,hProc, Ptr,pRB, UInt,0, UInt,0x8000 )
        DllCall( "CloseHandle",   Ptr,hProc                               )
	}
	DetectHiddenWindows, %d%
	Return oTrayInfo
}

TrayIcon_Hide(idCmd, sTrayP:="Shell_TrayWnd", bHide:=True) {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x404, idCmd, bHide, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_HIDEBUTTON
	SendMessage, 0x1A, 0, 0, , ahk_class %sTrayP%
    DetectHiddenWindows, %d%
}

TrayIcon_Remove(hWnd, uID) {
	sz := VarSetCapacity( NID, (A_PtrSize == 4) ? 832 : 848, 0 )
	NumPut( sz, NID, 0 ), NumPut( hWnd, NID, A_PtrSize ), NumPut( uID, NID, A_PtrSize*2 )
	DllCall( "Shell32.dll\Shell_NotifyIcon", UInt,2, Ptr,&NID )
}

TrayIcon_Delete(idx, sTrayP:="Shell_TrayWnd") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x416, idx, 0, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_DELETEBUTTON
	SendMessage, 0x1A, 0, 0, , ahk_class %sTrayP%
	DetectHiddenWindows, %d%
}

TrayIcon_Move(idxOld, idxNew, sTrayP:="Shell_TrayWnd") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x452, idxOld, idxNew, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_MOVEBUTTON
    DetectHiddenWindows, %d%
}

TrayIcon_GetTrayBar() {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	WinGet, ControlList, ControlList, ahk_class Shell_TrayWnd
	RegExMatch(ControlList, "(?<=ToolbarWindow32)\d+(?!.*ToolbarWindow32)", nTB)

	Loop, %nTB%
	{
		ControlGet, hWnd, hWnd,, ToolbarWindow32%A_Index%, ahk_class Shell_TrayWnd
		hParent := DllCall( "GetParent", Ptr,hWnd )
		WinGetClass, sClass, ahk_id %hParent%
		If (sClass <> "SysPager")
			Continue
		idxTB := A_Index
			Break
	}
	
	DetectHiddenWindows, %d%
	Return	idxTB
}

TrayIcon_GetHotItem() {
   idxTB := TrayIcon_GetTrayBar()
   SendMessage, 0x447, 0, 0, ToolbarWindow32%idxTB%, ahk_class Shell_TrayWnd ; TB_GETHOTITEM
   Return ErrorLevel << 32 >> 32
}

3 Ответ от becauseim 2016-03-28 13:08:31

becauseim
Участник
Неактивен

Рейтинг : [2|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

mafckz, Спасибо, работает! Т.е. без трей-сообщения нельзя получить информацию из клиента Google Drive?

Если можно, добавьте, пожалуйста, положение, при котором состояние будет проверяться циклично, т.е. чтобы сообщение выходило после каждого отдельно синхронизированного файла, а не только после запуска скрипта.

4 Ответ от mafckz 2016-03-28 13:19:24 (изменено: mafckz, 2016-03-28 13:27:18)

mafckz
Участник
Неактивен

Рейтинг : [12|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

becauseim пишет:

Если можно, добавьте, пожалуйста, положение, при котором состояние будет проверяться циклично, т.е. чтобы сообщение выходило после каждого отдельно синхронизированного файла, а не только после запуска скрипта.

После каждого файла - без понятия как сделать. Добавил интервал проверки состояния через 10 секунд.

------
Только, если сделать проверку каждые N миллисекунд, отслеживать когда статус изменится на "синхронизация" (т.е. новые объекты начали синхронизироваться) - после этого ждать статуса "Синхронизация завершена" - и тогда выводить сообщение. Но это как-то некрасиво совсем.

5 Ответ от mafckz 2016-03-28 13:57:30

mafckz
Участник
Неактивен

Рейтинг : [12|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

Написал с интервалом проверки 100 милисекунд. За работоспособность и возможные глюки не отвечаю
Все-таки, такую задачу нужно решать по-другому.

#SingleInstance Force
sync := false

#Persistent
SetTimer checkSync, 100  ; милисекунды

checkSync:
googleDrive := TrayIcon_GetInfo("googledrivesync.exe")
if (InStr(googleDrive[1].tooltip, "Sync complete") || InStr(googleDrive[1].tooltip, "Синхронизация завершена"))
{
	if sync
	{
		SetTimer checkSync, off
		sync := false
		
		MsgBox Sync Complete! Синхронизация завершена!
		
		SetTimer checkSync, on
	}
}
else
	sync := true
return


;// ниже идет сама библиотека

; ----------------------------------------------------------------------------
TrayIcon_GetInfo(sExeName:="") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On   

    oTrayInfo := Object()
	For key, sTrayP in ["Shell_TrayWnd", "NotifyIconOverflowWindow"]
    {	
        idxTB := TrayIcon_GetTrayBar()
        WinGet, pidTaskbar, PID, ahk_class %sTrayP%

        hProc := DllCall( "OpenProcess",    UInt,0x38, Int,0, UInt,pidTaskbar                       )
        pRB   := DllCall( "VirtualAllocEx", Ptr,hProc, Ptr,0, UInt,20,        UInt,0x1000, UInt,0x4 )

        szBtn := VarSetCapacity( btn, (A_Is64bitOS) ? 32 : 24, 0 )
        szNfo := VarSetCapacity( nfo, (A_Is64bitOS) ? 32 : 24, 0 )
        szTip := VarSetCapacity( tip, 128 * 2,                 0 )

        SendMessage, 0x418, 0, 0, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_BUTTONCOUNT
        Loop, %ErrorLevel%
        {
            SendMessage, 0x417, A_Index - 1, pRB, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_GETBUTTON

            DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,pRB, Ptr,&btn, UInt,szBtn, UInt,0 )

            iBitmap	:= NumGet( btn, 0                       )
            idCmd   := NumGet( btn, 4                       )
            Statyle := NumGet( btn, 8                       )
            dwData	:= NumGet( btn, (A_Is64bitOS) ? 16 : 12 )
            iString	:= NumGet( btn, (A_Is64bitOS) ? 24 : 16 )

            DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,dwData, Ptr,&nfo, UInt,szNfo, UInt,0 )

            hWnd  := NumGet( nfo, 0                       )
            uID	  := NumGet( nfo, (A_Is64bitOS) ? 8  : 4  )
            nMsg  := NumGet( nfo, (A_Is64bitOS) ? 12 : 8  )
            hIcon := NumGet( nfo, (A_Is64bitOS) ? 24 : 20 )

            WinGet,      pid,      PID,         ahk_id %hWnd%
            WinGet,      sProcess, ProcessName, ahk_id %hWnd%
            WinGetClass, sClass,                ahk_id %hWnd%

            If ( !sExeName || (sExeName == sProcess) || (sExeName == pid) )
                DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,iString, Ptr,&tip, UInt,szTip, UInt,0 )
              , oTrayInfo.Insert({ "idx": A_Index-1, "idcmd": idCmd, "pid": pid, "uid": uID, "msgid": nMsg
                                 , "hicon": hIcon, "hwnd": hWnd, "class": sClass, "process": sProcess
                                 , "tooltip": StrGet(&tip, "UTF-16"), "place": sTrayP })
        }
        
        DllCall( "VirtualFreeEx", Ptr,hProc, Ptr,pRB, UInt,0, UInt,0x8000 )
        DllCall( "CloseHandle",   Ptr,hProc                               )
	}
	DetectHiddenWindows, %d%
	Return oTrayInfo
}

TrayIcon_Hide(idCmd, sTrayP:="Shell_TrayWnd", bHide:=True) {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x404, idCmd, bHide, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_HIDEBUTTON
	SendMessage, 0x1A, 0, 0, , ahk_class %sTrayP%
    DetectHiddenWindows, %d%
}

TrayIcon_Remove(hWnd, uID) {
	sz := VarSetCapacity( NID, (A_PtrSize == 4) ? 832 : 848, 0 )
	NumPut( sz, NID, 0 ), NumPut( hWnd, NID, A_PtrSize ), NumPut( uID, NID, A_PtrSize*2 )
	DllCall( "Shell32.dll\Shell_NotifyIcon", UInt,2, Ptr,&NID )
}

TrayIcon_Delete(idx, sTrayP:="Shell_TrayWnd") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x416, idx, 0, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_DELETEBUTTON
	SendMessage, 0x1A, 0, 0, , ahk_class %sTrayP%
	DetectHiddenWindows, %d%
}

TrayIcon_Move(idxOld, idxNew, sTrayP:="Shell_TrayWnd") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x452, idxOld, idxNew, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_MOVEBUTTON
    DetectHiddenWindows, %d%
}

TrayIcon_GetTrayBar() {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	WinGet, ControlList, ControlList, ahk_class Shell_TrayWnd
	RegExMatch(ControlList, "(?<=ToolbarWindow32)\d+(?!.*ToolbarWindow32)", nTB)

	Loop, %nTB%
	{
		ControlGet, hWnd, hWnd,, ToolbarWindow32%A_Index%, ahk_class Shell_TrayWnd
		hParent := DllCall( "GetParent", Ptr,hWnd )
		WinGetClass, sClass, ahk_id %hParent%
		If (sClass <> "SysPager")
			Continue
		idxTB := A_Index
			Break
	}
	
	DetectHiddenWindows, %d%
	Return	idxTB
}

TrayIcon_GetHotItem() {
   idxTB := TrayIcon_GetTrayBar()
   SendMessage, 0x447, 0, 0, ToolbarWindow32%idxTB%, ahk_class Shell_TrayWnd ; TB_GETHOTITEM
   Return ErrorLevel << 32 >> 32
}

+ becauseim

6 Ответ от becauseim 2016-03-28 20:59:52

becauseim
Участник
Неактивен

Рейтинг : [2|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

mafckz, спасибо! Но если, как Вы упомянули, это не самый верный способ решения данной задачи, то как подразумевается её верное решение? Думал, что при интервальной проверке сообщение будет выходить при каждой перезагрузке скрипта, однако, как и задумывалось, выходит только после момента синхронизации файлов. Думаю, это то, что мне нужно.

7 Ответ от becauseim 2016-03-28 21:03:43

becauseim
Участник
Неактивен

Рейтинг : [2|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

А можно ли установить проверку лишь на тот случай, если фалы синхронизировались как минимум пять минут? Оповещение о синхронизации, например, текстового файла, что происходит мгновенно, как оказалось, мне ни к чему.

8 Ответ от Malcev 2016-03-29 02:54:27 (изменено: Malcev, 2016-03-29 02:56:22)

Malcev
Разработчик
Неактивен

Рейтинг : [609|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

Конечно было бы замечательно если бы кто-то написал враппер Гугловского Api для Ahk.
Есть утилитка, можешь ее покопать:
https://github.com/prasmussen/gdrive
Кстати в первом коде ошибка.
Правильно, наверное, так - проверить не могу.

#SingleInstance Force
DetectHiddenWindows, On
SetTitleMatchMode 2

Loop
{
   ControlGetText, SyncStatus, wxWindowNR16, ahk_exe googledrivesync.exe 
   if (SyncStatus = "Sync complete")
   {
	   MsgBox Sync Complete!
       return
   }
   sleep 50
}

9 Ответ от mafckz 2016-03-29 19:37:08 (изменено: mafckz, 2016-03-29 19:38:30)

mafckz
Участник
Неактивен

Рейтинг : [12|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

becauseim пишет:

А можно ли установить проверку лишь на тот случай, если фалы синхронизировались как минимум пять минут?

#SingleInstance Force

syncTime := 10000  ; время синхронизации в милисекундах, больше которого выводить сообщение
sync := false

#Persistent
SetTimer checkSync, 100  ; милисекунды

checkSync:
googleDrive := TrayIcon_GetInfo("googledrivesync.exe")
if (InStr(googleDrive[1].tooltip, "Sync complete") || InStr(googleDrive[1].tooltip, "Синхронизация завершена"))
{
	if sync
	{
		sync := false
		if ( (A_TickCount - StartTime) > syncTime )
		{
			SetTimer checkSync, off
			
			MsgBox Sync Complete! Синхронизация завершена!
			
			SetTimer checkSync, on
		}
	}
}
else
{
	if !sync
	{
		sync := true
		StartTime := A_TickCount
	}
}
return


;// ниже идет сама библиотека

; ----------------------------------------------------------------------------
TrayIcon_GetInfo(sExeName:="") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On   

    oTrayInfo := Object()
	For key, sTrayP in ["Shell_TrayWnd", "NotifyIconOverflowWindow"]
    {	
        idxTB := TrayIcon_GetTrayBar()
        WinGet, pidTaskbar, PID, ahk_class %sTrayP%

        hProc := DllCall( "OpenProcess",    UInt,0x38, Int,0, UInt,pidTaskbar                       )
        pRB   := DllCall( "VirtualAllocEx", Ptr,hProc, Ptr,0, UInt,20,        UInt,0x1000, UInt,0x4 )

        szBtn := VarSetCapacity( btn, (A_Is64bitOS) ? 32 : 24, 0 )
        szNfo := VarSetCapacity( nfo, (A_Is64bitOS) ? 32 : 24, 0 )
        szTip := VarSetCapacity( tip, 128 * 2,                 0 )

        SendMessage, 0x418, 0, 0, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_BUTTONCOUNT
        Loop, %ErrorLevel%
        {
            SendMessage, 0x417, A_Index - 1, pRB, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_GETBUTTON

            DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,pRB, Ptr,&btn, UInt,szBtn, UInt,0 )

            iBitmap	:= NumGet( btn, 0                       )
            idCmd   := NumGet( btn, 4                       )
            Statyle := NumGet( btn, 8                       )
            dwData	:= NumGet( btn, (A_Is64bitOS) ? 16 : 12 )
            iString	:= NumGet( btn, (A_Is64bitOS) ? 24 : 16 )

            DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,dwData, Ptr,&nfo, UInt,szNfo, UInt,0 )

            hWnd  := NumGet( nfo, 0                       )
            uID	  := NumGet( nfo, (A_Is64bitOS) ? 8  : 4  )
            nMsg  := NumGet( nfo, (A_Is64bitOS) ? 12 : 8  )
            hIcon := NumGet( nfo, (A_Is64bitOS) ? 24 : 20 )

            WinGet,      pid,      PID,         ahk_id %hWnd%
            WinGet,      sProcess, ProcessName, ahk_id %hWnd%
            WinGetClass, sClass,                ahk_id %hWnd%

            If ( !sExeName || (sExeName == sProcess) || (sExeName == pid) )
                DllCall( "ReadProcessMemory", Ptr,hProc, Ptr,iString, Ptr,&tip, UInt,szTip, UInt,0 )
              , oTrayInfo.Insert({ "idx": A_Index-1, "idcmd": idCmd, "pid": pid, "uid": uID, "msgid": nMsg
                                 , "hicon": hIcon, "hwnd": hWnd, "class": sClass, "process": sProcess
                                 , "tooltip": StrGet(&tip, "UTF-16"), "place": sTrayP })
        }
        
        DllCall( "VirtualFreeEx", Ptr,hProc, Ptr,pRB, UInt,0, UInt,0x8000 )
        DllCall( "CloseHandle",   Ptr,hProc                               )
	}
	DetectHiddenWindows, %d%
	Return oTrayInfo
}

TrayIcon_Hide(idCmd, sTrayP:="Shell_TrayWnd", bHide:=True) {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x404, idCmd, bHide, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_HIDEBUTTON
	SendMessage, 0x1A, 0, 0, , ahk_class %sTrayP%
    DetectHiddenWindows, %d%
}

TrayIcon_Remove(hWnd, uID) {
	sz := VarSetCapacity( NID, (A_PtrSize == 4) ? 832 : 848, 0 )
	NumPut( sz, NID, 0 ), NumPut( hWnd, NID, A_PtrSize ), NumPut( uID, NID, A_PtrSize*2 )
	DllCall( "Shell32.dll\Shell_NotifyIcon", UInt,2, Ptr,&NID )
}

TrayIcon_Delete(idx, sTrayP:="Shell_TrayWnd") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x416, idx, 0, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_DELETEBUTTON
	SendMessage, 0x1A, 0, 0, , ahk_class %sTrayP%
	DetectHiddenWindows, %d%
}

TrayIcon_Move(idxOld, idxNew, sTrayP:="Shell_TrayWnd") {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	idxTB := TrayIcon_GetTrayBar()
	SendMessage, 0x452, idxOld, idxNew, ToolbarWindow32%idxTB%, ahk_class %sTrayP% ; TB_MOVEBUTTON
    DetectHiddenWindows, %d%
}

TrayIcon_GetTrayBar() {
    d := A_DetectHiddenWindows
	DetectHiddenWindows, On
	WinGet, ControlList, ControlList, ahk_class Shell_TrayWnd
	RegExMatch(ControlList, "(?<=ToolbarWindow32)\d+(?!.*ToolbarWindow32)", nTB)

	Loop, %nTB%
	{
		ControlGet, hWnd, hWnd,, ToolbarWindow32%A_Index%, ahk_class Shell_TrayWnd
		hParent := DllCall( "GetParent", Ptr,hWnd )
		WinGetClass, sClass, ahk_id %hParent%
		If (sClass <> "SysPager")
			Continue
		idxTB := A_Index
			Break
	}
	
	DetectHiddenWindows, %d%
	Return	idxTB
}

TrayIcon_GetHotItem() {
   idxTB := TrayIcon_GetTrayBar()
   SendMessage, 0x447, 0, 0, ToolbarWindow32%idxTB%, ahk_class Shell_TrayWnd ; TB_GETHOTITEM
   Return ErrorLevel << 32 >> 32
}

Malcev пишет:

Правильно, наверное, так - проверить не могу.

Проблема в том, что код:

ControlGetText, SyncStatus, wxWindowNR16, ahk_exe googledrivesync.exe

помещает в переменную SyncStatus либо пустую строку, либо "panel", а не статус синхронизации.

+ becauseim

10 Ответ от becauseim 2016-12-20 05:24:42

becauseim
Участник
Неактивен

Рейтинг : [2|0]

Re: AHK: Оповещение о завершении синхронизации Google Drive

Подскажите, пожалуйста, как правильно добавить в checkSync из последнего сценария от mafckz перечисление нескольких различных клиентов (программ) и соответствующих сообщений для них? Например, "Yandex.Disk: Synced" для YandexDisk.exe. Спасибо!

AHK: Оповещение о завершении синхронизации Google Drive

Сообщения 10

1 Тема от becauseim 2016-03-28 12:06:56

Тема: AHK: Оповещение о завершении синхронизации Google Drive

2 Ответ от mafckz 2016-03-28 12:57:02 (изменено: mafckz, 2016-03-28 13:16:52)

Re: AHK: Оповещение о завершении синхронизации Google Drive

3 Ответ от becauseim 2016-03-28 13:08:31

Re: AHK: Оповещение о завершении синхронизации Google Drive

4 Ответ от mafckz 2016-03-28 13:19:24 (изменено: mafckz, 2016-03-28 13:27:18)

Re: AHK: Оповещение о завершении синхронизации Google Drive

5 Ответ от mafckz 2016-03-28 13:57:30

Re: AHK: Оповещение о завершении синхронизации Google Drive

6 Ответ от becauseim 2016-03-28 20:59:52

Re: AHK: Оповещение о завершении синхронизации Google Drive

7 Ответ от becauseim 2016-03-28 21:03:43

Re: AHK: Оповещение о завершении синхронизации Google Drive

8 Ответ от Malcev 2016-03-29 02:54:27 (изменено: Malcev, 2016-03-29 02:56:22)

Re: AHK: Оповещение о завершении синхронизации Google Drive

9 Ответ от mafckz 2016-03-29 19:37:08 (изменено: mafckz, 2016-03-29 19:38:30)

Re: AHK: Оповещение о завершении синхронизации Google Drive

10 Ответ от becauseim 2016-12-20 05:24:42

Re: AHK: Оповещение о завершении синхронизации Google Drive

Сообщения 10