VBS: Вставка данный в открытый файл Excel

' Пример для сервера сценариев Windows
'
' ------------------------------------------------------------------------
'                     (C) Корпорация Microsoft, 1996-1998
'
' Вы имеете право, не требующее дополнительных лицензионных платежей, 
' на использование, изменение, воспроизведение и распространение файлов
' примеров (и любой измененной версии) любым способом, учитывая, что
' Корпорация Microsoft не предоставляет гарантий и обязательств, 
' а также не несет ответственности за любой из файлов примеров
' ------------------------------------------------------------------------
	
' Пример вывода свойств сервера сценариев Windows в Microsoft Excel.

L_Welcome_MsgBox_Message_Text    = "Пример вывода свойств сервера сценариев Windows в Microsoft Excel."
L_Welcome_MsgBox_Title_Text      = "Пример сервера сценариев Windows"
Call Welcome()
    

' ********************************************************************************
' *
' * Пример Excel
' *
Dim objXL
Set objXL = WScript.CreateObject("Excel.Application")

objXL.Visible = TRUE

objXL.WorkBooks.Add

objXL.Columns(1).ColumnWidth = 20
objXL.Columns(2).ColumnWidth = 30
objXL.Columns(3).ColumnWidth = 40

objXL.Cells(1, 1).Value = "Свойство"
objXL.Cells(1, 2).Value = "Значение"
objXL.Cells(1, 3).Value = "Описание"

objXL.Range("A1:C1").Select
objXL.Selection.Font.Bold = True
objXL.Selection.Interior.ColorIndex = 1
objXL.Selection.Interior.Pattern = 1 'xlSolid
objXL.Selection.Font.ColorIndex = 2

objXL.Columns("B:B").Select
objXL.Selection.HorizontalAlignment = &hFFFFEFDD ' xlLeft

Dim intIndex
intIndex = 2

Sub Show(strName, strValue, strDesc)
    objXL.Cells(intIndex, 1).Value = strName
    objXL.Cells(intIndex, 2).Value = strValue
    objXL.Cells(intIndex, 3).Value = strDesc
    intIndex = intIndex + 1
    objXL.Cells(intIndex, 1).Select
End Sub

'
' Вывод свойств WScript
'
Call Show("Name",            WScript.Name,           "Имя приложения")
Call Show("Version",         WScript.Version,        "Версия приложения")
Call Show("FullName",        WScript.FullName,       "Контекст приложения: полное имя")
Call Show("Path",            WScript.Path,           "Контекст приложения: только путь")
Call Show("Interactive",     WScript.Interactive,    "Состояние режима взаимодействия")


'
' Вывод аргументов командной строки.
'
Dim colArgs
Set colArgs = WScript.Arguments
Call Show("Arguments.Count", colArgs.Count, "Число аргументов командной строки")

For i = 0 to colArgs.Count - 1
    objXL.Cells(intIndex, 1).Value = "Arguments(" & i & ")"
    objXL.Cells(intIndex, 2).Value = colArgs(i)
    intIndex = intIndex + 1
    objXL.Cells(intIndex, 1).Select
Next



' ********************************************************************************
' *
' * Приветствие
' *
Sub Welcome()
    Dim intDoIt

    intDoIt =  MsgBox(L_Welcome_MsgBox_Message_Text, _
                      vbOKCancel + vbInformation,    _
                      L_Welcome_MsgBox_Title_Text )
    If intDoIt = vbCancel Then
        WScript.Quit
    End If
End Sub