VBS: Файл с расширением по почте

' параметр для вставки в кнопки/ярлыки вызова - <путь к скрипту.vbs> <путь рабочего каталога>:
Path = WScript.Arguments(0)

Last = 3 ' максимальное число последних файлов без расширения

' создаём объект FSO:
Set FSO = CreateObject("Scripting.FileSystemObject")

' проходимся циклом по всем файлам в папке
For Each F in FSO.GetFolder(Path).Files
' если (ищем с конца строки) не находим точку, то создаём список (S) через возврат каретки (vbCr):
  If InStrRev(F.Name, ".") = 0 Then S = S & vbCr & F
Next

' Если в списке непусто, то убираем из него первый лишний символ vbCr:
If S <> "" Then S = Mid(S, 2)

' создаём массив, разделитель - возврат каретки
Mass = Split(S, vbCr)

' Определяем число элементов массива за вычетом единицы (массивы начинают отсчёт с нуля):
Max = Ubound(Mass)

' Если максимум равен 0 (т.е. 1 шт.) или более, то работа продолжается:
If Max >= 0 Then

' Если заданное число посл. файлов больше максимума массива, то нет смысла брать это число
' Приводим его к максимуму, иначе отнимаем единицу для правильной работы с массивами
  If Last > Max Then Last = Max Else Last = Last - 1

' создаём объект Recordset для создания коллекции полей данных
' см. http://www.script-coding.com/ADO.html#RecordsetObject
' или http://ekinoks.cu.edu.tr/devguru/ADO/recordset_fieldscollection.html
  Set Dict = CreateObject("ADODB.Recordset")

' Добавляем (Append) поле в коллекцию Fields с произвольными названиями "Name" и "Date"
' первый параметр отвечает за тип данных (200 - строковый, 135 - формат даты)
' второй - допустимое число символов (255 - предел для строки и имени файла)
' см. http://www.devguru.com/technologies/ado/8763
' или http://ekinoks.cu.edu.tr/devguru/ADO/recordset_fieldscollection.html
  Dict.Fields.Append "Name", 200, 255
  Dict.Fields.Append "Date", 135, 22

  Dict.Open ' открываем на редактирование

' Проходимся по массиву избранных файлов без расширения
  For Each F In Mass

    Dict.AddNew ' добавляем новую запись 

    Dict("Name") = F ' заносим полное имя файла в поле Name

'   заносим дату модификации в поле Date, приводя запись к строковому типу [CStr(..)]:
    Dict("Date") = CStr(FSO.GetFile(F).DateLastModified)

  Next

' Сортируем поля (столбцы) по дате в обратном (DESC) порядке
  Dict.Sort = "Date DESC"

' Создаём массив, разбивая всю коллекцию полей в строковом (GetString) виде по возврату каретки
  Sort = Split(Dict.GetString, vbCr)

' Пишем постоянную часть URI:
  Web = "http://schemas.microsoft.com/cdo/configuration/"

  With CreateObject("CDO.Message")
    .From = "info@main.local.domain"
    .To = "name@yandex.ru"
    .Subject = "User fail" 
    .Textbody = "Automatic mail-sender"

'   Проходимся циклом с пределом Last по элементам массива Sort:
    For i = 0 to Last

      ' Добавляем файл с полном именем, вырезанным из строки формата <FullFileName><Tab><Date>:
      .AddAttachment Left(Sort(i), InStrRev(Sort(i), vbTab) - 1)

    Next

' Другой метод заключается проходе по списку полей пока указатель не достигнет конца (EOF)
' В этом случае строку Sort = Split(Dict.GetString, vbCr) нужно удалить
'    Do Until Dict.EOF

'      .AddAttachment Dict("Name") ' добавляем файлы с путями, указанными в списке поля/столбца Name

'      выходим из цикла если позиция счётчика станет равна числу посл. файлов:
'      If i = Last Then Exit Do

'      i = i + 1 : Dict.MoveNext ' переходим к след. строке

'    Loop

    .Configuration.Fields.Item (Web & "sendusing") = 2
    .Configuration.Fields.Item (Web & "smtpserver") = "192.168.1.1"
    .Configuration.Fields.Item (Web & "smtpserverport") = 25
    .Configuration.Fields.Update : .Send
  End With

End If