VBS\JS: лог печати - как сделать?

Dim objWMI, objCollection, objItem, lngNumEvents
Dim strMsg, intPosL, intPosR, strOwner, intPages
Dim dtmEventDate, dtmFirstDate, dtmLastDate
Dim objDict, objFS, objFile
Const strComputer = "здесь - DNS-имя станции, журнал которой анализируется"
Const strResFile = "C:\Temp\Results.txt"
dtmFirstDate = DateValue("01.05.2008")
dtmLastDate = DateValue("28.05.2008")
Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set objCollection = objWMI.ExecQuery("SELECT * FROM Win32_NTLogEvent WHERE Logfile='System' " & _
    "AND EventType=3 AND SourceName='Print' AND EventCode=10")
lngNumEvents = objCollection.Count
If lngNumEvents > 0 Then
    Wscript.Echo "Найдено событий указанного вида: " & lngNumEvents
    Set objDict = CreateObject("Scripting.Dictionary")
    objDict.CompareMode = 1
    For Each objItem In objCollection
        dtmEventDate = Date_Convert(CStr(objItem.TimeWritten))
        If dtmFirstDate <= dtmEventDate And dtmEventDate <= dtmLastDate Then
            strMsg = objItem.Message
            intPosL = InStr(1, strMsg, "владельца", vbTextCompare)
            intPosR = InStr(1, strMsg, "напечатан", vbTextCompare)
            strOwner = Mid(strMsg, intPosL + 10, intPosR - intPosL - 11)
            intPosL = InStrRev(strMsg, ":")
            intPages = CInt(Mid(strMsg, intPosL + 2))
            If objDict.Exists(strOwner) Then
                objDict.Item(strOwner) = objDict.Item(strOwner) + intPages
            Else
                objDict.Add strOwner, intPages
            End If
        End If
    Next
    Set objFS = CreateObject("Scripting.FileSystemObject")
    Set objFile = objFS.CreateTextFile(strResFile, True)
    For Each objItem In objDict.Keys
        objFile.WriteLine (objItem & " = " & objDict.Item(objItem))
    Next
    objFile.Close
    Set objFile = Nothing
    objDict.RemoveAll
    Set objDict = Nothing
    Wscript.Echo "Готово."
Else
    Wscript.Echo "Событий указанного вида в журнале не обнаружено."
End If
Set objCollection = Nothing
Set objWMI = Nothing

Function Date_Convert(strDTM)
Date_Convert = DateValue(Mid(strDTM, 7, 2) & "." & Mid(strDTM, 5, 2) & "." & Mid(strDTM, 1, 4))
End Function

Set objNetwork = CreateObject("Wscript.Network")
CompName = objNetwork.ComputerName
          
strComputer = "."
Set objFSO = CreateObject("Scripting.FileSystemObject")
Const ForAppending = 8

' даём принтеру установку, чтобы он сохранял задания для логирования скриптом
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colInstalledPrinters = objWMIService.ExecQuery("Select * from Win32_Printer")
For Each objPrinter in colInstalledPrinters
If Left(objPrinter.DeviceID,3)="OKI" then
PrinterID=objPrinter.DeviceID
objPrinter.KeepPrintedJobs = True
objPrinter.Put_
End if
Next

'отменяем все задания
Set colInstalledPrinters = objWMIService.ExecQuery("Select * from Win32_Printer")
For Each objPrinter in colInstalledPrinters
objPrinter.CancelAllJobs()
Next

'удаляем все задания
Set colPrintJobs = objWMIService.ExecQuery("Select * from Win32_PrintJob")
For Each objPrintJob in colPrintJobs 
objPrintJob.Delete_
Next

' ну и мониторим каждые 60 сек события о печати :-)
Set colPrintJobs = objWMIService.ExecNotificationQuery("select * from __InstanceCreationEvent Within 60 where TargetInstance isa 'Win32_PrintJob' and TargetInstance.JobStatus='Напечатано'")
Do While True
    Set objPrintJob = colPrintJobs.NextEvent
    If InStr(objPrintJob.TargetInstance.Name, PrinterID)<>0 Then 
        docname=objPrintJob.TargetInstance.Document
        size=objPrintJob.TargetInstance.Size
        owner=objPrintJob.TargetInstance.Owner
        jobstamp=WMIDateToString(objPrintJob.TargetInstance.TimeSubmitted)
        pages=objPrintJob.TargetInstance.TotalPages
        On error resume next
        Set LogFile = objFSO.OpenTextFile("\\192.168.42.90\Pubs\PM\" & CompName & "_Print.Log", ForAppending, True)
        LogFile.WriteLine Owner & "   " & jobstamp & "   " & docname & "   " & size & "   " & pages
        LogFile.Close
        On error goto 0
    End If
Loop 


Function WMIDateToString(dtmDate)

WMIDateToString = CDate(Mid(dtmDate, 5, 2) & "/" & _
                  Mid(dtmDate, 7, 2) & "/" & _
                  Left(dtmDate, 4) & "   " & _
                  Mid(dtmDate, 9, 2) & ":" & _
                  Mid(dtmDate, 11, 2) & ":" & _
                  Mid(dtmDate, 13, 2))

End Function

 ...
ll = intPosL
rr = intPosR
            strOwner = Mid(strMsg, intPosL + 10, intPosR - intPosL - 11)
 ...           
Wscript.Echo ll
Wscript.Echo rr
    Wscript.Echo "Готово."