AHK: Вывод информации о треке из AIMP

Как из AIMP, не знаю, но можно извлечь информацию непосредственно из файла.

Нет, не в курсе, как узнать, какой файл звучит, да и AIMP'ом не пользуюсь.

Для Winamp скрипта тоже нет, посмотрю попозже, если будет время.

получить весь текущий плейлист

В файле AIMPSDKRemote.h описаны способы взаимодействия с плеером «извне».
Получение информации о треке:

AIMP_GetTrackInfo() {
    static AIMPRemoteAccessClass := "AIMP2_RemoteInfo"
        , AIMPRemoteAccessMapFileSize := 2048
        , FILE_MAP_READ := 4


    if !hFile := DllCall("OpenFileMapping"
        , "UInt", FILE_MAP_READ
        , "UInt", true
        , "Ptr",  &AIMPRemoteAccessClass)
    {
        return false
    }

    info := DllCall("MapViewOfFile"
        , "Ptr",  hFile
        , "UInt", FILE_MAP_READ
        , "UInt", 0
        , "UInt", 0
        , "Ptr",  AIMPRemoteAccessMapFileSize)

    size := NumGet(info|0, 0, "UInt")
    textOffset := info + size

    albumLen    := NumGet(info|0, 40, "UInt")
    artistLen   := NumGet(info|0, 44, "UInt")
    dateLen     := NumGet(info|0, 48, "UInt")
    fileNameLen := NumGet(info|0, 52, "UInt")
    genreLen    := NumGet(info|0, 56, "UInt")
    titleLen    := NumGet(info|0, 60, "UInt")

    TrackInfo := {
    (Join,
        active     : NumGet(info|0, 4,  "Int")
        bitRate    : NumGet(info|0, 8,  "UInt")
        channels   : NumGet(info|0, 12, "UInt")
        duration   : NumGet(info|0, 16, "UInt")
        fileSize   : NumGet(info|0, 20, "Int64")
        rating     : NumGet(info|0, 28, "UInt")
        sampleRate : NumGet(info|0, 32, "UInt")
        trackID    : NumGet(info|0, 36, "UInt")
        album      : StrGet(textOffset,                    albumLen)
        artist     : StrGet(textOffset += albumLen * 2,    artistLen)
        date       : StrGet(textOffset += artistLen * 2,   dateLen)
        fileName   : StrGet(textOffset += dateLen * 2,     fileNameLen)
        genre      : StrGet(textOffset += fileNameLen * 2, genreLen)
        title      : StrGet(textOffset += genreLen * 2,    titleLen)
    )}

    DllCall("CloseHandle", "Ptr", hFile)
    return TrackInfo
}

Результат работы функции — ассоциативный массив, содержащий в соответствующих полях всю доступную информацию о файле, или 0, если «что-то пошло не так».

Space::
    track := AIMP_GetTrackInfo()
    MsgBox % track.artist " — " track.title
    return

При нажатии пробела — «вывод названия исполнителя и трека».

Дайте код, пожалуйста, на AHK 1.0.48.05 (Не L)

И чтоб под windows 95 работал. 4 года с окончания поддержки — слишком малый срок для отказа от приложения.