AHK: Внесенные изменения в файл

У меня есть файл

Файлы бывают разные - текстовые, бинарные и.т.п.

внес в этот файл сторонней программой

Дописал в конец файла? Или изменения могут затрагивать любую часть.

FileRead, Text, %FileName%
LastLen := StrLen(Text) 
Return

1::
    FileRead, Text, %FileName%
    MsgBox % SubStr(Text, LastLen+1) 
    LastLen := StrLen(Text)
    Return

Ладно

Скрипт показывает, какие строки были удалены и/или добавлены со времени последней проверки.
При этом порядок строк и их расположение в исходных файлах неважны, дубликаты строк тоже не учитываются.
Если файл file2 отсутствует при первом запуске, он будет создан при подтверждении замены.

#NoEnv
file1 = c:\Windows\SYSTEM32\drivers\etc\hosts
file2 = %A_ScriptDir%\hosts.old
Loop 2 {
   Iter := A_Index, Arr%Iter% := []
   Loop, Read, % file%Iter%
      Arr%Iter%.Insert(A_LoopReadLine, "")
}
for Key in Arr1
   Str_add .=  Arr2.HasKey(Key) ? "" : Key . "`n"
for Key in Arr2
   Str_del .=  Arr1.HasKey(Key) ? "" : Key . "`n"
MsgBox % "Добавлено: `n_____________`n`n" . Str_Add . "`n`n"
       . "Убрано: `n_____________`n`n" . Str_Del . "`n"
if (Str_Del || Str_Add) {
   MsgBox,4,, Зафиксировать изменения ?`n`nФайл "%file2%" будет заменен`nфайлом "%file1%"
   IfMsgBox Yes
      FileCopy, %file1%, %file2%,1
}
return

Если нужны номера строк с изменениями:

+ Показать

#NoEnv
file1 = c:\Windows\SYSTEM32\drivers\etc\hosts
file2 = %A_ScriptDir%\hosts.old
Loop 2 {
   Iter := A_Index, Arr%Iter% := []
   Loop, Read, % file%Iter%
      Arr%Iter%.Insert(A_LoopReadLine, A_Index)
}
for Key, V in Arr1
   Str_add .=  Arr2.HasKey(Key) ? "" : "строка № " . V . "  -> " . Key . "`n"
for Key, V in Arr2
   Str_del .=  Arr1.HasKey(Key) ? "" : "строка № " . V . " -> " . Key . "`n"
MsgBox % "Добавлено: `n_____________`n`n" . Str_Add . "`n`n"
       . "Убрано: `n_____________`n`n" . Str_Del . "`n"
if (Str_Del || Str_Add) {
   MsgBox,4,, Зафиксировать изменения ?`n`nФайл "%file2%" будет заменен`nфайлом "%file1%"
   IfMsgBox Yes
      FileCopy, %file1%, %file2%,1
}
return

Понял, что нужно еще что-то сверх того, что написано в первом посте.
Что значит "выдавала именно то что я ввел в данное время"? То есть данные отредактированы в редакторе, но файл не сохранен, или что-то другое?

После показа измененых строк появляется диалог с запросом: "Зафиксировать изменения?" и двумя вариантами ответа.
Нажми "Да" и запусти скрипт еще раз.

Я внес изменения в пост #12, чтобы в случае невозможности копирования обновленного файла hosts, скрипт сообщал бы об ошибке. Это может быть, если скрипту не хватает прав для копирования файла в папку, откуда он запущен, например из папки с ОС.

#NoEnv
#Persistent
file1 = c:\Windows\SYSTEM32\drivers\etc\hosts
file2 = %A_ScriptDir%\hosts.old
IfNotExist, %file2%    
   FileCopy, %file1%, %file2%,1
if ErrorLevel {
   MsgBox Невозможно скопировать файл.
   ExitApp
}
SetTimer, Check, 10000 ; 10 секунд
Return

Check:
   FileGetTime, time1, %file1%
   FileGetTime, time2, %file2%
   if (time1 = time2)
      Return
   Loop 2 {
      J := A_Index, Arr%J% := []
      Loop, Read, % file%J%
         Arr%J%.Insert(A_LoopReadLine . "`n", "")
   }
   loop 2 {
      A:=3-A_Index
      Str_%A% =
      for Key in Arr%A_Index%
         Str_%A% .=  Arr%A%.HasKey(Key) ? "" : Key
   }
   if (Str_2 || Str_1) {
      MsgBox % "Добавлено: `n_____________`n`n" . Str_2 . "`n`n"
             . "Убрано: `n_____________`n`n" . Str_1 . "`n"
   }
   FileCopy, %file1%, %file2%, 1
   if ErrorLevel {
      MsgBox Невозможно скопировать файл.
      ExitApp
   }
Return

Вместо таймера лучше использовать уведомления, как например в этом примере, но пока пусть так.