1 (изменено: Esc, 2015-02-23 22:10:07)

Тема: AHK: Зумирование изображений в браузере колесом мыши.

Здравствуйте, давным давно появилась идея с зумом, но не знал как её реализовать, а AutoHotkey похоже способен на это. Помогите пожалуйста.

Суть проста, когда в интернет браузере открываем изображение или видео в отдельной вкладке, переназначить действие колеса мыши со скроллинга на зумирование.

Wheel Down = Ctrl и + (Plus)
Wheel Up = Ctrl и - (Minus)

Нужно чтобы скрипт срабатывал на заголовки Firefox, примеры которых перечислены ниже, и мгновенно отключался при переходе на любую другую вкладку. Как видно, здесь наиболее постоянными являются расширения файлов, вот как бы сделать, чтобы не было ложных срабатываний.

cats.jpg (JPEG Image, 773 × 421 pixels)
kittens.jpeg (JPEG Image, 1280 × 720 pixels)
promo.png (PNG Image, 4000 × 3000 pixels)
1484654253244.gif (GIF Image, 473 × 360 pixels)
Vincenzo Salvia - Over the Pillars.webm
ForeignBlade - Cybernetic Implant Installation Procedure.mp4

2 (изменено: stealzy, 2015-02-24 13:57:24)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Это лучше делать расширением для браузера.
По-моему, Imagus от Deathamns решает вашу проблему.

3

Re: AHK: Зумирование изображений в браузере колесом мыши.

stealzy
Спасибо, но такого расширения нет для Firefox, и самое главное, все подобные расширения зумируют при помощи зажатия ПКМ и колеса мыши, и их невозможно инвертировать, чтобы изображение приближалось при прокручивании мыши вниз. Напомню, мне нужно не взрывное увеличение эскизов, как это делает маст хэв скрипт Mouseover Popup Image Viewer, а зумирование на отдельной странице.

Я много искал подобное и даже с помощью Custom Buttons пытался сделать, но похоже, из браузера, весьма сложно реализовать. А вот, насколько я знаю AutoHotkey, он способен на это запросто и с нужной функциональностью или я ошибаюсь?

4 (изменено: Drugoy, 2015-02-24 23:08:26)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Fx add-on: Image resizer. (ПКМ/ЛКМ) + тащить.

+ Esc

5

Re: AHK: Зумирование изображений в браузере колесом мыши.

Drugoy
Спасибо, весьма интересная штука, но функционал не совсем подходит. ПКМ занята функциональными жестами, а ЛКМ отключает Drug'n'Drop, и самое главное, отсутствует возможность зумирования .webm и .mp4.

Мне казалось переназначить клавиши по заголовку довольно просто, даже представляю код, но не разбираюсь с "регулярными выражениями" RegEx.

6

Re: AHK: Зумирование изображений в браузере колесом мыши.

Esc, RegEx'ы же будут давать ложные срабатывания: на странице с заголовком типа "Проблемы перевода в .webm" - нельзя будет прокрутить страницу, вместо этого будет работать зум страницы. Я уж молчу про то, что настройки зума будут сохраняться в about:config (для отдельных сайтов), отчего он будет и сам захламляться (но допустим, что не сильно), так ещё и при повторном заходе будет включаться старое значение зума, что будет уже бесить.
Ну и такой подход будет работать только для картинок и видео, открытых в новой вкладке, а правильный подход, когда контроль зума есть над любой картинкой и когда не надо ради её приближения открывать новую вкладку.
А ещё в конце заголовка у открытой картинки может быть приписка типа " - Scaled (51%)"

"iS)^.+\.(jpg|jpeg|png|gif)(\s\((jpeg|png|gif)\simage,\s\d+\s×\s\d+\spixels\))?(\s-\sscaled\s\(\d+%\))?$"
+
"iS)^.+\.(webm|mp4)$"
=
"iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif)(\s\((jpeg|png|gif)\simage,\s\d+\s×\s\d+\spixels\))?(\s-\sscaled\s\(\d+%\))?)$"

+ Esc

7

Re: AHK: Зумирование изображений в браузере колесом мыши.

Drugoy
Да, возможны ложные срабатывания, нужно выяснять опытным путём, хотя кажется, они будут на уровне погрешности, обычно же в конце заголовков пишется название сайта. Тем более about:config у меня автоматически очищается.

Именно для вкладок это и требуется, для встроенных картинок же есть Mouseover Popup Image Viewer, в нём как раз зумирование отлично реализовано. Когда-то вообще приходилось все изображения открывать в новой вкладке для зума, тогда и появилась идея такого скрипта.

Спасибо большое, попробую создать скрипт, правда я чайник в этом, нет ли случайно на памяти похожего скрипта с RegEx-ами?

8

Re: AHK: Зумирование изображений в браузере колесом мыши.

Не могу понять, как всётаки всё это совместить с RegEx. И можно ли еще делать одинарный клик ЛКМ при появлении окна с webm/mp4 заголовком?

loop
{
SetTitleMatchMode, RegEx 
WinWaitActive,  (Title, "iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif)(\s\((jpeg|png|gif)\simage,\s\d+\s×\s\d+\spixels\))?(\s-\sscaled\s\(\d+%\))?)$", Title)
    {
      WheelDown::^+
      WheelUp::^-
    }
}

9 (изменено: Irbis, 2015-02-26 13:06:06)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Хоткеи в цикле задавать не надо, и SetTitleMatchMode достаточно один раз, в начале скрипта.
Предложенный выше шаблон для REgEx в Опере не срабатывет, привел более простой вариант (переменная Match). Шаблон для webm/mp4 в Match1.

SetTitleMatchMode, RegEx
Match = iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif))
Match1 = iS)^.+\.(webm|mp4)

loop {
   WinWaitActive, %Match1%
   Click ; или Click X, Y - с координатами
   WinWaitNotActive, %Match1%
}

#If WinActive(Match)
WheelDown::^+
WheelUp::^-
#If
+ Esc

10

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Спасибо огромное, всё работает, как же мне этого не хватало. Вот только как правильно добавить ahk_class Firefox, чтобы только в нём срабатывало?

Потому что реагирует и на MPC-BE, и регулировка зума происходит еще и над панелью задач, хотя там назначена регулировка звука колесиком мыши.

11 (изменено: DD, 2015-02-26 15:14:06)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Так, кажись:

GroupAdd, MozillaBrows, ahk_class MozillaUIWindowClass ; FF
GroupAdd, MozillaBrows, ahk_class MozillaWindowClass   ; FF

SetTitleMatchMode, RegEx
Match = iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif))
Match1 = iS)^.+\.(webm|mp4)

loop {
   WinWaitActive, %Match1%
   Click ; или Click X, Y - с координатами
   WinWaitNotActive, %Match1%
}

#If WinActive(Match) && WinActive("ahk_group MozillaBrows")
WheelDown::^+
WheelUp::^-
#If

12

Re: AHK: Зумирование изображений в браузере колесом мыши.

DD
А у Вас работает корректно? У меня ничего не изменилось.

13 (изменено: Irbis, 2015-02-26 16:54:40)

Re: AHK: Зумирование изображений в браузере колесом мыши.

SetTitleMatchMode, RegEx
GroupAdd, MozillaBrows, ahk_class MozillaUIWindowClass ; FF
GroupAdd, MozillaBrows, ahk_class MozillaWindowClass   ; FF
GroupAdd, MozillaBrows, ahk_class OperaWindowClass ; тест Opera, можно убрать
Match = iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif))
Match1 = iS)^.+\.(webm|mp4)

loop {
   WinWaitActive, %Match1% AHK_group MozillaBrows
   sleep 1000 ; 1c
   Click ; или Click X, Y - с координатами
   WinWaitNotActive, %Match1% AHK_group MozillaBrows
}

#If WinActive(Match . "*AHK_group MozillaBrows") && OverActive()
WheelDown::^+
WheelUp::^-
#If

OverActive() {
   MouseGetPos,,,id
   return (id = WinExist("A"))
}
+ Esc

14

Re: AHK: Зумирование изображений в браузере колесом мыши.

Esc пишет:

ahk_class Firefox

Может у вас на Мозилле этот класс стоит. Попробуйте добавить.

15

Re: AHK: Зумирование изображений в браузере колесом мыши.

ahk_class Firefox

Такого класса нет, по-моему.

16

Re: AHK: Зумирование изображений в браузере колесом мыши.

Тоже такого не видел.

17

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Этот вариант работает, спасибо, только нужно убрать тильды ~, а то зум вместе со скроллом происходит. Класс MozillaWindowClass верен. Единственное чего для идеала не хватает, это 1 секунды задержки перед кликом по webm/mp4, потому что иногда страница не успевает загрузиться, поможете?

18

Re: AHK: Зумирование изображений в браузере колесом мыши.

- Убрал;
+ Добавил. ))
Тильды остались от прошлого варианта "обхода" регулировки громкости, затем переделал, а про них забыл.

19 (изменено: DD, 2015-02-26 17:02:03)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Вообще-то (это даже я знаю ), перед кликом нужно вписать:

Sleep, 1000

В справке такого добра ещё много

20

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Вот теперь идеал, спасибо огромное. Такой функционал в ФФ должен быть из коробки, это же по настоящему удобно, тем более скроллинг не нужен, пока изображение меньше экрана, но хорошо, что есть Серый Форум и его участники.

DD
Я тоже знал, но не помнил, и почему-то думал SetTimer нужен. Справка мне слабовато помогает обычно, хотя я код и представляю, но правильно составить не могу. )

21

Re: AHK: Зумирование изображений в браузере колесом мыши.

Пожалуйста. ))
Не все приходит сразу, приходится учиться от простого к... чуть менее простому. Да и код не идеален, хотя бы из-за наличия Loop. Есть и другие варианты, более изощренные.

22

Re: AHK: Зумирование изображений в браузере колесом мыши.

Мне тоже вещь понравилась. Правда в моём very biggest скрипте код не срабатывает.

А кстати, не будет ли противоречием одновременное существование в скрипте двух команд: SetTitleMatchMode 2 и SetTitleMatchMode, RegEx?

23 (изменено: DD, 2015-02-26 17:45:49)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis, а вот такой нескончаемый код, использующий сообщения от системы, уместно использовать вместо Loop? —

SetTitleMatchMode, RegEx
GroupAdd, MozillaBrows, ahk_class MozillaUIWindowClass ; FF
GroupAdd, MozillaBrows, ahk_class MozillaWindowClass   ; FF
GroupAdd, MozillaBrows, ahk_class OperaWindowClass ; тест Opera, можно убрать

Match = iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif))
Match1 = iS)^.+\.(webm|mp4)


#If WinActive(Match . "*AHK_group MozillaBrows") && OverActive()
WheelDown::^+
WheelUp::^-
#If

OverActive() {
   MouseGetPos,,,id
   return (id = WinExist("A"))
}


OnWindowActivated("AHK_group MozillaBrows", "BRS_Activated")
return

BRS_Activated(hWnd) ; эта процедура будет выполнятся при каждой активации окна
{
   Soundplay *48  ;Exclamation
   WinWaitActive, %Match1% AHK_group MozillaBrows
   sleep 1000 ; 1c
   Click ; или Click X, Y - с координатами
   WinWaitNotActive, %Match1% AHK_group MozillaBrows
   return
}

; ниже — служебные функции которые уместно держать в отдельном файле и в скрипт включать посредством #Include
OnWindowActivated(winTitle, procName = "", maxThreads = 1)
{
    global ShellHookActionList
 
    IsObject(ShellHookActionList) || ShellHookActionList := Object()
    IsObject(ShellHookActionList[4]) || ShellHookActionList[4] := Object()
 
    if procName
        ShellHookActionList[4][winTitle] := procName
    else
        return ShellHookActionList[4][winTitle]
 
    if !OnMessage(DllCall("RegisterWindowMessage", "str", "SHELLHOOK")) {
        DllCall("RegisterShellHookWindow", "UInt", A_ScriptHwnd)
        OnMessage(DllCall("RegisterWindowMessage", "str", "SHELLHOOK"), "ShellProc", maxThreads)
    }
}

ShellProc(wParam, lParam)
{
    global ShellHookActionList
 
    if ShellHookActionList.HasKey(wParam) {
        for winTitle, procName in ShellHookActionList[wParam] {
            WinGet, hWndList, List, %winTitle%
            loop %hWndList%
                continue
            until hWndList%A_Index% = lParam && found := true
 
            if (found)
                %procName%(lParam), found := false
        }
    }
    return
}

24 (изменено: Esc, 2015-02-27 02:32:41)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
У меня много скриптов с loop работают уже почти год, вроде бы проблем не обнаружено, и утечек памяти.

25 (изменено: Irbis, 2015-02-26 20:04:00)

Re: AHK: Зумирование изображений в браузере колесом мыши.

DD, уместно, если работает. Несколько замечаний:

- Работать в таком виде не будет, так как строка

OnWindowActivated("AHK_group MozillaBrows", "BRS_Activated")

находится в блоке хоткеев, а не в секции автовыполнения.

- В функции BRS_Activated() WinWait'ы лишние, ведь функция вызывается и так при активации окна.
Лучше использовать IfWinActive, <шаблон>

- Метод в данном случае сработает только при переключении между разными окнами, а для системы переход по вкладкам браузера является работой в одном окне -> выводы сделай сам. ))

- Где же OnExit, Exit (из оригинального скрипта)? Хук сам по себе не снимается при выходе из скрипта.

<...> А кстати, не будет ли противоречием одновременное существование в скрипте двух команд: SetTitleMatchMode 2 и SetTitleMatchMode, RegEx?

Будет. Последнее использование будет определять режим, узнать текущий режим поможет встроенная переменная A_TitleMatchMode. Если есть конфликт, лучше все шаблоны привести к виду RegEx, так как с его помощью можно заменить режимы 1-2-3, а вот наоборот - нет.


Esc, неплохо.

+ DD

26

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis пишет:

- Метод в данном случае сработает только при переключении между разными окнами, а для системы переход по вкладкам браузера является работой в одном окне -> выводы сделай сам. ))

Конфуз, однако Зато теперь понял, почему этого формата скрипт на диалоговое окно не реагирует. Спасибо за расклад.

27

Re: AHK: Зумирование изображений в браузере колесом мыши.

На смену заголовков есть сообщение - http://forum.script-coding.com/viewtopi … 169#p84169.

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru Telegram: https://t.me/sergiol982
Win10x64 AhkSpy, Hotkey, ClockGui

28

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Быть может еще улучшим твик? Два варианта на выбор.)

1) Всегда интересовало, можно ли, с помощью AutoHotkey, сделать навигацию по изображению больше экрана, с помощью зажатия левой кнопки мыши и движения, как это сделано в IrfanView?

2) Или просто выделить часть экрана (по координатам), в которой работает обычный скроллинг.

29

Re: AHK: Зумирование изображений в браузере колесом мыши.

Изображение открыто в браузере? По поводу FF помочь не смогу, в Опере скролл большого изображения при помощи ЛКМ - по умолчанию. Второй пункт не совсем понял, поясни.

30

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Да, в браузере, ого, в опере молодцы, а то я постоянно интуитивно пытаюсь двигать изображение по ЛКМ, нажатие СКМ как-то не очень удобно. Но сделать это, с помощью AutoHotkey, наверное, невозможно или код будет километровый.

А второй пункт прост, насколько я знаю, в AutoHotkey это легко сделать, выделить, например, квадрат 300x300 пикселей в любом местоположении окна, и при нахождении курсора в нём, изменить поведение любых кнопок, в нашем случае, вернуть скролл. Так здесь люди делали регулировку громкости по левому краю браузера.

31 (изменено: Irbis, 2015-02-27 21:22:33)

Re: AHK: Зумирование изображений в браузере колесом мыши.

По СКМ изображения перетаскиваются? Тогда изменения составят пару строк.
В коде из #13 добавить обмен действий СКМ и ЛКМ при открытии картинки. Побочный эффект - картинку можно закрыть одиночным щелчком ЛКМ по заголовку вкладки. ))

; < остальной код >
;
#If WinActive(Match . "*AHK_group MozillaBrows") && OverActive()
WheelDown::^+
WheelUp::^-
LButton::MButton
MButton::LButton ; на всякий случай ))
#If
;
; < остальной код > 

Пункт 2 возможен, надо только конкретики, какие клавиши должны изменять свое поведение при нахождении курсора за пределами (в пределах) области (X1,Y1 x X2,Y2).

32

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Спасибо, но тут немного не то, в IrfanView при зажатии ЛКМ происходит как-бы щипок и вместо курсора "рука", а в Firefox, при нажатии СКМ, просто появляется "компас" и чем дальше курсор от него, тем быстрее скорость перемещения. Это два разных способа навигации. Но это, наверное, можно сделать только эмуляцией "руки", а это тонна кода.

По поводу второго, может быть лучше сделать, чтобы по координатам работал весь ваш скрипт? Т.е., например, зум работает только в области размером 1600x950 окна Firefox справа снизу (950px вертикально, чтобы не затрагивать вкладки), а 320x1040 слева, не изменяют своего поведения (скроллинг).

Простой пример такого кода, кстати, очень бы пригодился, в любом окне можно добавить удобные горячие клавиши на мышь, на не функциональные элементы интерфейса.

33 (изменено: serzh82saratov, 2015-02-28 11:01:54)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Было много раз, например - AHK: Множественные действия на левой и верхней границах экрана.
Там правда про относительные координаты, но под конкретные ещё проще. Разбиваем экран на четыре области:

CoordMode, Mouse

#If (Area := WhatArea())
LButton::
    If Area = 1
        ToolTip 1
    Else If Area = 2
        ToolTip 2
    Else If Area = 3
        ToolTip 3
    Else If Area = 4
        ToolTip 4 
    Return
#If
    
WhatArea()  {
    Static R := [[0,0,A_ScreenWidth/2,A_ScreenHeight/2]
                , [A_ScreenWidth/2,0,A_ScreenWidth,A_ScreenHeight/2]
                , [0,A_ScreenHeight/2,A_ScreenWidth/2,A_ScreenHeight]
                , [A_ScreenWidth/2,A_ScreenHeight/2,A_ScreenWidth,A_ScreenHeight]]
    MouseGetPos, X, Y 
    For K, V in R
        If (X >= V[1] && X <= V[3] && Y >= V[2] && Y <= V[4])
            Return K
} 
По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru Telegram: https://t.me/sergiol982
Win10x64 AhkSpy, Hotkey, ClockGui

34

Re: AHK: Зумирование изображений в браузере колесом мыши.

serzh82saratov, Irbis
Если кому не сложно, помогите пожалуйста готовым кодом, у меня всё-таки ничего не получилось. Окно нужно разделить на две половины, как на изображении и можно ли сделать, чтобы работало и в оконном режиме, нужны относительные координаты? Ниже код, которым пользуюсь.

#NoTrayIcon
SetTitleMatchMode, RegEx
GroupAdd, MozillaBrows, ahk_class MozillaUIWindowClass ; FF
GroupAdd, MozillaBrows, ahk_class MozillaWindowClass   ; FF
Match = iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif))
Match1 = iS)^.+\.(webm|mp4)

loop {
   WinWaitActive, %Match1% AHK_group MozillaBrows
   sleep 1000 ; 1c
   Click, 960, 550 ; или Click, X, Y - с координатами
   WinWaitNotActive, %Match1% AHK_group MozillaBrows
}

#If WinActive(Match . "*AHK_group MozillaBrows") && OverActive()
WheelDown::^+
WheelUp::^-
#If

OverActive() {
   MouseGetPos,,,id
   return (id = WinExist("A"))
}

http://i.imgur.com/K0B61V6.png

35 (изменено: Irbis, 2015-03-18 13:47:40)

Re: AHK: Зумирование изображений в браузере колесом мыши.

На  портативной версии FF протестировал такой вариант панорамирования картинок при помощи ЛКМ. +Разделение экрана
В функции OverActive() числа 80 и 150 задают, что верхние 80 пикселей (окна браузера), а также левая часть шириной 150 будут обрабатывать колесо и ЛКМ как обычно.
Переменная Pan определяет скорость перемещения, можно ее варьировать, т.к. при большом увеличении картинка быстрее "убегает" от курсора, при маленьком - может чуть запаздывать. По крайней мере, перемещение получилось реалистичней и удобней, на мой взгляд, чем существующее панорамирование средней кнопкой мыши.

#NoTrayIcon
SetTitleMatchMode, RegEx
Pan:=40, dir := ["{Right}","{Left}", "{Down}", "{Up}"]
GroupAdd, MozillaBrows, ahk_class MozillaUIWindowClass ; FF
GroupAdd, MozillaBrows, ahk_class MozillaWindowClass   ; FF
Match = iS)^.+\.((webm|mp4)|(jpg|jpeg|png|gif))
Match1 = iS)^.+\.(webm|mp4)

loop {
   WinWaitActive, %Match1% AHK_group MozillaBrows
   sleep 1000 ; 1c
   Click, 960, 550 ; или Click, X, Y - с координатами
   WinWaitNotActive, %Match1% AHK_group MozillaBrows
}

#If WinActive(Match . "*AHK_group MozillaBrows") && OverActive()
LButton::
MouseGetPos, x0, y0
While GetKeyState("LButton", "P"){
   MouseGetPos, x, y
   if (Abs(dx:=x-x0)>Pan) {
      SendInput % dir[(dx>0)+1]
      x0+=dx, dx:=0
   }
   if (Abs(dy:=y-y0)>Pan) {
      SendInput % dir[(dy>0)+3]
      y0+=dy, dy:=0
   }
   sleep 20
}Return

WheelDown::^+
WheelUp::^-
#If

OverActive(){
   MouseGetPos,WinX,WinY,id
   return (id = WinExist("A"))&(WinY>80)&(WinX>150) ; заменить на нужные величины
}
+ Esc

36

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Спасибо большое, скролл работает. Только вот панорамирование по ЛКМ нет, и клик по середине не происходит, а вообще интересно было бы попробовать такой вариант. )

37

Re: AHK: Зумирование изображений в браузере колесом мыши.

Хм.. Когда открыто большое изображение,  оно двигается стрелками клавиатуры влево-вправо, вверх-вниз?

38

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Да, наверное у меня что-то не так, раз у Вас работает, нужно разбираться.

А не могли бы Вы сделать простой код, в который я бы мог подставлять нужные приложения и переназначения, например, переместиться в точку скроллбара по СКМ=Shift+ЛКМ, как в Firefox. Два варианта, где можно было бы назначить определённый квадрат в программе и с относительными координатами.

http://i.imgur.com/wA53jvc.png

39

Re: AHK: Зумирование изображений в браузере колесом мыши.

C браузером будем разбираться, насчет последнего абзаца не совсем уловил, что нужно, и при чем тут NP++
Лучше по этому вопросу создать отдельную тему.

40

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Заработало, навигация по изображению с зажатой ЛКМ это просто фантастика, то чего так не хватало. Работает даже по диагонали, всё как положено.

Единственное не работает авто-клик на .webm,.mp4 и ЛКМ естественно, может быть переназначить СКМ=ЛКМ и авто-клик на неё назначить?

В этой теме всё подробно расписал : AHK: Мгновенный переход по скроллбару средней кнопкой мыши, как в FF..

41 (изменено: Esc, 2015-03-28 17:06:07)

Re: AHK: Зумирование изображений в браузере колесом мыши.

Irbis
Подскажите пожалуйста, как в этом скрипте переназначить СКМ на ЛКМ и сделать авто-клик по  .webm,.mp4 на СКМ, раз левая кнопка мыши это навигация по изображению.

Наверное, должно быть что-то в этом роде:

loop {
   WinWaitActive, %Match1% AHK_group MozillaBrows
   sleep 1000 ; 1c
   СКМ Click, 960, 550 ; или Click, X, Y - с координатами
   WinWaitNotActive, %Match1% AHK_group MozillaBrows
}

#If WinActive(Match . "*AHK_group MozillaBrows") && OverActive()
ЛКМ::СКМ
СКМ::ЛКМ
СКМ::
MouseGetPos, x0, y0
While GetKeyState("LButton", "P"){
   MouseGetPos, x, y
   if (Abs(dx:=x-x0)>Pan) {
      SendInput % dir[(dx>0)+1]
      x0+=dx, dx:=0
   }
   if (Abs(dy:=y-y0)>Pan) {
      SendInput % dir[(dy>0)+3]
      y0+=dy, dy:=0
   }
   sleep 20
}Return

42

Re: AHK: Зумирование изображений в браузере колесом мыши.

Esc, с каких пор у нас код выделяется тегом quote?

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

43

Re: AHK: Зумирование изображений в браузере колесом мыши.

teadrinker, а с каких пор в теге code стало возможным выделение цветом?

44

Re: AHK: Зумирование изображений в браузере колесом мыши.

teadrinker, Flasher
Да, именно, лишь для наглядности, так нельзя?

45

Re: AHK: Зумирование изображений в браузере колесом мыши.

Flasher пишет:

teadrinker, а с каких пор в теге code стало возможным выделение цветом?

В теге code невозможно, а почему вы спрашиваете? Для выделения текста в коде есть комментарии.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

46

Re: AHK: Зумирование изображений в браузере колесом мыши.

Esc пишет:

teadrinker, Flasher
Да, именно, лишь для наглядности, так нельзя?

Код по правилам форума выделяется тегом code, и никаким другим.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

47

Re: AHK: Зумирование изображений в браузере колесом мыши.

teadrinker
По-моему, это крайности. Я в разных местах всегда использовал тег quote именно для выделения цветом. И никто не жаловался, понимая, что другой альтернативы нет, а здесь с учётом одноцветного по умолчанию шрифта - тем более.

48

Re: AHK: Зумирование изображений в браузере колесом мыши.

teadrinker пишет:

Код по правилам форума выделяется тегом code, и никаким другим.

Хорошо, я исправил, просто цвет сразу бросается в глаза и моментально становится ясна суть проблемы.

49

Re: AHK: Зумирование изображений в браузере колесом мыши.

Flasher пишет:

teadrinker
По-моему, это крайности. Я в разных местах всегда использовал тег quote именно для выделения цветом. И никто не жаловался, понимая, что другой альтернативы нет, а здесь с учётом одноцветного по умолчанию шрифта - тем более.

Почему же нет? А упомянутые мной комментарии? Думаю, если каждый начнёт оформлять посты как-то по своему, исходя из своих соображений, хорошо не будет. Так что лучше придерживаться правил.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

50 (изменено: Flasher, 2015-03-28 17:28:54)

Re: AHK: Зумирование изображений в браузере колесом мыши.

teadrinker пишет:

А упомянутые мной комментарии?

Комментарии - да, но дольше и больше занимает места. Иногда выгодно разделение по группам с указанием, что выделено тем или иным цветом.

teadrinker пишет:

Так что лучше придерживаться правил.

В правилах можно дописать "за исключением отделения кода в цитату, когда высока необходимость выделить цветом, жирным или наклонным шрифтом определённые его части".

51

Re: AHK: Зумирование изображений в браузере колесом мыши.

Ну, хотите, поднимите эту тему Script-Coding.com community.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder