VBScript: Мониторинг открытых потров TCP/UDP

Option Explicit
If WScript.Arguments.Count<>1 Then
    Wscript.Echo "обязательный параметр : Удаленный Хост / IP"
    WScript.Quit
End If

Dim K,P
If right(Ucase(WScript.FullName),11)="WSCRIPT.EXE" Then
    Set K=CreateObject("WScript.Shell")
    K.Run K.ExpandEnvironmentStrings("%COMSPEC%") & " /C cscript.exe """ & WScript.ScriptFullName & """ " & WScript.Arguments(0),1,False
    Set K=Nothing
    WScript.Quit
End If

Set K=I()

L "Сканирование портов запущено на " & K.LocalHostName & " (" & K.LocalIP & ")"

K.RemoteHost=WScript.Arguments(0)
For P=25 To 111
    K.RemotePort=P
    K.Connect
    While K.State<>0
        wscript.sleep 90
    Wend
Next
L "Финиш!"

Function I()
    On Error Resume Next
    Err.Number=0
    Set I=WScript.CreateObject("MSWinsock.Winsock","s_")
    Select Case Err.Number
    Case 0
    case &H80040112
        L "нет лицензии, нужно добавить в реестр значение для регистрации винсок: " &_
        "http://social.msdn.microsoft.com/Forums/en-US/Vsexpressvcs/thread/8dd70eb9-b377-4ef6-b75d-a0fc0e9a9b5e"
    case &H80020009
        L "ActiveX Winsock не зарегестрирован - юзай regsvr32"
    Case else
        L "Error " & Err.Number & " - &H" & Hex(Err.Number) & " - " & Err.Description
    End Select
End Function

Sub L(S):WScript.Echo S:End Sub

Sub s_Connect
    K.Close
    L "порт " & P & " Открыт !"
End Sub
Sub s_Error(ByVal N,D,c,S,F,H,A)
    K.Close
    If N=10061 Then
        WScript.StdOut.Write "."
    Else
        L P & ":" & N & " " & D
    End If
End Sub