VBScript: Подсчет суммы чисел в колонке файла csv

Option Explicit
Const CsvFile1 = "qwe.csv" 'читаем
Const CsvFile2 = "qwe.txt" 'пишем
Dim fso, arr, i, x, y, newCsvFile

Set fso = CreateObject("Scripting.FileSystemObject")

If Not fso.FileExists(CsvFile1) Then
	MsgBox "Файл " & CsvFile1 & " не найден"
	WScript.Quit
End If

arr = ReadCSV(CsvFile1) 'читаем

For i = 1 To UBound(arr,2) 'считаем
	x = x + CInt(arr(1,i))
	y = y + CInt(arr(2,i))
Next

With fso	
	If Not .FileExists(CsvFile2) Then
		Set newCsvFile = .CreateTextFile(CsvFile2)
		newCsvFile.Close	
	End If
	
	Set newCsvFile = .OpenTextFile(CsvFile2,8)
	With newCsvFile 'пишем
		.WriteLine arr(1,0) & " = " & x
		.WriteLine arr(2,0) & " = " & y		
		.Close
	End With
End With

Function ReadCSV(filePath)	
	Dim dataArray() 
	Dim splitArray 
	Dim i, j 
	i = 0
	With fso.OpenTextFile(filePath) 		
		Do Until .AtEndOfStream 			
			splitArray = Split(.ReadLine, ";")			
			ReDim Preserve dataArray(2, i)		
			For j = 0 To 2
				dataArray(j, i) = splitArray(j)
			Next				
			i = i + 1				
		Loop
		.Close
	End With
	ReadCSV = dataArray
End Function

текст1;текст2;текст3;текст4;текст5;текст6
10.10.3.131;10;11;484;aa;191
10.10.3.131;10;11;347;aa;503
10.10.3.131;10;11;514;aa;210
10.10.3.131;10;11;510;aa;190
10.10.3.131;10;11;347;aa;503
10.10.3.131;10;11;514;aa;210

Option Explicit
Const CsvFile1 = "qwe.csv" 'читаем
Const CsvFile2 = "qwe.txt" 'пишем
Const ColNumber = 5 'количество колонок (от 0)
Dim fso, arr, k, m, n, x, y, newFile
Dim arr2 'массив номеров колонок для счета (от 0)
arr2 = Array(3,5) 'например 3-я и 5-я колонки

Set fso = CreateObject("Scripting.FileSystemObject")

If Not fso.FileExists(CsvFile1) Then
	MsgBox "Файл " & CsvFile1 & " не найден"
	WScript.Quit
End If

arr = ReadCSV(CsvFile1, ColNumber) 'читаем

With fso	
	If Not .FileExists(CsvFile2) Then
		Set newFile = .CreateTextFile(CsvFile2)
		newFile.Close	
	End If
	
	Set newFile = .OpenTextFile(CsvFile2,8)
	With newFile 
		For k = 0 To UBound(arr2)		
			m = 0
			For n = 1 To UBound(arr,2) 'считаем			
				m = m + CInt((arr(arr2(k),n)))
			Next
			.WriteLine arr(arr2(k),0) & " = " & m 'пишем
		Next
		.Close
	End With
End With

Function ReadCSV(filePath, intColNumber)	
	Dim dataArray() 
	Dim splitArray 
	Dim i, j 
	i = 0
	With fso.OpenTextFile(filePath) 		
		Do Until .AtEndOfStream 			
			splitArray = Split(.ReadLine, ";")			
			ReDim Preserve dataArray(intColNumber, i)		
			For j = 0 To intColNumber
				dataArray(j, i) = splitArray(j)
			Next				
			i = i + 1				
		Loop
		.Close
	End With
	ReadCSV = dataArray
End Function

Const ColNumber = 4 'количество колонок (от 0)
arr2 = Array(3,4) 'например 3-я и 5-я колонки