AHK: выгрузка результатов поиска

var := "ёлка"

ComObjError(False)
oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("http://google.com/#q=" URIEncode(var))
While !InStr(oIE.document.documentElement.OuterHtml, "class=""r""")
{
   if InStr(oIE.document.documentElement.OuterHtml, "<div class=""med card-section"">")
   {
      msgbox Ничего не нашлось
      ExitApp
   }
   Sleep 100
}
rElements := OIE.document.getElementsByClassName("r")
loop % rElements.Length
{
   aElement := rElements[A_Index-1].getElementsByTagName("a")
   url := aElement[0].href
   urlList .= url . "`n"
}
msgbox % urlList
return


URIEncode(Str)
{
   b_Format:=A_FormatInteger
   SetFormat, IntegerFast, H
   Loop, % StrPutVar(Str, Var, "UTF-8")
   {
      Ch:=NumGet(Var, A_Index-1, "UChar")
      If Ch=0
         Break
      If (Ch>0x7f Or Ch<0x30 Or Ch=0x3d)
         s.="%"((StrLen(c:=SubStr(Ch, 3))<2) ? "0"c:c)
      else
         s.=Chr(Ch)
   }
   SetFormat, IntegerFast, % b_Format
   Return, s
}

StrPutVar(string, ByRef var, encoding = "CP0")
{
    ; Ensure capacity.
    VarSetCapacity( var, StrPut(string, encoding)
        ; StrPut returns char count, but VarSetCapacity needs bytes.
        * ((encoding="utf-16"||encoding="cp1200") ? 2 : 1) )
    ; Copy or convert the string.
    return StrPut(string, &var, encoding)
}

C:\Windows\SysWOW64\wscript.exe C:\ScriptName.vbs