AHK: Отключить скрипт во время набора текста

^vk50::  ; Ctrl + P
	SetTimer, SendKey, % (i := !i) ? "On" : "Off"
	Return

SendKey:
	if !GetKeyState("Ctrl", "P")
		SendInput, {!}
	Return

#Persistent
ScriptName := "KeySender.ahk"  ; имя скрипта, который нужно поставить на паузу
BlockPeriod := 3000        ; время, на которое нужно остановить скрипт
Blocker.Init(ScriptName, BlockPeriod)
Return

class Blocker
{
	Init(ScriptName, time)  {
		this.ScriptName := ScriptName
		this.BlockTime := time
		this.UnBlock := this.UnBlockTimer.Bind(this)
		this.hHookKeybd := DllCall("SetWindowsHookEx"
			, Int, WH_KEYBOARD_LL := 13
			, Ptr, RegisterCallback("LowLevelKeyboardProc", "Fast")
			, Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr)
			, UInt, 0, Ptr)
	}
	Block()  {
		if !hWnd := this.GetScriptMainWindow()
			Return
		if !this.Blocked  {
			this.Blocked := 1
			WinMenuSelectItem, % "ahk_id" hWnd,, 1&, 5&
		}
		timer := this.UnBlock
		SetTimer, % timer, % "-" this.BlockTime
	}
	UnBlockTimer()  {
		WinMenuSelectItem, % "ahk_id" this.GetScriptMainWindow(),, 1&, 5&
		this.Blocked := 0
	}
	GetScriptMainWindow()  {
		SetTitleMatchMode, 2
		DetectHiddenWindows, On
		Return WinExist(this.ScriptName)
	}
}
	
LowLevelKeyboardProc(nCode, wParam, lParam)
{
	static LLKHF_INJECTED := 0x10, INJECTED
	flags := NumGet(lParam + 8, "UInt")
	INJECTED := (flags & LLKHF_INJECTED) >> 4
	SetTimer, EventHandling, -10
	Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
	
EventHandling:
   if !INJECTED
		Blocker.Block()
	Return
}

#Persistent
ScriptNames := ["KeySender.ahk", "KeySender2.ahk"]  ; имена скриптов, которые нужно завершить
Blocker.Init(ScriptNames)
Return

class Blocker
{
	Init(ScriptNames)  {
		this.ScriptNames := ScriptNames
		this.hHookKeybd := DllCall("SetWindowsHookEx"
			, Int, WH_KEYBOARD_LL := 13
			, Ptr, RegisterCallback("LowLevelKeyboardProc", "Fast")
			, Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr)
			, UInt, 0, Ptr)
	}
	Terminate()  {
		SetTitleMatchMode, 2
		DetectHiddenWindows, On
		for k, v in this.ScriptNames
			if WinExist(v)
				WinClose
	}
}
	
LowLevelKeyboardProc(nCode, wParam, lParam)
{
	static LLKHF_INJECTED := 0x10, INJECTED
	flags := NumGet(lParam + 8, "UInt")
	INJECTED := (flags & LLKHF_INJECTED) >> 4
	SetTimer, EventHandling, -10
	Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
	
EventHandling:
   if !INJECTED
		Blocker.Terminate()
	Return
}

#Persistent
ScriptNames := ["KeySender.ahk", "KeySender2.ahk"]  ; имена скриптов, которые нужно завершить
Blocker.Init(ScriptNames)
Return

class Blocker
{
	Init(ScriptNames)  {
		this.ScriptNames := ScriptNames
		this.oWMI := ComObjGet("winmgmts:")
		this.hHookKeybd := DllCall("SetWindowsHookEx"
			, Int, WH_KEYBOARD_LL := 13
			, Ptr, RegisterCallback("LowLevelKeyboardProc", "Fast")
			, Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr)
			, UInt, 0, Ptr)
	}
	Terminate()  {
		SetTitleMatchMode, 2
		DetectHiddenWindows, On
		for k, name in this.ScriptNames
			if WinExist(name) && (this.GetLifeTime(name) > 2)  ; закрываем процесс скрипта, если он был создан более двух секунд назад
				WinClose
	}
	GetLifeTime(name)  {
		WinGet, PID, PID, % name
		LifeTime -= this.oWMI.Get("Win32_Process.Handle=" PID).CreationDate, s
		Return LifeTime
	}
}
	
LowLevelKeyboardProc(nCode, wParam, lParam)
{
	static LLKHF_INJECTED := 0x10, INJECTED, msg
		  , oMsg := {0x100: "WM_KEYDOWN", 0x101: "WM_KEYUP", 0x104: "WM_SYSKEYDOWN", 0x105: "WM_SYSKEYUP"}
	msg  	:= wParam
	flags := NumGet(lParam + 8, "UInt")
	INJECTED := (flags & LLKHF_INJECTED) >> 4
	SetTimer, EventHandling, -10
	Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
	
EventHandling:
   if InStr(oMsg[msg], "DOWN") && !INJECTED
		Blocker.Terminate()
	Return
}