CMD/BAT: ping в txt

Добрый день.

Ковыряй в эту сторону, по хорошему надо организовать цикл и через переменные перебить ip

@echo off
ping -n 2 92.168.1.10 | find "TTL=" > nul
if %errorlevel%==1 echo Ping Propal %date% %time% >> 92.168.1.10.txt

powerwer, ip адреса в одной подсети 192.168.1 или она все время меняеться?

powerwer, так попробуйте запустить под win 2008, не думаю что ping.exe или cmd.exe сильно отличаются от тех что на win 7 Pro.
Не забудьте сюда написать работает или нет.

ping xxx > nul || echo куйня какаято

powerwer, сделайте следующее:
1) переименуйте файл в MyCso.bat
2) скопируйте или перенесите файл MyCso.bat в корень диска d:\ или c:\ диска, главное что бы у Вас были права на запись на этом диске
3) запустите cmd.exe если не знаете как то напишите
4) в командной строке cmd.exe перейдите в папку куда Вы скопировали MyCso.bat
5) и наберите: MySco.bat 192.168.1.10 192.168.1.20
PS:
192.168.1.10 и 192.168.1.20 - это параметры которые передаются батнику в командной строке

MegaScrew ты ваааащеее молодец, круто. РЕСПЕКТ!!!! 

Как показал себя этот исходник.
Он сканировал под сеть "1", хоть есть или нет ping или нет он создавал отчет каждому ip подробно и сканировал только один раз и программа завершился.
заработал, все отлично, у кого был пинг во вложении txt файла написал пинг появился у кого нет то пинг пропал, есть одно "НО" этот код типа сканирует только один раз выбранную под сеть так? а как сделать чтоб он постоянно сканировал чтоб при отсутствии или появления сети сразу же добавил в отчет типа чтоб он всегда был на процессе чтоб можно было смотреть когда пропал сеть и когда появился....
И еще можно ли создать отчет по папкам с именем даты. пример папка с именем 01-08-2012 а внутри его все эти текстовые отчеты за 1-е августа и т.д.
Можно ли сделать так? 

Вот новый код с учетом твоих пожеланий:
1) отчеты в папке с именем 01-08-2012
2) после запуска батник работает по циклу, пока не нажмешь CTRL+C
3) после проверки всех IP адресов выдерживается пауза от 1 до 60 секунд.
Длину паузы указываешь сам при запуске батника MySco.bat 192.168.1.10 192.168.1.20 10

@echo off
rem подсеть IP которую проверяем берем из первого параметра батника
    set ipset=%~n1
    set tochka=.

rem временная переменная
    set k=%~x1

rem с какого IP начинать проверять         
    set a=%k:~1,3%

rem на каком IP заканчивать проверку
    set k=%~x2
    set b=%k:~1,3%

:cikl
    for /l %%i in (%a%,1,%b%) do ( call :pingtest %ipset%%tochka%%%i% )
    call :sleep %~3
    goto cikl

rem ################################################################
:pingtest
setlocal
    set mydir=%date:~0,2%-%date:~3,2%-%date:~6,4%
    if not exist %mydir% ( mkdir %mydir% )

    ping.exe -n 1 -w 1000 %~1 | find "TTL=" > nul
        if %errorlevel%==1 (
            echo Ping Propal %date% %time% >> %mydir%/%~1.txt
        ) else (
            echo Ping Poyavilsa %date% %time% >> %mydir%/%~1.txt
            )
endlocal
exit /b 0
rem ################################################################

rem ################################################################
:sleep
setlocal
    if %time:~5,2% EQU :0 (set /a ftime=%time:~7,-3%+%1 ) else ( set /a ftime=%time:~6,-3%+%1 )
    if %ftime% GEQ 60 set /a ftime-=60
    :loop
     if %time:~5,2% EQU :0 (set /a ctime=%time:~7,-3% ) else ( set /a ctime=%time:~6,-3% )
        if /i %ftime% NEQ %ctime% goto :loop
endlocal
exit /b 0
rem ################################################################

:exit