AHK : двойной клик и около.

Двойной клик это два последовательных клика с длительностью паузы менее определённого значения.
«Перехватить» двойной клик нельзя, можно заблокировать лишь второй клик из двух.
Если у «этого» клика нет определяемых с помощью ahk признаков, то выявить именно «этот» клик из множества «других» двойных кликов по окну нужной программы не выйдет (очевидно )

MultiClick(numClick, clickTimeout)
{
    static clickCount, priorHotKey, priorTickCount
    b := (clickCount := (A_ThisHotkey == priorHotKey && A_TickCount-priorTickCount <= clickTimeout)? clickCount+1 : 0) = numClick-1
    , priorHotKey := A_ThisHotkey, priorTickCount := A_TickCount
    return b
}

#if WinActive("ahk_class CabinetWClass") && MultiClick(2, 300)
    ~LButton::SoundBeep ; при «двойном клике» в окне проводника раздастся звуковой сигнал.
#if

Только проверку добавить, равны ли имена текущей и предыдущей горячей клавиши

А вот в таком случае проверка A_TimeSincePriorHotkey <> -1 не требуется, потому как когда A_TimeSincePriorHotkey = -1 — A_ThisHotkey <> A_PriorHotkey.

А теперь это условие можно завернуть в функцию, назвать её DoubleClick и использовать везде где нужно (за исключением директивы #if)

~LButton::
If DoubleClick(400)
    MsgBox You double clicked on something
Return

DoubleClick(clickTimeout)
{
    return A_TimeSincePriorHotkey<clickTimeout and A_ThisHotkey = A_PriorHotkey
}

Или

#if DoubleClick(400)
    ~LButton::MsgBox You double clicked on something
#if

DoubleClick(clickTimeout)
{
    static doubleClick, priorHotKey, priorTickCount
    doubleClick := (A_ThisHotkey == priorHotKey && !doubleClick && A_TickCount-priorTickCount <= clickTimeout)
    , priorHotKey := A_ThisHotkey, priorTickCount := A_TickCount
    return doubleClick
}

  Во-первых - спасибо!
Во вторых,  очень познавательно, но "меня терзают смутные сомнения", что это совсем не тот язык  о котором я спрашивал.
По крайней мере я практически не могу понять где тут операторы, где переменные, а где ...классы(?),  методы(?)
Ну - это ладно. Не всем же понимать.

Но хоть скажите, как это в код встраивать? По таймеру или в общем потоке повесить?  Если по таймеру, то какое минимальное время ему можно выставить, что не тормозило даже на слабых компах, например нетбуках?

Понял.

А как бы второй клик ещё ограничить по расстоянию от первого? Чтобы это срабатывало именно как настощий двойной клик. Допустим если больше 3-5 пикселей между местами кликов - то не защитывается.

И ещё одно. Если окно неактивно, то двойной клик в него не засчитывается. Приходится делать "тройной". Можно это как-то побороть?
Речь идёт о коде из сообщения #2.

Определяйте при клике координаты мыши, сравнивайте с ранее сохранёнными координатами предыдущего клика, сохраняйте текущие координаты в качестве «предыдущих».

Не верю ©

Можно и развернуть условие.

MultiClick(numClick, clickTimeout)
{
    static clickCount
    static priorHotKey
    static priorTickCount

    if (A_ThisHotkey == priorHotKey && A_TickCount-priorTickCount <= clickTimeout)
        ++clickCount
    else clickCount := 0

    priorHotKey := A_ThisHotkey
    priorTickCount := A_TickCount

    if (clickCount = numClick-1)
        return true
    else return false
}

«Непонятно» не принимается.

Только пятая строчка наверное так должна выглядеть?

If (Abs(x1 - x2) < 5) and (Abs(y1 - y2) < 5)

Разобрался, спасибо! Просто с фукциями, а также такими встроенными переменными и "#if" не имел дела до этого.

Про "#if" вообще ничего нигде нет. Только по аналогии с "#IfWinActive" смог догадаться что тут к чему. Кстати их даже в списке команд http://www.script-coding.com/AutoHotkey … dList.html нет.

http://l.autohotkey.net/docs/commands/_If.htm