AHK: Как передать данные из одного скрипта в другой?

#SingleInstance Force
#Persistent    
#NoEnv
DetectHiddenWindows, On
PathScript = C:\Users\sergey\Desktop\=Test.ahk
Run %PathScript%,,,pid

Loop {
    Sleep 500
    Random, Rand, 56, 256
    Param := "var1=" Chr(Rand) Chr(Rand+115)
    SendMessage, 0xC, 0, &Param,, %PathScript% - AutoHotkey ahk_pid %pid%
    Param = var2=%Rand% 
    SendMessage, 0xC, 0, &Param,, %PathScript% - AutoHotkey ahk_pid %pid%
} 

#SingleInstance Force
#Persistent    
#NoEnv
OnMessage(0xC, "GetText")

GetText(wParam, lParam) { 
    Global  
    RegExMatch(StrGet(lParam), "(.*?)=(.*)", Data)
    %Data1% := Data2
    Return True 
}  
Loop
    MsgBox, , ,  % "var1 = " var1 "`n`nvar2 = " var2, 0.7

Gui, Font, s18
Gui, Add, Text, vText x0 y0 w200 h30 Center
Gui, Show, w200 h30, Заголовок
PID := DllCall("GetCurrentProcessId")
OnMessage(0xC, "WM_SETTEXT")

Loop
{
   SendMessage, 0xC,, "Text " . A_Index,, ahk_pid %PID%
   Sleep, 100
}

WM_SETTEXT(wp, lp)
{
   GuiControl,, Text, % StrGet(lp)
   Return 0
}

GuiClose:
   ExitApp

Gui, Font, s18
Gui, Add, Text, vText x0 y0 w200 h30 Center
Gui, Show, w200 h30, Заголовок
ParentPID := DllCall("GetCurrentProcessId")
OnMessage(0xC, "WM_SETTEXT")
OnExit, Exit

Script =
(
   #NoTrayIcon
   Loop
   {
      SendMessage, 0xC,, "Text " . A_Index,, ahk_pid %ParentPID%
      Sleep, 100
   }
)

FilePath := A_Temp "\_MyScript_" A_TickCount ".ahk"
FileAppend, % Script, % FilePath
Run, % FilePath,,, PID
DetectHiddenWindows, On
WinWait, % "ahk_pid" PID
FileDelete, % FilePath
Return

GuiClose:
   ExitApp

Exit:
   Process, Close, %PID%
   ExitApp

WM_SETTEXT(wp, lp)
{
   GuiControl,, Text, % StrGet(lp)
   Return 0
}

#SingleInstance
OnMessage(0x4a, "Receive_WM_COPYDATA")  ; 0x4a is WM_COPYDATA
return

Receive_WM_COPYDATA(wParam, lParam)
{
    StringAddress := NumGet(lParam + 8)  ; lParam+8 is the address of CopyDataStruct's lpData member.
    StringLength := DllCall("lstrlen", UInt, StringAddress)
    if StringLength <= 0
        ToolTip %A_ScriptName%`nA blank string was received or there was an error.
    else
    {
        VarSetCapacity(CopyOfData, StringLength)
        DllCall("lstrcpy", "str", CopyOfData, "uint", StringAddress)  ; Copy the string out of the structure.
        ; Show it with ToolTip vs. MsgBox so we can return in a timely fashion:
        ToolTip %A_ScriptName%`nReceived the following string:`n%CopyOfData%
    }
    return true  ; Returning 1 (true) is the traditional way to acknowledge this message.
}

TargetScriptTitle = Receiver.ahk ahk_class AutoHotkey

#space::  ; Win+Space hotkey. Press it to show an InputBox for entry of a message string.
InputBox, StringToSend, Send text via WM_COPYDATA, Enter some text to Send:
if ErrorLevel  ; User pressed the Cancel button.
    return
result := Send_WM_COPYDATA(StringToSend, TargetScriptTitle)
if result = FAIL
    MsgBox SendMessage failed. Does the following WinTitle exist?:`n%TargetScriptTitle%
else if result = 0
    MsgBox Message sent but the target window responded with 0, which may mean it ignored it.
return

Send_WM_COPYDATA(ByRef StringToSend, ByRef TargetScriptTitle)  ; ByRef saves a little memory in this case.
; This function sends the specified string to the specified window and returns the reply.
; The reply is 1 if the target window processed the message, or 0 if it ignored it.
{
    VarSetCapacity(CopyDataStruct, 12, 0)  ; Set up the structure's memory area.
    ; First set the structure's cbData member to the size of the string, including its zero terminator:
    NumPut(StrLen(StringToSend) + 1, CopyDataStruct, 4)  ; OS requires that this be done.
    NumPut(&StringToSend, CopyDataStruct, 8)  ; Set lpData to point to the string itself.
    Prev_DetectHiddenWindows := A_DetectHiddenWindows
    Prev_TitleMatchMode := A_TitleMatchMode
    DetectHiddenWindows On
    SetTitleMatchMode 2
    SendMessage, 0x4a, 0, &CopyDataStruct,, %TargetScriptTitle%  ; 0x4a is WM_COPYDATA. Must use Send not Post.
    DetectHiddenWindows %Prev_DetectHiddenWindows%  ; Restore original setting for the caller.
    SetTitleMatchMode %Prev_TitleMatchMode%         ; Same.
    return ErrorLevel  ; Return SendMessage's reply back to our caller.
}