Вообще-то частично есть:
<span class="time" data-tz="Europe/Moscow" data-format="%H:%i:%s">20:42</span>
Секунд нет.
На этом сайте есть API, можно так получить:
MsgBox, % GetTimeFromTime100ru(3, "HH:mm:ss")
GetTimeFromTime100ru(localTimeOffset := 0, formatString := "") {
static url := "https://time100.ru/api.php"
unixTime := GetResponseText(url,,,, error)
if error
throw error
Return UnixTimeToLocal(unixTime, localTimeOffset, formatString)
}
GetResponseText(url, method := "GET", HeadersArray := "", body := "", ByRef error := "") {
Whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
Whr.Open(method, url, true)
for name, value in HeadersArray
Whr.SetRequestHeader(name, value)
Whr.Send(body)
Whr.WaitForResponse()
status := Whr.status
if (status != 200)
error := "HttpRequest error, status: " . status
Arr := Whr.responseBody
pData := NumGet(ComObjValue(arr) + 8 + A_PtrSize)
length := arr.MaxIndex() + 1
Return StrGet(pData, length, "UTF-8")
}
UnixTimeToLocal(unixTime, diff, formatStr := "") {
time := "19700101"
time += unixTime, s
time += diff, h
if formatStr
FormatTime, time, % time, % formatStr
Return time
}
Но это API возвращает UTC время, чтобы преобразовать в локальное, нужно знать, на сколько оно отличается. Московское это +3 часа (если нет перехода на зимнее-летнее время).
Если на компьютере верно указана time zone, то можно так узнать разницу:
localTimeOffset := A_Now
localTimeOffset -= A_NowUTC, h
MsgBox, % localTimeOffset
Разработка AHK-скриптов:
e-mail
dfiveg@mail.ruTelegram
jollycoder