VBS: Возможно ли на vbs послать на печать документ Word?

Word установлен на машине?

Думаю распечатать документ Word "с блокнота с сохранением форматирования" можно вряд ли. Можно поискать параметры командной строки winword.exe для печати. Или попытаться выполнить скриптом команду "Print" контекстного меню файла.

Думаю, в такой ситуации можно попробовать программно выполнить "глагол" реестра, т.е. пункт контекстного меню для файла, описание и пример здесь. Команда может быть как "Print", так и "Печать".

Некоторые особенности методов DoIt, InvokeVerb, InvokeVerbEx, ShellExecute объекта автоматизации Shell.Application и метода Run объекта автоматизации WScript.Shell.

Нет. Однако есть такое средство, как WordView.

К сожалению, вынужден сделать некоторые поправки ко второму скрипту.

В операторе

w.Visible = false

необходимости нет: при работе в качестве сервера автоматизации Word, по умолчанию, не отображает окно приложения.

w.ActiveDocument.PrintOut

Вместо применения .ActiveDocument — правильно:

Set objDoc = .Documents.Open("D:\Doc1.doc")
objDoc.PrintOut

Далее просто ошибка:

w.ActiveDocument.PrintOut
WScript.Sleep(1000)

По умолчанию Word производит фоновую печать документа (при этом работа скрипта продолжается). Однако, задержки в 1000 мс достаточно для печати лишь коротких и простых по структуре документов. Если фоновая печать к этому времени не будет завершена, то по w.Quit незаконченное задание на печать будет снято. Необходимо:
— либо ждать, пока не будет завершена фоновая печать документа;
— либо печатать напрямую, так сказать, на «переднем» плане.

В данном конкретном случае, когда требуется только отпечатать документ, выбор метода особо не важен (хотя… при фоновой печати, в цикле ожидания можно выводить индикатор, что печать продолжается [ну, конечно, без процентов… ]). В других случаях, если кроме печати документа требуется проделать ещё какие-либо манипуляции — выбор фоновой печати однозначен.

В качестве примера (проверено на MS Word 2003):

Option Explicit

Const wdDoNotSaveChanges    =  0
Const wdPromptToSaveChanges = -2
Const wdSaveChanges         = -1


Dim objWord
Dim objDoc

Set objWord = WScript.CreateObject("Word.Application")

With objWord
    ' .Documents.Open(FileName, ConfirmConversions, ReadOnly, AddToRecentFiles)
    Set objDoc = .Documents.Open("C:\Temp\01.doc", False, True, False)
    
    ' 
    '- Метод 1. Печать в фоновом режиме -----------------------------------------
    objDoc.PrintOut True                         ' .PrintOut(Background)
    
    ' Здесь, при необходимости, можно делать что-то ещё

    Do
        WScript.Sleep 500
    Loop Until .BackgroundPrintingStatus = 0     ' Ждём окончания фоновой печати
    '----------------------------------------------------------------------------
    
    '- Метод 2. Печать напрямую -------------------------------------------------
    objDoc.PrintOut False                        ' .PrintOut(Background)
    '----------------------------------------------------------------------------
    
    Set objDoc = Nothing
    
    .Quit wdDoNotSaveChanges                     ' .Quit(SaveChanges)
End With

Set objWord = Nothing

WScript.Quit 0

В качестве примера (проверено на MS Excel 2000):

Option Explicit

Dim objExcel
Dim objWorkbook

Set objExcel = WScript.CreateObject("Excel.Application")

With objExcel
    ' .Workbooks.Open(FileName, UpdateLinks, ReadOnly,...)
    '
    '  UpdateLinks is:
    ' 0 Doesn't update any references 
    ' 1 Updates external references but not remote references 
    ' 2 Updates remote references but not external references 
    ' 3 Updates both remote and external references 
    '
    ' or .AskToUpdateLinks = False
    
    Set objWorkbook = .Workbooks.Open("C:\Temp\01.xls", 0, True)
    
    objWorkbook.PrintOut
    objWorkbook.Saved = True
    
    Set objWorkbook = Nothing
    
    .Quit
End With

Set objExcel = Nothing

WScript.Quit 0

P.S. Во время работы обоих скриптов теоретически возможно появление и других непредусмотренных диалогов (мне сейчас сложно всё заранее предусмотреть). Возможно, в этом случае стоит поиграться со свойством Application.DisplayAlerts.

насколько я понял, печатаются документы на принтер, установленный по умолчанию.
А как направить печать документов на определенный сетевой принтер?

Подскажите, пожайлуйста, как этот скрипт использовать в totalcmd для печати документов.
Если задать команду в меню Start totalсmd, то как скрипт получит путь необходимого файла?
Как видно в описанных здесь решениях путь задан жёстко.

То, что есть мышка я помню, но мне хотелось бы по комбинации клавиш отправлять задания на печать (чаще файлы *.doc) в фоновом режиме.
В то же время, даже когда используешь команду print через контекстное меню, на экране появляется окно Worda, мелькает (как будто я не знаю, что дал команду на печать), и вот приходится смотреть на все эти выкрутасы.
Хотелось бы просто: нажал - дефолтный принтер заработал - а пользователь не отвлекается от других документов и не ловит мышку по столу.

alexii Спасибо за разъяснение и подготовку скрипта и файла реестра!
Пришлось повозиться с настройкой клавиш в totalcmd.
Нашёл некоторую информацию на форуме wincmd.ru, кое-что мне подсказала сама программа totalcmd.
В итоге необходимо в параметрах запуска скрипта, созданного alexii, добавить %p%n и будет счастье! , но только для одного файла.
В смысле печататься будет один файл, а вот если выделить два файла, то печататься будет тот, на котором находится курсор totalcmd.
Для полного счастья пока не знаю, что сделать. То ли это total так себя ведёт, то ли скрипт?

В "Start Menu" totalcmd создал пункт "print Word",
в поле "command" - C:\Program Files\AutoHotkey\PrintSilent.vbs
в поле "parameters" - %p%n
в поле "Start patch" - C:\Program Files\AutoHotkey\

Если поле "parameters" оставить пустым, то при нажатии клавиши Ctrl+p ничего не происходит.
Если в поле "parameters" поставить %p%n, то происходит "тихая печать".
Если при этом параметре в totalcmd выделить 2 файла (*.doc), то печатается только тот, который находится под курсором totalcmd. Видимо, эти параметры означают передачу пути файла, находящегося под курсором, а не тех, что выделены.

Karam, пробуйте:

Option Explicit

Const ForReading         = 1


Dim objFSO
Dim objTS

Dim objWshShell

Dim objWord
Dim objDoc

Dim objExcel
Dim objWorkbook

Dim strListFileName
Dim strFileName


If WScript.Arguments.Count = 1 Then
    Set objFSO      = WScript.CreateObject("Scripting.FileSystemObject")
    Set objWshShell = WScript.CreateObject("WScript.Shell")
    
    strListFileName = WScript.Arguments.Item(0)
    
    'WScript.Echo strListFileName
    
    If objFSO.FileExists(strListFileName) Then
        Set objTS = objFSO.OpenTextFile(strListFileName, ForReading)
        
        Set objWord  = Nothing
        Set objExcel = Nothing
        
        Do Until objTS.AtEndOfStream
            strFileName = objTS.ReadLine()
            
            'WScript.Echo strFileName
            
            If objFSO.FileExists(strFileName) Then
                Select Case UCase(objFSO.GetExtensionName(strFileName))
                    Case "DOC"
                        PrintDOC strFileName
                    Case "XLS"
                        PrintXLS strFileName
                    Case "TXT"
                        PrintTXT strFileName
                    Case Else
                        ' Nothing to do
                End Select
            End If
        Loop
        
        If Not objWord Is Nothing Then
            objWord.Quit
            
            Set objWord = Nothing
        End If
        
        If Not objExcel Is Nothing Then
            objExcel.Quit
            
            Set objExcel = Nothing
        End If
    End If
    
    Set objWshShell = Nothing
    Set objFSO      = Nothing
End If

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub PrintDOC(strFileName)
    Const wdDoNotSaveChanges = 0
    
    If objWord Is Nothing Then
        Set objWord = WScript.CreateObject("Word.Application")
    End If
    
    With objWord
        Set objDoc = .Documents.Open(strFileName, False, True, False)
        
        objDoc.PrintOut True
        
        Do
            WScript.Sleep 500
        Loop Until .BackgroundPrintingStatus = 0
        
        objDoc.Close wdDoNotSaveChanges
        
        Set objDoc = Nothing
    End With
End Sub
'=============================================================================

'=============================================================================
Sub PrintXLS(strFileName)
    If objExcel Is Nothing Then
        Set objExcel = WScript.CreateObject("Excel.Application")
    End If
    
    With objExcel
        .AskToUpdateLinks = False
        .Interactive      = False
        .DisplayAlerts    = False
        
        Set objWorkbook = .Workbooks.Open(strFileName, 0, True)
        
        objWorkbook.PrintOut
        objWorkbook.Close False
        
        Set objWorkbook = Nothing
    End With
End Sub
'=============================================================================

'=============================================================================
Sub PrintTXT(strFileName)
    objWshShell.Run """notepad.exe"" /p """ & strFileName & """", 0, False
End Sub
'=============================================================================

Поддерживает печать *.doc, *.xls и *.txt. В двух последних случаях всё равно будет отображаться окно «Печать»: «Идёт печать документа …».

В созданном пункте меню TC меняете «Command:» на:

wscript.exe "<путь>\PrintSilent.vbs"

В «Parameters:» указываете «%L».

P.S. Если Вы ранее импортировали reg-файл из #21 — удалите из реестра добавленные им параметры, для текущего метода печати они не нужны.

Karam, я ведь сказал: забудьте про предыдущий вариант полностью и окончательно, удалите из реестра добавленные параметры и забудьте о таком пункте, как «Тихая печать» — Вы ведь сказали, что контекстное меню Вам не подходит, печатать Вы планируете из стартового меню TC (кстати, а ему можно назначить горячую клавишу? Или она есть, а я не знаю?)

Кстати, что случилось с ответами на мои вопросы:

Я их почему-то не вижу . Если Вы планируете получить результат, желательно отвечать на задаваемые вопросы.

Теперь по Вашему посту:

У меня всё работает. Обычно я стараюсь проверять и после того, как выкладываю код на форум — копирую текст скрипта из браузера и проверяю ещё раз.

У меня тоже Windows XP SP3, MS Office 2003 SP3, версия TC, применявшаяся для проверки (я им не пользуюсь), — 6.55.

…то он распечатает имена выделенных файлов. Первый скрипт на это и не рассчитан. Он принимает в качестве параметра имя файла для печати. В случае указания параметра «%L» ему будет передан текстовый файл, содержащий имена выделенных на панели TC файлов, которые он добросовестно и распечатает, поскольку никакой проверки, что имя переданного файла есть документ Microsoft Word, не делается (и не предполагалось делать, поскольку первый скрипт был предназначен для запуска исключительно из контекстного меню файлов типа «Word.Document»).

Вы нашли и прочли в справке TC, что есть параметр «%L» и для чего он нужен?

Если Вы готовы, мы можем пройтись по пунктам, как и что делать.

Бывает.

В той, что я использовал для отладки (6.55), — есть. Однако, поскольку, как я и писал выше, его не пользую, то и не знал где «копать». Поиск в справке к нужному результату меня не привёл.

Karam, у меня отсутствует Office 2007 как таковой, «*.docx» проверять и отлаживать не на чем. Но Вы можете попробовать просто исправить имеющийся скрипт, добавив обработку расширения «docx», может быть и заработает (*.rtf добавляется так же, но это я проверить могу).

Замените:

Case "DOC"

на:

Case "DOC", "DOCX", "RTF"

и:

Case "XLS"

на:

Case "XLS", "XLSX"

Karam, на главной странице сайта есть:

Это максимум, что требуется, если Вы захотите его где-то разместить; я-то точно не буду этим заниматься — на мой взгляд скрипт тривиален, узкоспецифичен и малоценен.

Если речь про этот скрипт, то добавьте строку «objFSO.GetFile(strFileName).Name = objFSO.GetBaseName(strFileName) & "_printed." & objFSO.GetExtensionName(strFileName)» в скрипт примерно так:

    …
    If Not objExcel Is Nothing Then
        objExcel.Quit
        
        Set objExcel = Nothing
    End If
    
    objFSO.GetFile(strFileName).Name = objFSO.GetBaseName(strFileName) & "_printed." & objFSO.GetExtensionName(strFileName)
End If
…

segreich, я попробую посмотреть вечером на реальном примере.

С вордом все отлично как с ожиданием печати, так и без. А вот Acrobat зараза не закрывает себя после печати и пока его вручную не закроешь, то печать не продолжается (это в случае True, ожидания печати). В случае False Acrobat выдает ошибку об отсутствии файла. Файлы переименовываются все нормально.

Пока нашел альтенативный промотрщик pdf, который работает с коммандной строкой и закрывает себя после печати: Manual for Sumatra PDF reader.
Но по скорости он медленнее.

Если будет желание/возможность доработать Acrobat, то было бы здорово. Если нет, то альтернативный вариант пока вполне сгодится.
В любом случае спасибо за помощь!

segreich, к сожалению, из того, что я пробовал с Reader'ом (а также из того, о чём периодически шла речь у нас на форуме про печать pdf) — я сделал вывод, что по сю пору Adobe, мягко говоря, клал на подобные потребности пользователей, и следует, как Вы и сделали, использовать для печати стороннее средство. Кроме приведённой ссылки Sumatra PDF также упоминался и Foxit Reader. Сам я не пользовался ни тем, ни другим.