AHK: Создание QRCode

len := QrGenerator("https://forum.script-coding.com/", pngData, 200)
FileOpen(A_ScriptDir . "\qr.png", "w").RawWrite(pngData, len)
Gui, Margin, 0, 0
Gui, Add, Pic,, % A_ScriptDir . "\qr.png"
Gui, Show
Return

GuiClose() {
   ExitApp
}

QrGenerator(text, ByRef pngData, qrSizePix := 300, correctionLevel := "M") {
; correctionLevel: L, M, Q, H
   static url := "https://chart.googleapis.com/chart?cht=qr"
   completeUrl := url . "&chl=" . EncodeDecodeURI(text) . "&chs=" . qrSizePix . "&chld=" . correctionLevel
   dataLen := WebRequest(completeUrl, pngData,,,, error := "")
   if (error != "")
      throw error
   Return dataLen
}

EncodeDecodeURI(str, encode := true, component := true) {
   static Doc, JS
   if !Doc {
      Doc := ComObjCreate("htmlfile")
      Doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
      JS := Doc.parentWindow
      ( Doc.documentMode < 9 && JS.execScript() )
   }
   Return JS[ (encode ? "en" : "de") . "codeURI" . (component ? "Component" : "") ](str)
}

WebRequest(url, ByRef data, method := "GET", HeadersArray := "", body := "", ByRef error := "") {
   Whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
   Whr.Open(method, url, true)
   for name, value in HeadersArray
      Whr.SetRequestHeader(name, value)
   Whr.Send(body)
   Whr.WaitForResponse()
   status := Whr.status
   if (status != 200)
      error := "HttpRequest error, status: " . status
   Arr := Whr.responseBody
   pData := NumGet(ComObjValue(arr) + 8 + A_PtrSize)
   length := Arr.MaxIndex() + 1
   VarSetCapacity(data, length, 0)
   DllCall("RtlMoveMemory", "Ptr", &data, "Ptr", pData, "Ptr", length)
   Return length
}

MsgBox, % CONVERT_TO_BYTE_ENCODING("тест")

CONVERT_TO_BYTE_ENCODING(MESSAGE_TO_ENCODE) {
   Loop, parse, MESSAGE_TO_ENCODE
   {
      code := Asc(A_LoopField)
      MESSAGE_STRING .= Format("{:016}", ToBin(code))
   }
   Return MESSAGE_STRING
}

ToBin(Number)
{
   While Number
      bin := (Number&1 ? 1 : 0) . bin, Number >>= 1
   Return bin
}