1

Тема: AHK: Оверлейные часы

Здравствуйте дорогие форумчане
Не подскажите как сделать так что бы данные часы полностью игнорировались курсором?
Проблема:
При клике по часам "клик не проходит через них" то есть на рабочем столе я не могу кликнуть по ярлыку из-за часов.

Скрин:
http://prntscr.com/jsy85r

Код:

+ открыть спойлер
#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

ZeroX := (A_ScreenWidth // 1.2)
ZeroY := 0 ; (A_ScreenHeight // 100)

CustomColor = EEAA99 ; Может быть любого RGB цвета (ниже он будет сделан прозрачным).
Gui, 1:+AlwaysOnTop +LastFound +Owner -Caption +ToolWindow ; Опция +Owner мешает появлению кнопки на панели задач.
Gui, 1:Color, %CustomColor%
Gui, 1:Font, s18
; XX & YY служит для того, чтобы автоматически задать размер окна.
Gui, 1:Add, Text, vMyText cLime, XX YYYYY
; Делаем все пиксели этого цвета прозрачными, а сам текст - полупрозрачным (150):
WinSet, TransColor, %CustomColor% 200
SetTimer, UpdateOSD, 1000
Gosub, UpdateOSD ; Не ожидая таймера, делаем сразу первое обновление.
Gui, 1:Show, x%ZeroX% y%ZeroY% NoActivate NA
return

UpdateOSD:
GuiControl,, MyText, %A_Hour%:%A_Min%:%A_Sec% NoActivate NA
return

Спасибо откликнувшимся

2 (изменено: stealzy, 2018-06-09 19:07:20)

Re: AHK: Оверлейные часы

Gui, 1: +E0x20
Gui, 1: Font, s18 q3

3

Re: AHK: Оверлейные часы

stealzy
Через "WinSet" ?

4

Re: AHK: Оверлейные часы

Не сработает, можете проверить:

Gui, +AlwaysOnTop +LastFound +Owner -Caption +ToolWindow
Gui, +E0x20
Gui, Show, w300 h100

Потому, что E0x20 только для layered windows.
А вот так сработает:

Gui, +AlwaysOnTop +LastFound +Owner -Caption +ToolWindow +E0x20
WinSet, Transparent, 255
Gui, Show, w300 h100
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Skype dmitry_fiveg

5

Re: AHK: Оверлейные часы

А, прошу прощения, проглядел.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Skype dmitry_fiveg