Вы не вошли. Пожалуйста, войдите или зарегистрируйтесь.
Страницы 1
Чтобы отправить ответ, вы должны войти или зарегистрироваться
Здравствуйте!
Подскажите пожалуйста, как выводить в Msgbox последние 14 строк конкретного Лог-файла? Файл имеет плавающий размер...
Этот лог лежит в опредёлённой папке по одному и тому-же пути. Там он один.
Но у разных пользователей он носит разные имена.
Существует решение на VBScript ?
Задача, как я понимаю, складывается из двух частей:
1. Определить имя единственного файла в заданной папке.
2. Если файл единственный — прочитать последние N строк.
Пункт первый решается обычными методами. Для второго предлагаю использовать LogParser (хоть у него и нет предиката LAST, но всё ж будет быстрее прочего).
Попытка решения на VBScript:
Option Explicit
Const N = 14 'Необходимое количество последних строк
Dim FSO: Set FSO = CreateObject("Scripting.FileSystemObject")
Dim Path
Path = CreateObject("Shell.Application")._
NameSpace("shell:Common Documents\NAME\logs").Self.Path
Dim File, TextStream
For Each File In FSO.GetFolder(Path).Files
If UCase(FSO.GetExtensionName(File.Name)) = "LOG" Then
Set TextStream = File.OpenAsTextStream(1)
Exit For
End If
Next
If IsEmpty(TextStream) Then
MsgBox "Файл *.LOG не найден!"
WScript.Quit 1
End If
ReDim Lines(N - 1)
Dim I: I = 0
While Not TextStream.AtEndOfStream
Lines(I) = TextStream.ReadLine()
I = (I + 1) Mod N
Wend
Dim Message: Message = ""
Dim J
For J = 0 To N - 1
Message = Message & Lines((I + J) Mod N) & vbNewLine
Next
MsgBox Messageshiz, интересное решение. Сами придумали?
alexii
Спасибо, придумал сам, по-моему ничего такого в нём нет.
Ну, почему же, а количество используемой памяти?
2All: у нас было что-либо подобное ранее?
Пример, работающий при условии несовпадения строк:
'==================================================================
' Показать последние N строк в log-файле
' Параметры: "<Путь к папке c log-файлом>" N
'==================================================================
With WScript.Arguments : Path = .Item(0) : N = .Item(1) : End With
L = vbnewline
With CreateObject("Scripting.FileSystemObject")
For Each F In .GetFolder(Path).Files
If StrComp(.GetExtensionName(F), "log", 1) = 0 Then
Set File = .OpenTextFile(Path & .GetFilename(F), 1)
Exit For
End if
Next
End With
Text = File.ReadAll
If InstrRev(Text, L) > 0 Then _
MsgBox Mid(Text, InStrRev(Text, Split(Text, L)(Abs(File.Line) - N) & L))
File.Closealexii
Спасибо, придумал сам, по-моему ничего такого в нём нет.
Очень лаконичное решение прохода по массиву!
Я когда аналогичное решение делал, то получилось очень громоздко - держал дополнительные признаки для обслуживания такого массива, а так как содержимое массива получается из двух "хронологических последовательностей", то и вывод содержимого массива делал за два раза.
Вот, пример моей функции, которая формирует из последних строк опции выбора для HTA-приложения.
' --- формирование списка протокола - gsFileLogPing'
i_aLOG_max = gi_tSetPC_LogLimitMax - 1
ReDim a_LOG( i_aLOG_max )
If fso.FileExists( gsFileLogPing ) Then
Dim fspi, sLine, i, iCnt, i_aLOG_cyrcle, i_aLOG_last, i_aLOG_prev
Set fspi=fso.OpenTextFile(gsFileLogPing, 1)
iCnt = 0 'общее кол-во считанных с файла строк'
i_aLOG_cyrcle = 0 'признак кругового заполнения массива ga_LOG'
i_aLOG_last = -1 'индекс последнего задействованного элемента ga_LOG'
i_aLOG_prev = -1 'индекс предпоследнего залействованного элемента ga_LOG'
Do While not fspi.AtEndOfStream
sLine = Trim( fspi.ReadLine )
iCnt = iCnt + 1
If iCnt>1 Then i_aLOG_prev = i_aLOG_last
If i_aLOG_last + 1 <= i_aLOG_max Then
i_aLOG_last = i_aLOG_last + 1
else 'закручиваем массив по кругу'
i_aLOG_cyrcle = 1
i_aLOG_last = 0
End If
a_LOG (i_aLOG_last) = sLine
Loop
fspi.Close
Set fspi = Nothing
If iCnt > 0 Then
'формирование таблицы протокола'
sLog = "<SELECT >"
sOpt = ""
For i=i_aLOG_last To 0 Step -1
sLine = Trim( a_LOG (i) )
'Формируем из sLine новую позицию'
sOpt = sOpt & "<OPTION>" & sLine & "</OPTION>"
NEXT
If i_aLOG_cyrcle Then
For i=i_aLOG_max-1 To i_aLOG_last+1 Step -1
sLine = a_LOG (i)
'Формируем из sLine новую позицию'
sOpt = sOpt & "<OPTION>" & sLine & "</OPTION>"
NEXT
End If
sLog = sLog & sOpt & "</SELECT>"
End If 'iCnt > 0'
End IF 'fso.FileExists( gsFileLogPing )А Ваша идея красивая! Браво. Мне понравилось.
Задача, как я понимаю, складывается из двух частей:
1. Определить имя единственного файла в заданной папке.
2. Если файл единственный — прочитать последние N строк.Пункт первый решается обычными методами. Для второго предлагаю использовать LogParser (хоть у него и нет предиката LAST, но всё ж будет быстрее прочего).
Попытка решения на VBScript:
Большое спасибо!!
А если в папке единственный .log , но есть файлы с другими расширениями?
Можно-ли как-то привязать работу скрипта к расширению?
Ну по типу к *.log - всё равно Log там один?
Можно-ли как-то привязать работу скрипта к расширению?
В моём скрипте именно так.
Пример, работающий при условии несовпадения строк:
[...]
Я не удержался, чтоб не потестировать) Класс!
Как оказывается поучительно бывает почитать форум
_D_V_S_ пишет:Можно-ли как-то привязать работу скрипта к расширению?
В моём скрипте именно так.
Ваш скрипт с параметрами.
А мне надо "без". Чтобы человек запустил его и увидел MsgBox :-)
А если в папке единственный .log , но есть файлы с другими расширениями?
Используйте:
If StrComp(.GetExtensionName(F), "log", 1) = 0 ThenFlasher пишет:_D_V_S_ пишет:Можно-ли как-то привязать работу скрипта к расширению?
В моём скрипте именно так.
Ваш скрипт с параметрами.
А мне надо "без". Чтобы человек запустил его и увидел MsgBox :-)
Ну, Вы даете)
Вот как я тестировал сей скрипт (замена первой строки)
' With WScript.Arguments : Path = .Item(0) : N = .Item(1) : End With
Path = "c:\R\Develop\last_row_from_log\" : N = 5_D_V_S_ пишет:Flasher пишет:В моём скрипте именно так.
Ваш скрипт с параметрами.
А мне надо "без". Чтобы человек запустил его и увидел MsgBox :-)Ну, Вы даете)
Вот как я тестировал сей скрипт (замена первой строки)' With WScript.Arguments : Path = .Item(0) : N = .Item(1) : End With Path = "c:\R\Develop\last_row_from_log\" : N = 5
Да Вы не допоняли...
Куча людей, у каждого свой лог.
Имена файлов - разные, но находятся они по одному пути.
По этому пути - единственный файл с раширением .log, но могут быть другие файлы с другими расширениями (грубо говоря - лишний мусор).
Эти люди должны просто запустить скрипт и увидеть MsgBox :-)
_D_V_S_ пишет:А если в папке единственный .log , но есть файлы с другими расширениями?
Используйте:
If StrComp(.GetExtensionName(F), "log", 1) = 0 Then
Огромное спасибо!!
Я не удержался, чтоб не потестировать) Класс!
Спасибо. Делал для разминки.)
Ваш скрипт с параметрами.
Параметры как раз создаются для удобства. Комстрока не только в cmd бывает, но и в кнопках тулбаров, ярлыках, что позволяет при одном скрипте иметь несколько вариантов для разных файлов/папок и значений переменных.
2_D_V_S_: Хммм...
Самый первый вариант кода Flasher и так Вас должен полностью удовлетворить.
Людям раздайте батник или ярлык со строкой запуска скрипта, который и будет запускать скрипт, с указанием того самого единственного пути.
Либо вбейте путь в скрипт, как я сделал: Path = "c:\R\Develop\last_row_from_log\" - это у меня тот самый единственный путь...
Не злоупотребляйте цитированием.
А почему не работает в пути
Const PATH = "%CommonDocuments%\NAME\logs"в то время когда
Const PATH = "c:\Users\Public\Documents\NAME\logs"прекрасно работает?
1. Вы уверены, что есть такая переменная окружения? Что говорит:
set CommonDocumentsв командной строке?
2. Если есть, то для использования в WSH её надо развернуть:
Const PATH = "%CommonDocuments%\NAME\logs"
Dim objWshShell
Set objWshShell = WScript.CreateObject("WScript.Shell")
WScript.Echo objWshShell.ExpandEnvironmentStrings(PATH)А вообще: один вопрос — одна тема.
Людям раздайте ... ярлык со строкой запуска скрипта
О чём я и говорю. Положить ярлык рядом со скриптом, в поле "Объект" вписать след. конструкцию:
'%WINDIR%\system32\RunDll32.exe shell32.dll,ShellExec_RunDLL .\ИМЯ_СКРИПТА.vbs c:\Users\Public\Documents\NAME\logs\ 14
Пошукал, погуглил по буржуйским форумам и решил-таки! :-)
Option Explicit
Const COMMONDOCUMENTS = &H2e
Dim objShell : Set objShell = CreateObject("Shell.Application")
Dim objFolder : Set objFolder = objShell.Namespace(COMMONDOCUMENTS)
Dim objFolderItem : Set objFolderItem = objFolder.Self
Wscript.Echo objFolderItem.Path
Dim P1 : P1 = objFolderItem.Path
Const P2 = "\NAME\logs"
Dim PATH : PATH = P1 + P2
Wscript.Echo PATHИ т.д...
Всё работает! :-)
Всем огромное Спасибо за помощь!!
Завтра буду в божеский вид скрипт приводить...
Переменная-то есть (Windows у меня) - но CMD отвечает:
C:\Users\DVS>set CommonDocuments
Переменная среды CommonDocuments не определенаСтранно...
А Ваш скрипт выдаёт кстати:
%CommonDocuments%\NAME\logsНо - моя наработка заработала как надо...
Спасибо ещё раз!!
Переменная-то есть (Windows у меня)
Значит, нет такой переменной окружения, Вы её выдумали 
.
А Ваш скрипт выдаёт кстати:
Естественно: нет переменной — нечего и разворачивать.
Пошукал, погуглил по буржуйским форумам…
Наши тоже не лыком шиты 
: Серый форум / WSH: перечень предопределённых символьных имён Shell.Application. Ваше имя — «shell:Common Documents». Однако же это не переменная окружения.
Одно непонятно - как-же всё-таки прописать, чтобы скрипт работал только с файлом по расширению .log ...
:-(
PS я брал отсюда:
PS Может, если по другому нельзя, перед выполнением основной части скрипта просто удалять лишние файлы из директории?
Не соображу, как использование регулярных выражений привязать к имени и расширению файла.
Я в ступоре :-(
На всякий случай изменил #3 с учётом ".LOG" и "%CommonDocuments%".
На всякий случай изменил #3 с учётом ".LOG" и "%CommonDocuments%".
Огромное спасибо!!
Извиняюсь, внёс ещё одно (косметическое) изменение в #3:
Path = CreateObject("Shell.Application")._
NameSpace("shell:Common Documents\NAME\logs").Self.Pathвместо громоздкого и не вполне корректного:
Path = FSO.BuildPath(_
CreateObject("Shell.Application")._
NameSpace("shell:Common Documents").Self.Path, _
"NAME\logs"_
)Добавил идею в Коллекцию: VBScript: чтение последних N строк текстового файла.
Страницы 1
Чтобы отправить ответ, вы должны войти или зарегистрироваться
