AHK : Как обмениваться сообщениями между скриптами?

Спасибо что откликнулись!
Т.е. в скрипте приёмнике - OnMessage(0x4a, "Receive_WM_COPYDATA") 0x4a - задаёт имя сообщения, Receive_WM_COPYDATA - задаёт функцию которая будет вызвана при получении этого сообщения?

В скрипте отправителе - TargetScriptTitle = Receiver.ahk ahk_class AutoHotkey это вроде то, куда собственно отправлять. А если нет GUI? И Receiver.ahk указан без пути, т.е. скрипты должны лежать в одной папке, а если путь не может быть известен?
Так понял что сам посыл производит команда SendMessage из функции Send_WM_COPYDATA, а все танцы в ней вокруг обработки текста из InputBox.

Да, только 0x4a — это не имя, а уникальный код сообщения WM_COPYDATA.

По-крайней мере одно окно есть у всех AHK-скриптов. Изначально оно скрыто, его можно увидеть, сделав двойной клик по иконке скрипта в трее, или выполнив команду Open из трей-меню. В заголовке этого окна присутствует путь к файлу скрипта, соответственно и его название, поэтому чтобы обратиться к такому окну, достаточно названия, если указать SetTitleMatchMode 2.

Главные танцы в ней вокруг создания структуры CopyDataStruct, указатель(поинтер) на которую, собственно, и посылается.

WM_SETTEXT работает. Вот пример.

Получатель сообщения.

OnMessage(0xC, "GetText")

GetText(wParam, lParam, msg, hwnd)
{
    MsgBox, % StrGet(lParam)
    Return 1
}

Отправитель.

Receiver = D:\SomeScript.ahk    ; Путь к получателю.
DetectHiddenWindows, On

F11::
    SendMessage, 0xC, 0, "Hello, world!",, %Receiver%
Return

serzh82saratov
Да, должно быть 4 параметра, так положено. Про wParam написано, что он не используется, но числа в нём, оказывается, передать можно. Я и не знал.
В параметре msg будет код сообщения. В данном случае 0xC. Т.е. эту функцию GetText можно назначить как перехватчик для нескольких сообщений и по msg она определит, для какого сообщения вызвана. Hwnd — идентификатор окна, которому поступило сообщение.

Про несколько параметров вы верно мыслите. Можно в строку их соединить, а в получателе разделить. Можно и имя функции таким образом передать, которую нужно вызвать в получателе. Вот так, например.

Отправитель.

Receiver = D:\SomeScript.ahk
DetectHiddenWindows, On

F11::
    Params = Func1|Hello, world!|0x888
    SendMessage, 0xC, 0, &Params,, %Receiver%
Return

Получатель.

OnMessage(0xC, "GetText")

GetText(wParam, lParam, msg, hwnd)
{
    Params := StrGet(lParam)
    StringSplit, Param, Params, |
    MsgBox, Параметры GetText:`n%Param1%`n%Param2%`n%Param3%
    %Param1%(Param2, Param3)    ; Вызов функции по переданному имени.
    Return 1
}

Func1(p1, p2)
{
    MsgBox, Параметры Func1:`n%p1%`n%p2%
}

На самом деле не обязательно. Можно указывать меньше параметров, вплоть до того, который нужен. Т. е. если msg и hwnd не используются, можно указать только wParam и lParam:

OnMessage(0xC, "GetText")

GetText(wParam, lParam)
{
    Params := StrGet(lParam)
    StringSplit, Param, Params, |
    MsgBox, Параметры GetText:`n%Param1%`n%Param2%`n%Param3%
    %Param1%(Param2, Param3)    ; Вызов функции по переданному имени.
    Return 1
}

Func1(p1, p2)
{
    MsgBox, Параметры Func1:`n%p1%`n%p2%
}