WSH: Нужен скрипт для копирования файлов

InitialFolder = "C:\Job" ' каталог, откуда копируем
TargetFolder = "C:\Temp\Temp" ' каталог, куда копируем
ControlDate = CDate("01.08.2006") ' контрольная дата (копируем файлы с датой создания раньше этой)
'====================================================================
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShellApp = CreateObject("Shell.Application")
CopyFiles InitialFolder

' процедура рекурсивно перебирает файлы в каталоге
Sub CopyFiles(FolderPath)
    Set objFolderItems = objShellApp.NameSpace(FolderPath).Items()
    For Each objFolderItem In objFolderItems
        If objFolderItem.IsFolder And LCase(Right(objFolderItem.Name, 4)) <> ".zip" Then
            CopyFiles objFolderItem.Path
        Else
            Set objFile = objFSO.GetFile(objFolderItem.Path)
            If objFile.DateCreated < ControlDate Then
                CopyFile objFolderItem.Path
            End If
        End If
    Next
End Sub

' процедура копирует файл
Sub CopyFile(FilePath)
    SubPath = Mid(FilePath, Len(InitialFolder) + 1)
    TargetPath = TargetFolder & SubPath
    FolderPath = objFSO.GetParentFolderName(TargetPath)
    If Not objFSO.FolderExists(FolderPath) Then
        CreateFolder FolderPath
    End If
    objFSO.CopyFile FilePath, TargetPath, True
End Sub

' процедура создаёт каталог
Sub CreateFolder (FolderPath)
    ParentFolder = objFSO.GetParentFolderName(FolderPath)
    If Not objFSO.FolderExists(ParentFolder) Then
        CreateFolder ParentFolder
    End If
    objFSO.CreateFolder FolderPath
End Sub

InitialFolder = "C:\Job" ' каталог, откуда копируем
TargetFolder = "C:\Temp\Temp" ' каталог, куда копируем
ControlDate = CDate("01.08.2006") ' контрольная дата (копируем файлы с датой создания раньше этой)
'====================================================================
On Error Resume Next
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShellApp = CreateObject("Shell.Application")
LogPath = objFSO.GetParentFolderName(WScript.ScriptFullName)
Set LogStream = objFSO.OpenTextFile(LogPath & "\CopyLog.log", 8, True)
LogStream.WriteLine "Начало копирования " & Now()

CopyFiles InitialFolder
LogStream.WriteLine "Конец копирования: " & Now()
LogStream.Close

' процедура рекурсивно перебирает файлы в каталоге
Sub CopyFiles(FolderPath)
    On Error Resume Next
    Set objFolderItems = objShellApp.NameSpace(FolderPath).Items()
    For Each objFolderItem In objFolderItems
        If objFolderItem.IsFolder And LCase(Right(objFolderItem.Name, 4)) <> ".zip" Then
            CopyFiles objFolderItem.Path
        Else
            Set objFile = objFSO.GetFile(objFolderItem.Path)
            If objFile.DateCreated < ControlDate Then
                CopyFile objFolderItem.Path
            End If
        End If
    Next
End Sub

' процедура копирует файл
Sub CopyFile(FilePath)
    On Error Resume Next
    SubPath = Mid(FilePath, Len(InitialFolder) + 1)
    TargetPath = TargetFolder & SubPath
    FolderPath = objFSO.GetParentFolderName(TargetPath)
    If Not objFSO.FolderExists(FolderPath) Then
        CreateFolder FolderPath
    End If
    ' если у файла назначения есть атрибут ReadOnly, снимаем его
    If objFSO.FileExists(TargetPath) Then
        Set objFile = objFSO.GetFile(TargetPath)
        If objFile.Attributes And 1 Then
            objFile.Attributes = objFile.Attributes - 1
        End If
    End If
    objFSO.CopyFile FilePath, TargetPath, True
    If Err.Number <> 0 Then
        LogStream.WriteLine
        LogStream.WriteLine FilePath
        LogStream.WriteLine Err.Description
        LogStream.WriteLine
        Err.Clear
    Else
        LogStream.WriteLine TargetPath
    End If
End Sub

' процедура создаёт каталог
Sub CreateFolder (FolderPath)
    On Error Resume Next
    ParentFolder = objFSO.GetParentFolderName(FolderPath)
    If Not objFSO.FolderExists(ParentFolder) Then
        CreateFolder ParentFolder
    End If
    objFSO.CreateFolder FolderPath
End Sub

Set WshShell = CreateObject("WScript.Shell")
WshShell.Run "командная строка вызова архиватора", 0, True

LogStream.Close

InitialFolder = "C:\1" ' каталог, откуда удаляем
ControlDate = Now-3 ' контрольная дата (удаляет файлы с датой создания раньше этой)

'====================================================================
On Error Resume Next
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShellApp = CreateObject("Shell.Application")
LogPath = objFSO.GetParentFolderName(WScript.ScriptFullName)
Set LogStream = objFSO.OpenTextFile(LogPath & "\CopyLog.log", 8, True)
LogStream.WriteLine "Начало удаления " & Now()

DelFiles InitialFolder
LogStream.WriteLine "Конец удаления: " & Now()
LogStream.WriteLine
LogStream.Close

' процедура рекурсивно перебирает файлы в каталоге удаляя их
Sub DelFiles(FolderPath)
    On Error Resume Next
    Set objFolderItems = objShellApp.NameSpace(FolderPath).Items()
    For Each objFolderItem In objFolderItems
        If objFolderItem.IsFolder And LCase(Right(objFolderItem.Name, 4)) <> ".zip" Then
            DelFiles objFolderItem.Path
        Else
            Set objFile = objFSO.GetFile(objFolderItem.Path)
            If objFile.DateCreated < ControlDate Then
                LogStream.WriteLine "Был удалён файл: " & objFolderItem.Path
                objFile.Delete true
            End If
        End If
    Next
End Sub

Option Explicit

'=======================================================
Sub ClearSubFolders(objFolder)
    Dim objSubFolder
    Dim objFile

    For Each objSubFolder In objFolder.SubFolders
        ClearSubFolders objSubFolder
    Next

    For Each objFile In objFolder.Files
        If DateDiff("d", objFile.DateCreated, Now()) > 3 Then
            objFile.Delete(True)
        End If
    Next

    If (objFolder.Files.Count = 0) And (objFolder.SubFolders.Count = 0) Then
        If objFolder.Path = strPathToClear Then
        Else
            objFolder.Delete(True)
        End If
    End If
End Sub
'=======================================================

Dim objWshShell

Dim objFS
Dim objFolder

Const strPathToClear = "E:\Для обмена"

Set objFS = WScript.CreateObject("Scripting.FileSystemObject")

ClearSubFolders objFS.GetFolder(strPathToClear)

WScript.Echo Now
WScript.Echo Now - 30

Option Explicit

Public objFSO
Dim objArchiveFolder
Dim objFile

Dim strWorkFolder
Dim strArchiveFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

strWorkFolder = "c:\Temp\001"
strArchiveFolder = strWorkFolder & "\Архив"

If Not objFSO.FolderExists(strArchiveFolder) Then
    objFSO.CreateFolder strArchiveFolder
End If

Set objArchiveFolder = objFSO.GetFolder(strArchiveFolder)

For Each objFile In objFSO.GetFolder(strWorkFolder).Files
    If Age(objFile) > 5 Then
        MoveFileToArchive objFile, objArchiveFolder
    End If
Next

WScript.Quit(0)

'=======================================================================
Function Age(objFile)
    Age = DateDiff("d", objFile.DateCreated, Now())
End Function
'=======================================================================

'=======================================================================
Sub MoveFileToArchive(objFile, objArchiveFolder)
    Dim strSubFolderToMove

    strSubFolderToMove = objArchiveFolder.Path & "\" & Left(objFile.Name, 5)
    
    If Not objFSO.FolderExists(strSubFolderToMove) Then
        objFSO.CreateFolder strSubFolderToMove
    End If

    objFile.Move strSubFolderToMove & "\" & objFile.Name
End Sub
'=======================================================================

Set objRegExp = CreateObject("VBScript.RegExp")
objRegExp.Global = False
objRegExp.Pattern = "\d{5}-\d{2}-\d{2}\..*"
Str = "12345-01-01.xls"
MsgBox objRegExp.Test(Str)
Str = "Копия 12345-01-01.xls"
MsgBox objRegExp.Test(Str)