1 Тема от The gray Cardinal

  • The gray Cardinal
  • Разработчик
  • Неактивен

Тема: VBScript: определение текущего IP-адреса

Определение текущих IP-адресов существующих сетевых подключений данного компьютера.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set IPConfigSet = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled=TRUE")
 
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then 
        For Each IPAddress In IPConfig.IPAddress
            WScript.Echo IPAddress
        Next
    End If
Next
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

2 Ответ от The gray Cardinal

  • The gray Cardinal
  • Разработчик
  • Неактивен

Re: VBScript: определение текущего IP-адреса

Получение IP-адреса для определённого сетевого подключения:

strComputer  =  "."
' отредактировать под нужное имя сетевого подключения:
strNetworkConnection = "'Подключение по локальной сети'"

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colNics = objWMIService.ExecQuery("Select * From Win32_NetworkAdapter " _
    & "Where NetConnectionID = " & strNetworkConnection)
For Each objNic in colNics
    Set colNicConfigs = objWMIService.ExecQuery("ASSOCIATORS OF " _
        & "{Win32_NetworkAdapter.DeviceID='" & objNic.DeviceID & "'}" _
        & " WHERE AssocClass=Win32_NetworkAdapterSetting")
    For Each objNicConfig In colNicConfigs
        For Each strIPAddress in objNicConfig.IPAddress
            Wscript.Echo "IP Address: " & strIPAddress
        Next
    Next
Next

Пример опубликовал cmepx.

Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.