Вы не вошли. Пожалуйста, войдите или зарегистрируйтесь.
Страницы 1
Чтобы отправить ответ, вы должны войти или зарегистрироваться
Доброй ночи. Прошу вашей помощи.
Как можно получить и считать содержимое манифеста в файле если он есть как это делает Resource Hacker?
У скомпилированных ахк скриптов есть манифест. Хотелось бы считать содержимое манифеста любого скомпилированого ахк скрипта.
Я так понял что надо копать в сторону функций FindResource, но поиск привел меня только к извлечению иконок.
Вот так можно:
File = D:\Temp\Hello.exe
hFile := DllCall("LoadLibraryEx", "str", File, "ptr", 0, "uint", 2, "ptr")
hRsrc := DllCall("FindResource", "ptr", hFile, "ptr", 1, "ptr", 24, "ptr")
hData := DllCall("LoadResource", "ptr", hFile, "ptr", hRsrc, "ptr")
pData := DllCall("LockResource", "ptr", hData, "ptr")
Manifest := StrGet(pData, "cp0")
DllCall("FreeLibrary", "ptr", hFile)
MsgBox, %Manifest%
Спасибо большое!
Помогите! Скрипт крашит, тоесть просто так сам процесс убивается когда пытается прочитать манифест кое-какого файла. Манифест там есть так как Resource Hacker спокойно видит его.
Крашит из-за этой строчки:
Manifest := StrGet(pData, "cp0")Пробывал словить ошибку, но не помогает:
File = D:\setup.exe
hFile := DllCall("LoadLibraryEx", "str", File, "ptr", 0, "uint", 2, "ptr")
hRsrc := DllCall("FindResource", "ptr", hFile, "ptr", 1, "ptr", 24, "ptr")
hData := DllCall("LoadResource", "ptr", hFile, "ptr", hRsrc, "ptr")
pData := DllCall("LockResource", "ptr", hData, "ptr")
try {
Manifest := StrGet(pData, "cp0") ; Крашит из-за этого
} catch e {
msgbox, error
}
DllCall("FreeLibrary", "ptr", hFile)
MsgBox, %Manifest%Вот сам файл:
https://www.dropbox.com/s/5r5wqtgdje68t … p.exe?dl=0
В вашем файле 0 байт.
В вашем файле 0 байт.
Очень странно, но у гугл диска проблема с этим файлом.
Обновил ссылку
https://www.dropbox.com/s/5r5wqtgdje68t … p.exe?dl=0
Да, малость недоработал код. Надо размер ресурса узнавать, иначе StrGet залазит дальше положенного.
File = D:\setup.exe
hFile := DllCall("LoadLibraryEx", "str", File, "ptr", 0, "uint", 2, "ptr")
hRsrc := DllCall("FindResource", "ptr", hFile, "ptr", 1, "ptr", 24, "ptr")
hData := DllCall("LoadResource", "ptr", hFile, "ptr", hRsrc, "ptr")
pData := DllCall("LockResource", "ptr", hData, "ptr")
cbData := DllCall("SizeofResource", "ptr", hFile, "ptr", hRsrc)
Manifest := StrGet(pData, cbData, "cp0")
DllCall("FreeLibrary", "ptr", hFile)
MsgBox, %Manifest%
Спасибо. Все работает.
Страницы 1
Чтобы отправить ответ, вы должны войти или зарегистрироваться
