AHK: Контекстное меню безопасного удаления

Помоему проблема в WinWaitClose, ContextDeleteMenu. Посмотрите так есть проблемы при показе выделенного?:

clipboard := FileList := ""
Send, ^{vk43}
ClipWait, 2
clipboard = %clipboard%

Loop, parse, clipboard, `n, `r
{ 
    SplitPath, A_LoopField, OutFileName
    FileList .= OutFileName "`n"
}
MsgBox, 4, ContextDeleteMenu, Удалить безвозвратно:`n`n%FileList%`n`nПродолжить?
IfMsgBox, No
    Exit 
Loop, parse, clipboard, `n, `r 
    MsgBox, 32, ContextDeleteMenu, Удалено`r`n%A_LoopField%, 1.5  
Return

Чего вы ждёте командой WinWaitClose, ContextDeleteMenu?
Попробуйте просто RunWait, sdelete.exe -s "%A_LoopField%", , hide
И что значит "безопасное удаление файлов"?

Что мелькает-то?
У вас задача поставлена так, что не поймёшь в чём она заключается...
И совершенно не ясно при каких делах тут, контекстное меню.

ОК. Добавляю в реестр этот регфайл:

Windows Registry Editor Version 5.00

#####################
# ContextDeleteMenu #
#####################

[HKEY_CLASSES_ROOT\AllFilesystemObjects\shell\ContextDeleteMenu]
"MUIVerb"="Безопасное удаление"
"Icon"="SHELL32.dll,131"

[HKEY_CLASSES_ROOT\AllFilesystemObjects\shell\ContextDeleteMenu\command]
@="ContextDeleteMenu.exe"

Получаю в контекстном меню проводника пункт ""Безопасное удаление".

Далее в C:\Windows\ или C:\Windows\System32\ (не имеет значения) ложу программу SDelete.exe и рядом скомпилированный в exe скрипт AHK ContextDeleteMenu.exe который будет выдавать запрос на подтверждения удаления объектов и в случае подтверждения, будет передавать команду программе SDelete.exe на их удаление ...

Надеюсь, теперь внятно написал ....

Мигают (открываются и закрываются) поочередно все PopUp окна ... пока не остановишь вручную работу скрипта. Это в случае выделения и удаления двух и более объектов.

... ну может не так выразился, извиняюсь. Это MsgBox

В принципе, этот скрипт нужен для того, чтобы случайно безвозвратно не удалить нужный файл. Можно непосредственно в реестр добавить вместо ContextDeleteMenu.exe - sdelete.exe. Все работает, но без запроса на удаление объектов ...

Вам были заданы вопросы в 5 посте, из ответов на которые можно было бы сделать выводы....

Остальные ваши "текста", увы не возвращают мне сути по сабжу.

#NoEnv
#NoTrayIcon
#SingleInstance Ignore
SetBatchLines -1

if !fileList := GetFileList()
    ExitApp

loop Parse, fileList, `n
{
    Splitpath, A_LoopField, fileName
    fileNameList .= fileName . "`n"
}

MsgBox, 4, ContextDeleteMenu, Удалить безвозвратно:`n`n%fileNameList%`n`nПродолжить?
IfMsgBox, No, ExitApp

loop Parse, fileList, `n
    FileWipe(A_LoopField)

FileWipe(ByRef filePath) {
    RunWait sdelete.exe -s "%filePath%",, hide UseErrorLevel
    if !ErrorLevel
        MsgBox, 32, ContextDeleteMenu, Удалено`r`n%filePath%, 1.5
}

GetFileList() {
    clipboard := ""
    Send, ^{vk43}
    ClipWait, 2
    return Clipboard
}

Список файлов из проводника можно получать с помощью COM, механизм «безопасного удаления» sdelete — реализовать на autohotkey. FileWipe и GetFileList используют способ предложенный в первом сообщении.

«Глюки», вероятно, возникали при множественном запуске скрипта и sdelete.

Большое спасибо, creature.ws! Теперь все заработало, как хотелось, но при множественном выделении почему-то удаляется только по одному файлу, хотя MsgBox сообщает, что файлы xxxxx.xxx удалены.

А как это все реализовать и какой вариант лучше? ... Я пока еще не "догоняю". Если Вам не сложно, пожалуйста! Мне легче понять это из кода скрипта, чем искать в справке ....

Для окон проводника:

ExplorerGetSelection(hwnd := "") {
; всего лишь пример. 
    (hwnd) || hwnd := WinExist("A")
    WinGetClass winClass, ahk_id %hwnd%

    if (winClass != "CabinetWClass" && winClass != "ExploreWClass")
        return

    for explorerWindow in ComObjCreate("Shell.Application").Windows {
        if (explorerWindow.hwnd != hwnd)
            continue

        for selectedItem in explorerWindow.Document.SelectedItems
            itemList .= selectedItem.path . "`n"
    }
    explorerWindow := selectedItem := ""
    return Rtrim(itemList) ; возвращается строка включающая пути выделенных файлов. разделитель `n
}

Как получить список выделенных файлов на рабочем столе  — по ссылке.