1 (изменено: eric-cartmanez, 2022-10-31 16:47:51)

Тема: AHK: Чтение всплывающей подсказки (title)

При наведении курсора мыши на какой-нибудь элемент, под курсором всплывает подсказка. Как с помощью AHK прочитать и сохранить в переменную эту подсказку? С помощью AhkSpy эту информацию можно получить, но я не смог разобраться как она там вычитывается.
https://i.ibb.co/Gp2swPv/image.png

2

Re: AHK: Чтение всплывающей подсказки (title)

Попробуйте так:

F11::
   if !AccObj := AccObjectFromPoint(child)
      throw "Failed to get accessible object from point"
   MsgBox, % AccObj.accHelp(child)
   Return
   
AccObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
   static VT_DISPATCH := 9, F_OWNVALUE := 1, h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
   
   AccObject := 0
   (x = "" || y = "") ? DllCall("GetCursorPos", "Int64P", pt) : pt := x & 0xFFFFFFFF | y << 32
   VarSetCapacity(varChild, 8 + 2*A_PtrSize, 0)
   if	DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "PtrP", pAcc, "Ptr", &varChild) = 0
      _idChild_ := NumGet(varChild, 8, "UInt"), AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
   Return AccObject
}
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

3

Re: AHK: Чтение всплывающей подсказки (title)

teadrinker
Да, именно то что мне необходимо. Спасибо!