XML/XSL: Обработка всех текстовых узлов всех тегов

<root>
  текст1
  <tag1>
    текст2
    <tag2>
      текст3
      <tag3/>
      текст4
    </tag2>
    текст5
  </tag1>
  текст6
  <tag4>
    текст7
    <tag5/>
    текст8
  </tag4>
  текст9
</root>

<p>root</p>
<p>текст1</p>
<p>текст6</p>
<p>текст9</p>
<p>tag1</p>
<p>текст2</p>
<p>текст5</p>
<p>tag2</p>
<p>текст3</p>
<p>текст4</p>
<p>tag4</p>
<p>текст7</p>
<p>текст8</p>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html" version="1.0" indent="yes" />
  <!-- формат выходных данных - html-документ, начиная каждый тег с новой строки -->

  <xsl:template match="/">
  <!-- для корня - чтобы 1 раз -->
    <style>
      .sn{color:navy;font-weight:bold}
      .sa{color:crimson;}
      .st{color:blue;}
      ul{list-style-type:none;margin:0;}
      li,ul ul{margin:3px 0 0 10px;}
    </style>
    <!-- прописали в начале -->
    <xsl:apply-templates />
    <!-- и корень же - на дальнейшую обработку -->
    <br />
    <!-- один раз в конце -->
  </xsl:template>

  <xsl:template match="*">
    <!-- для каждого узла -->
    <ul>
      <span class="sn">&lt;<xsl:value-of select="name()" />&gt;</span>
      <!-- сразу выводим имя узла -->
      <xsl:apply-templates select="@*" />
      <!-- на дальнейшую обработку: все атрибуты -->
      <xsl:apply-templates select="text()" />
      <!-- на дальнейшую обработку: все текстовые ноды -->
      <xsl:apply-templates select="*" />
      <!-- на дальнейшую обработку: все дочерние узлы - рекурсия -->
    </ul>
    <!-- результат обработки вернётся туда, откуда был вызван, т.е. -->
    <!-- окажется между тэгами <ul> и </ul>, и это рекурсивно -->
  </xsl:template>

  <xsl:template match="@*">
    <!-- для каждого атрибута -->
    <li>
      <span class="sa"><xsl:value-of select="name()" />=“</span>
      <!-- выводим имя= -->
      <span class="sv"><xsl:value-of select="." /></span>
      <!-- выводим значение -->
      <span class="sa">”</span>
    </li>
  </xsl:template>

  <xsl:template match="text()[normalize-space()]">
    <!-- для каждой непустой текстовой ноды -->
    <li>
      <span class="st">[Текст] “</span>
      <span class="sv"><xsl:value-of select="normalize-space()" /></span>
      <!-- точка - аргумент normalize-space(.) - означает текущий -->
      <!-- контент, поэтому можно без неё - по умолчанию будет он же -->
      <span class="st">”</span>
    </li>
    <!-- выводим [Текст] значение -->
  </xsl:template>

  <!-- в общем, больше ничего не делаем (пока) -->

</xsl:stylesheet>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="*">
  <!-- для тэгов -->
    <xsl:param name="indent" select="'&#10;'"/>
    <!-- задали параметр — начальный отступ (сначала это перенос строки) -->

    <xsl:value-of select="$indent"/>
    <!-- применили отступ перед тэгом -->
    <xsl:copy>
    <!-- копируем содержимое тэга (сам тэг — автоматически?) -->
      <xsl:copy-of select="@*" />
      <!-- атрибуты — как есть -->

      <xsl:apply-templates>
      <!-- рекурсия -->
        <xsl:with-param name="indent" select="concat($indent, '    ')"/>
        <!-- вложенные тэги — с новым значением отступа (+«табуляция») -->
      </xsl:apply-templates>

      <xsl:choose>
        <xsl:when test="*">
        <!-- если были вложенные тэги -->
          <xsl:value-of select="$indent"/>
          <!-- подвинуть закрывающий тэг (здесь отступ не увеличен) -->
        </xsl:when>
        <xsl:otherwise>
        <!-- если не было — закрывающий в той же строке, что и открывающий -->
          <xsl:text></xsl:text>
          <!-- чушь, но иначе всё равно переносит строку -->
        </xsl:otherwise>
      </xsl:choose>

    </xsl:copy>
  </xsl:template>

  <xsl:template match="comment()|processing-instruction()">
  <!-- для комментариев и инструкций процессора -->
    <xsl:param name="indent" select="''"/>
    <!-- задаём пустой параметр, всё равно будет передан правильный (with-param) -->
    <xsl:value-of select="$indent"/>
    <!-- отступ -->
    <xsl:copy />
    <!-- просто копируем (с отступом) -->
  </xsl:template>

  <xsl:template match="text()">
  <!-- для текстовых узлов -->
    <xsl:param name="indent" select="''"/>
    <!-- задаём пустой (см. выше) -->
    <xsl:value-of select="$indent"/>
    <!-- отступ -->
    <xsl:if test="normalize-space()!=''">
    <!-- если не пустой -->
      <xsl:copy-of select="normalize-space()" />
      <!-- копируем содержимое с нормализованными прбелами -->
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>