VBS: SQL запрос к листу Excel

Гы-ы-ы-ы....   вообщем сам тупанул (но видать вместе с компиком)
Дело в том, что вчера я запускал оное на Win7 x64, а чот видать из памяти выбило, что на такой винде нет объекта DAO, но что примечательно - винда вчера не ругалась (что невозможно создать такой объект), а вот сегодня - на неё нашло просветление и она мне подсказала
Ну и после оного поднял виртуал с хрюшкой, и дозаточил щас робит...

Set Engine = CreateObject("DAO.DBEngine.36")
Set mdb = Engine.OpenDatabase("c:\util\base.xls",True,False,"Excel 8.0")

' выводит имеющиеся имена таблиц
for each td in mdb.tabledefs
msgbox td.name
next


Set rs=mdb.OpenRecordset("1$")
msgbox rs.fields(0)

Ах да, ещё вот какая грабля оказалась,

- видать какое-то зарезервированное слово (я его хотел использовать в качестве сокращения для Recordset), его нельзя использовать в качестве переменной, но я почему-то опять был не в курсе...
видать длительный простой незамедлительно сказывается...

Господа, а то же самое (название листа/колонки) с помощью ADO можно получить?
Add: С листом

Set Conn = CreateObject("ADODB.Connection")
Conn.Open "..."
Set Catalog = CreateObject("ADOX.Catalog")
Set Catalog.ActiveConnection = Conn
WScript.Echo Catalog.Tables(<№ листа>).Name

С колонками не очень.
Первую получаю, допустим, так: .Execute("SELECT * FROM [чего-то там]").Fields(0).Name, а дальше?
Запись Catalog.Tables(<№ листа>).Columns(<№ колонки>) выдаёт сумятицу..

Также интересует получение заголовков табуляторов в соответствии со стилем ссылок (A1/R1C1).
Это возможно?

Ещё: у ADO (Recordset/Execute) есть метод GetString, а тут я не увидел. Имеется подобное в DAO?
И если в ADO я выделяю диапазон всего столбца (D:D, например), то GetString возвращает несколько лишних разделителей (возврат каретки по умолчанию) на конце списка. Причина этого в чём?

alexii
Это DAO. Про лист дописал.

Детальней напишите, пож-та, постараюсь разжевать.

В ADO для использования названия колонок из первой строки нужно было в connection string это указывать(HDR=YES). В DAO ситуация аналогичная - ADO Connection Strings. Ну и для запроса без диапазона нужно было указывать лист а не диапазон. Как с этим обстоит дело в DAO сказать затрудняюсь(никогда с DAO не работал), но скорее всего ситуация аналогична ADO. Попробуйте посмотреть этот пример: Use a closed workbook as a database (DAO).

P.S. Майкрософт  рекомендует отказаться от использования DAO :

Flasher, я не уверен что верно понял задачу.
Нужно делать выборку по имени колонки? Или нужно делать вывод по имени колонки?

Сделал таблицу в три столбца, в первой строке листа - названия колонок: user, Tel, Net.
В коде выбираем строки для которых число телефонных розеток равно 3:

Option Explicit

Dim oDAO, oDB
Set oDAO = CreateObject("DAO.DBEngine.36")
Set oDB = oDAO.OpenDatabase("tab1.xls", False, True, "Excel 8.0;HDR=Yes;")

Dim strSQL, oRS
strSQL = "SELECT * FROM [Лист1$] WHERE Tel = 3"
Set oRS = oDB.OpenRecordset(strSQL)

Do While Not oRS.EOF
   wscript.echo "Группа пользователей: " & oRs("user")
   wscript.echo "Кол-во телефонных розеток: " & oRs("Tel")
   wscript.echo "Кол-во езернет-розеток: " & oRs("Net")
   oRS.MoveNext
Loop

oRS.Close
oDB.Close
Set oRS = Nothing
Set oDB = Nothing
Set oDAO = Nothing

Это для случая когда названия колонок в первой строке листа, для диапазонов листа не пробовал.

По поводу получения адресов ячеек в стиле экселя - сильно сомневаюсь в такой возможности из коробки. Всё таки DAO предназначено для работы с БД, а там номера строки в экселевском представлении нет. Хотя, если не делать выборку, и не использовать сортировку - при переборе никто не мешает посчитать номер строки для конкретного набора данных. Но нужно быть на 100% уверенным, что DAO прочтёт строки именно в том порядке который имеется в листе. Это было бы логично, но я не уверен что всё именно так и есть . Номер колонки(для стиля R1C1) можно получить из свойств поля - oRs("user").OrdinalPosition + 1(нумерация полей в рекордсете от 0 идёт). Другие св-ва рекордсета можно посмотреть в студийном отладчике(я пользуюсь 2008-ой студией для таких случаев).

По ошибке - MDAC установлен? Какой именно код вызывает ошибку?

P.S. кажется я был немного невнимателен - тема плавно с DAO на ADO(а я всё про DAO, да про DAO )... Собственно по какому объекту сейчас обсуждение идёт?

Зачем вызывать Execute для получения каждой колонки? По первому запросу мы получаем таблицу(recordset), в нём уже имеется вся информация по числу колонок, по их номерам, по их именам(если HDR=YES). В моём примере запрос запускался один раз. Может я не тот пример смотрю?

Выяснить стиль ссылок точно можно прочитав экселевский файл(свойство ReferenceStyle объекта Workbook.Application; xlR1C1 = -4150, xlA1 = 1). Правда понадобится установленный Excel. Можно ли проверить это свойство силами ADO или DAO сказать не берусь(пока).

По работе с диапазонами сейчас ничего сказать не могу, так как с данной спецификой не сталкивался(в моих задачах всегда требовалось обрабатывать весь лист). Если выдастся время - попробую, тогда может быть что-то смогу подсказать по поводу имён колонок для диапазонов и определения стиля ссылок без использования  Excel.Application.

Excel 8.0;HDR=Yes; - это одно строковое значение для свойства Extended Properties. А так как она содержит символ ";", являщийся разделителем, она должна быть заключена в кавычки(экранированые). Правильно будет примерно так:

File = "C:\file.xls"
CreateObject("ADODB.Connection").Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & File & ";Extended Properties=""Excel 8.0;HDR=Yes;"""

Почитал внимательнее приведённую мной же ссылку, оказалось что HDR=YES значение по умолчанию

Надо будет всё таки потестировать разные варианты(включая именованные диапазоны и задаваемые вручную). Так, для собственного развития...

Всё равно не понимаю - получили рекордсет, дальше вытаскиваем из него всё что нужно, включая имена колонок:

option explicit
Const adUseClient = 3 : Const adOpenStatic = 3 : Const adLockOptimistic = 3 : Const adCmdText = &H1
Const adSchemaTables = 20 : Const adSchemaColumns = 4
Dim FileSource
FileSource = "tab1.XLS"

Dim oConn
Set oConn = CreateObject("ADODB.Connection")
Dim oRS
Set oRS = CreateObject("ADODB.Recordset")
With oConn
    .Provider = "Microsoft.Jet.OLEDB.4.0"
    .ConnectionString = "Data Source=" & FileSource & ";Extended Properties=""Excel 8.0;HDR=Yes;"""
    .CursorLocation = adUseClient
    .Open
End With

Dim strSQL
strSQL = "SELECT * FROM [Лист1$] WHERE Tel = 3"
Set oRS = oConn.Execute(strSQL)

wscript.echo "колонка №1: " & oRS.Fields(0).Name
wscript.echo "колонка №2: " & oRS.Fields(1).Name
wscript.echo "колонка №3: " & oRS.Fields(2).Name

oRS.Close
oConn.Close
Set oRS = Nothing
Set oConn = Nothing

Проблема №1: приведите, пожалуйста полный код - поо проскальзывающим кускам сложно понять что требуется.
Проблема №2: опишите чего нужно достичь на прикладном уровне - например на примере конкретного xls-файла(с образцом данных).

При открытии экселевского файла OLE DB пытается определить тип данных в колонках, анализируя первые 8(по умолчанию) строк. Подозреваю что речь о том, что если все 8 строк имеют одинаковый тип данных, OLE DB будет рассматривать это как отсутствие шапки у таблицы, и сам назначит колонкам имена(F1, F1 etc).

P.S. Зачем прятать код ещё и под спойлер(с непривычки даже не сразу понял что там код где-то в сообщении спрятан)? С "обрезкой" простыни успешно справляется тег code.