1 (изменено: NonameDayz, 2013-03-30 15:53:41)

Тема: AHK: Dоtа 2 Iпvokеr

Итак релиз скрипта с интерфейсом на инвокера.

Возможности:
Изменение хоткеев через интерфейс скрипта.
При использовании ghоst wаlk или ForgеSрirit автоматически кaстyетcя.


Системные кнопки:
F11 - отключает хоткеи.
F10 - перезапускает скрипт.

Запрещены кнопки как хоткеи: QWERDF
http://rghost.ru/44895912/thumb.png

GoSub, GeoLoc
Gosub, LoadIni
GoSub, FileInstaller
GoSub, LoadGui
Return

#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
Process, Priority, , High ;

F10::reload
F11::suspend

HotkeyCheck:

Gui, Submit, NoHide

if (%A_GuiControl% = "Q") || (%A_GuiControl% = "W") || (%A_GuiControl% = "E") || (%A_GuiControl% = "R")|| (%A_GuiControl% = "D")|| (%A_GuiControl% = "F"){
    GuiControl,, %A_GuiControl%
    return
}

for i in Array{
    if  (Array[i]!="") && (%A_GuiControl% = Array[i]) {
        GuiControl,, %A_GuiControl%
        MsgBox, 48, Внимание, Данная кнопка уже используеться!
        Gui, Submit, NoHide
    }
}        

Gosub, SaveIni

Return

ButtonClear:
GuiControl,, ColdSnap
GuiControl,, GhostWalk
GuiControl,, IceWall
GuiControl,, Emp
GuiControl,, Tornado
GuiControl,, Alacrity
GuiControl,, SunStrike
GuiControl,, ForgeSpirit
GuiControl,, Meteor
GuiControl,, DeafeningBlast
Gui, Submit, NoHide
Gosub, SaveINI
Return

ButtonStart:

for i in Array{
    if  (Array[i]=""){
    MsgBox, 16, Ошибка, Для запуска скрипта заполните все поля!
    Return
    }
}

Hotkey, %Tornado%, Tornado
Hotkey, %ColdSnap%, ColdSnap
Hotkey, %GhostWalk%, GhostWalk
Hotkey, %IceWall%, IceWall
Hotkey, %Emp%, Emp
Hotkey, %Tornado%, Tornado
Hotkey, %Alacrity%, Alacrity
Hotkey, %SunStrike%, SunStrike
Hotkey, %ForgeSpirit%, ForgeSpirit
Hotkey, %Meteor%, Meteor
Hotkey, %DeafeningBlast%, DeafeningBlast
Return

GhostWalk:
Send, QQWRWWW
Sleep 400
Send D
return


Tornado:
Send, WWQR
return

Emp:
Send, WWWR
return

DeafeningBlast: 
Send, QWER
return

SunStrike: 
Send, EEER
return

Meteor: 
Send, EEWR
return

ColdSnap: 
Send, QQQR
return

IceWall: 
Send, QQER
Return

ForgeSpirit: 
Send, EEQR
Sleep 400
Send D
Return

Alacrity:
Send, WWER
Return

GuiClose:
ExitApp

SaveINI:
IniWrite, %ColdSnap%, %A_ScriptDir%\config.ini, Skills, ColdSnap
IniWrite, %GhostWalk%, %A_ScriptDir%\config.ini, Skills, GhostWalk
IniWrite, %IceWall%, %A_ScriptDir%\config.ini, Skills, IceWall
IniWrite, %Emp%, %A_ScriptDir%\config.ini, Skills, Emp
IniWrite, %Tornado%, %A_ScriptDir%\config.ini, Skills, Tornado
IniWrite, %Alacrity%, %A_ScriptDir%\config.ini, Skills, Alacrity
IniWrite, %SunStrike%, %A_ScriptDir%\config.ini, Skills, SunStrike
IniWrite, %ForgeSpirit%, %A_ScriptDir%\config.ini, Skills, ForgeSpirit
IniWrite, %Meteor%, %A_ScriptDir%\config.ini, Skills, Meteor
IniWrite, %DeafeningBlast%, %A_ScriptDir%\config.ini, Skills, DeafeningBlast
Array := [ColdSnap, GhostWalk, IceWall, Emp, Tornado, Alacrity, SunStrike, ForgeSpirit, Meteor, DeafeningBlast]
Return

LoadINI:
IniRead, ColdSnap, %A_ScriptDir%\config.ini, Skills, ColdSnap
IniRead, GhostWalk, %A_ScriptDir%\config.ini, Skills, GhostWalk
IniRead, IceWall, %A_ScriptDir%\config.ini, Skills, IceWall
IniRead, Emp, %A_ScriptDir%\config.ini, Skills, Emp
IniRead, Tornado, %A_ScriptDir%\config.ini, Skills, Tornado
IniRead, Alacrity, %A_ScriptDir%\config.ini, Skills, Alacrity
IniRead, SunStrike, %A_ScriptDir%\config.ini, Skills, SunStrike
IniRead, ForgeSpirit, %A_ScriptDir%\config.ini, Skills, ForgeSpirit
IniRead, Meteor, %A_ScriptDir%\config.ini, Skills, Meteor
IniRead, DeafeningBlast, %A_ScriptDir%\config.ini, Skills, DeafeningBlast
Array := [ColdSnap, GhostWalk, IceWall, Emp, Tornado, Alacrity, SunStrike, ForgeSpirit, Meteor, DeafeningBlast]
Return

LoadGui:
Gui, Add, Picture, x300 y0 w150 h80 , %A_ScriptDir%\picture\icon.jpg
Gui, Add, Picture, x100 y110 w80 h80 , %A_ScriptDir%\picture\ability1.jpg
Gui, Add, Picture, x100 y200 w80 h80 , %A_ScriptDir%\picture\ability2.jpg
Gui, Add, Picture, x100 y290 w80 h80 , %A_ScriptDir%\picture\ability3.jpg
Gui, Add, Picture, x100 y380 w80 h90 , %A_ScriptDir%\picture\ability4.jpg
Gui, Add, Picture, x250 y110 w80 h80 , %A_ScriptDir%\picture\ability5.jpg
Gui, Add, Picture, x250 y200 w80 h80 , %A_ScriptDir%\picture\ability6.jpg
Gui, Add, Picture, x250 y290 w80 h80 , %A_ScriptDir%\picture\ability7.jpg
Gui, Add, Picture, x250 y380 w80 h90 , %A_ScriptDir%\picture\ability8.jpg
Gui, Add, Picture, x400 y110 w80 h80 , %A_ScriptDir%\picture\ability9.jpg
Gui, Add, Picture, x400 y200 w80 h80 , %A_ScriptDir%\picture\ability10.jpg
Gui, Add, Picture, x400 y290 w80 h80 , %A_ScriptDir%\picture\ability11.jpg
Gui, Add, Picture, x400 y380 w80 h90 , %A_ScriptDir%\picture\ability12.jpg
Gui, Add, Picture, x550 y110 w80 h80 , %A_ScriptDir%\picture\ability13.jpg
Gui, Add, Picture, x550 y200 w80 h80 , %A_ScriptDir%\picture\ability14.jpg
gui, font, w700 s15, Times New Roman
Gui, Add, Text, x70 y130 w20 h30 , Q
Gui, Add, Text, x70 y220 w20 h30 , W
Gui, Add, Text, x70 y310 w20 h30 , E
Gui, Add, Text, x70 y410 w20 h30 , R
gui, font,,
Gui, Add, Hotkey, vColdSnap gHotkeyCheck x185 y130 w60 h30 , %ColdSnap%
Gui, Add, Hotkey, vGhostWalk gHotkeyCheck x185 y220 w60 h30 , %GhostWalk%
Gui, Add, Hotkey, vIceWall gHotkeyCheck x185 y310 w60 h30 , %IceWall%
Gui, Add, Hotkey, vEmp gHotkeyCheck x185 y410 w60 h30 , %Emp%
Gui, Add, Hotkey, vTornado gHotkeyCheck x335 y130 w60 h30 , %Tornado%
Gui, Add, Hotkey, vAlacrity gHotkeyCheck x335 y220 w60 h30 , %Alacrity%
Gui, Add, Hotkey, vSunStrike gHotkeyCheck x335 y310 w60 h30 , %SunStrike%
Gui, Add, Hotkey, vForgeSpirit gHotkeyCheck x335 y410 w60 h30 , %ForgeSpirit%
Gui, Add, Hotkey, vMeteor gHotkeyCheck x485 y130 w60 h30 , %Meteor%
Gui, Add, Hotkey, vDeafeningBlast gHotkeyCheck x485 y220 w60 h30 , %DeafeningBlast%
Gui, Add, Button, x222 y550 w100 h30 , Start
Gui, Add, Button, x400 y550 w100 h30 , Clear
; Generated using SmartGUI Creator 4.0
Gui, Show, x600 y84 h600 w700, MyDota2Script
Return

GeoLoc:
URL := "https://sites.google.com/site/nonamedayz/"
goURL := UrlDownloadToVar(URL)

UrlDownloadToVar(URL, UserAgent = "")
{
   WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
   WebRequest.Open("GET", Url)
   UserAgent ? WebRequest.Option(WinHttpRequestOption_UserAgentString := 0) := UserAgent
   WebRequest.Send()
    return 
}
Return

FileInstaller:
FileCreateDir, Picture
FileInstall, E:\AutoHotkey\picture\ability1.jpg, %A_WorkingDir%\picture\ability1.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability2.jpg, %A_WorkingDir%\picture\ability2.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability3.jpg, %A_WorkingDir%\picture\ability3.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability4.jpg, %A_WorkingDir%\picture\ability4.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability5.jpg, %A_WorkingDir%\picture\ability5.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability6.jpg, %A_WorkingDir%\picture\ability6.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability7.jpg, %A_WorkingDir%\picture\ability7.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability8.jpg, %A_WorkingDir%\picture\ability8.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability9.jpg, %A_WorkingDir%\picture\ability9.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability10.jpg, %A_WorkingDir%\picture\ability10.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability11.jpg, %A_WorkingDir%\picture\ability11.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability12.jpg, %A_WorkingDir%\picture\ability12.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability13.jpg, %A_WorkingDir%\picture\ability13.jpg, 0
FileInstall, E:\AutoHotkey\picture\ability14.jpg, %A_WorkingDir%\picture\ability14.jpg, 0
FileInstall, E:\AutoHotkey\picture\icon.jpg, %A_WorkingDir%\picture\icon.jpg, 0
return

Скачать:
http://rghost.ru/44896097

Отчет по вирусам:
https://www.virustotal.com/ru/file/314a … 364644350/

2 (изменено: serzh82saratov, 2013-03-31 10:58:58)

Re: AHK: Dоtа 2 Iпvokеr

Тяжело получилось, и кнопок не видно, и не все назначить можно.

Попробуйте такой вариант:

+ открыть спойлер


#SingleInstance force 
#Include HotkeyUserFunc.ahk
Menu, Tray, Add, Настройки
Menu, Tray, Default, Настройки

Global Action := "ColdSnap|GhostWalk|IceWall|Emp|Tornado|Alacrity|SunStrike|ForgeSpirit|Meteor|DeafeningBlast"
Hotkey, IfWinActive, ahk_class Notepad
Loop, Parse, Action, | 
    Hotkey, % IniRead("Hotkey",A_LoopField), % RegExReplace(A_LoopField, A_Space, "_"), UseErrorLevel 
Hotkey, IfWinActive
Return

Настройки:
    Gui, Font, s10
    Gui, Color, 2F4F4F
    Gui, Add, Edit, w300 y280 Center ReadOnly vEdit -Background
    Gui, Add, DropDownList, vDropDownList gDropDownList xp yp+34 w120 Choose1 w200, % Action
    Gui, Add, Button, gAllView xp+210 yp hp, ???
    Gui, Add, Button, xp+50 yp hp gCleanAll, Del
    Gui, Add, Picture, x40 y22 vMyPic
    Gui, Show, w320 h350, Hotkeys
    HF_HotkeyUserFunc("ON","MyNameFunc")
DropDownList:
    GuiControlGet, DropDownList 
    GuiControl,, MyPic, *w240 *h-1 %DropDownList%.jpg
    D := HF_HotkeyUserRead(DropDownList,"Hotkey","INIFile.ini") , HF_KeyName := HF_Hotkey := HF_PR_Result := ""
    GuiControl,, Edit, %  D = "" ? "Нет" : D
    Return

MyNameFunc(Mod, KeyName, Prefix, Hotkey, VkCode, ThisKey)   {
    Global 
    If (Mod KeyName ~= "^(Q|W|E|R|D|F)$")
        Return ToolTip("Кнопку """ KeyName """ нельзя использовать`nбез модификатора") , HF_KeyName := HF_Hotkey := HF_PR_Result := ""
    If (Prefix Hotkey <> "" && Exist := ExistKey(Prefix Hotkey))
    {
        If (Exist = DropDownList)
            Return HF_KeyName := HF_Hotkey := HF_PR_Result := ""
        If Mod <>
            GuiControl,, Edit, % "Нет"   
        Return ToolTip("Кнопка " Mod KeyName "`nуже назначена на " Exist) , HF_KeyName := HF_Hotkey := HF_PR_Result := ""
    }         
    GuiControl,, Edit, % Mod KeyName = "" ? "Нет" : Mod KeyName
    IniWrite, % Prefix Hotkey, INIFile.ini, Hotkey, % DropDownList
}
HF_WinStatus(Stat)     {
    Gui, +Lastfound
    WinSet, Transparent, % Stat ? "Off" : 170
}
IniRead(Section, Key)     {
    IniRead, Var, INIFile.ini, % Section, % Key, % A_Space
    Return Var
}
ExistKey(Key)    {  
    Loop, Parse, Action, | 
        If (IniRead("Hotkey",A_LoopField) = Key)  
            Return A_LoopField   
        Return False
}    
ToolTip(Tip)    {
    ToolTip, % Tip, 3, 32   
    SetTimer, ToolTipOff, 1000
    Return
    ToolTipOff:
        SetTimer, ToolTipOff, Off 
        ToolTip
        Return
}
CleanAll:
    IniDelete, INIFile.ini, Hotkey
    GuiControl,, Edit, % "Нет" , HF_KeyName := HF_Hotkey := HF_PR_Result := ""
    Return

AllView:
    Tip =
    Loop, Parse, Action, | 
        Tip .= IniRead("Hotkey",A_LoopField) = "" ? "" : A_LoopField " -> " HF_HotkeyUserRead(IniRead("Hotkey",A_LoopField)) "`n"  
    ToolTip, % Tip = "" ? "Ничего не назначено" : Tip, 3, 32
    KeyWait, LButton, D
    ToolTip
    Return

GuiClose:
    Reload
    Return

    ; ------------------- Action -------------------

ColdSnap:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
GhostWalk:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
IceWall:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
Emp:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
Tornado:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
Alacrity:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
SunStrike:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
ForgeSpirit:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
Meteor:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return
DeafeningBlast:
    TrayTip % "Действие """ A_ThisLabel """ по кнопке:", % "`n" HF_HotkeyUserRead( A_ThisHotkey), 1, 1
    Return

Приложенную библиотеку HotkeyUserFunc.ahk (описание) положить в папку скрипта.
Картинки в папке переименовать в имена подпрограмм "ColdSnap|GhostWalk|IceWall|Emp|Tornado|Alacrity|SunStrike|ForgeSpirit|Meteor|DeafeningBlast".
После старта кликнуть по иконке в трее 2 раза, появится окно.
После ввода хоткеев закрыть окно.
В 7-ой строке заменить "ahk_class Notepad" на окно игры, чтоб хоткеи работали в ней.

Если что-то заинтересует, могу прокомментировать.

Post's attachments

HotkeyUserFunc.ahk 7.19 kb, 29 downloads since 2013-03-30 

You don't have the permssions to download the attachments of this post.
По вопросам возмездной помощи пишите письма
E-Mail: serzh82saratov@mail.ru
OS: Win7x64, AutoHotkey_L v1.1.26.01 (Unicode 32-bit).

3

Re: AHK: Dоtа 2 Iпvokеr

Я писал без использования библиотек.
Прочему вы считаете мой скрипт тяжёлым?

В изложенном вами скриптом нет проверки на дубликаты. Можно все скилы назначить на одну и туже кнопку...

4 (изменено: serzh82saratov, 2013-03-30 18:56:06)

Re: AHK: Dоtа 2 Iпvokеr

Я писал без использования библиотек.

Можно сказать я тоже, либа то моя. Можно тоже самое и без неё сделать, но не айс будет.

Прочему вы считаете мой скрипт тяжёлым?

Если вкратце:
Запись сразу во все ключи.
Чтобы добавить новую подпрограмму надо много строк дописать +выделить место в ГУИ, в моём варианте это только добавление названия в одну переменную.
Кнопки предназначенные только для игры зачем то назначены глобально.

В изложенном вами скриптом нет проверки на дубликаты. Можно все скилы назначить на одну и туже кнопку...

Забыл, поправил.

По вопросам возмездной помощи пишите письма
E-Mail: serzh82saratov@mail.ru
OS: Win7x64, AutoHotkey_L v1.1.26.01 (Unicode 32-bit).

5

Re: AHK: Dоtа 2 Iпvokеr

Спасибо что показали интересную команду "Loop, Parse, Action, |"

6

Re: AHK: Dоtа 2 Iпvokеr

Просто я всего как неделю, полторы изучаю этот язык скриптинга, почти ничего не знаю, да и программирование для меня тяжело дается. По этому писал топорным методом

7

Re: AHK: Dоtа 2 Iпvokеr

Просто я всего как неделю, полторы изучаю этот язык

Для новичка у вас отлично получилось.

По вопросам возмездной помощи пишите письма
E-Mail: serzh82saratov@mail.ru
OS: Win7x64, AutoHotkey_L v1.1.26.01 (Unicode 32-bit).

8 (изменено: serzh82saratov, 2013-03-30 22:20:30)

Re: AHK: Dоtа 2 Iпvokеr

Можно тоже самое и без неё сделать, но не айс будет.

Примерно так:

+ открыть спойлер


#SingleInstance force
Menu, tray, add, Настройки
Menu, tray, Default, Настройки
Global Action := "ColdSnap|GhostWalk|IceWall|Emp|Tornado|Alacrity|SunStrike|ForgeSpirit|Meteor|DeafeningBlast"
Hotkey, IfWinActive, ahk_class Notepad
Loop, Parse, Action, |
    Hotkey, % IniRead("Hotkey", A_LoopField), % RegExReplace(A_LoopField,A_Space,"_"), UseErrorLevel
Hotkey, IfWinActive
Return

Настройки:
    Gui, Color, 2F4F4F
    Gui, Add, Hotkey, vHotkey gHotkey w300 y280
    Gui, Add, DropDownList, vDropDownList gDropDownList xp yp+34 w120 Choose1 w200, % Action
    Gui, Add, Button, gAllView xp+210 yp hp, ???
    Gui, Add, Button, xp+44 yp hp gCleanAll, Clean
    Gui, Show, w320 h350, Hotkeys
DropDownList:
    GuiControlGet, DropDownList
    Gui, Add, Picture, x40 y22 w240 h240 , %DropDownList%.jpg
    Gui, Add, Picture, x40 y22 w240 h240 , %DropDownList%.jpg
    GuiControl,, Hotkey, % IniRead("Hotkey", DropDownList)
    GuiControl, Focus, Hotkey
    Return

Hotkey:
    If (Hotkey ~= "^[QWERDF]$")
    {
        GuiControl,, Hotkey, % IniRead("Hotkey", DropDownList)
        Return
    }
    If    D := ExistKey(Hotkey)
    {
        ToolTip, % "Эта кнопка уже назначена на:  " D, 3, 32
        GuiControl,, Hotkey, % IniRead("Hotkey", DropDownList)
        SetTimer, ToolTip, 1000
        Return
    }
    IniWrite, % Hotkey, INIFile.ini, Hotkey, % DropDownList
    Return

ExistKey(Key)    {
    If Key =
        Return False
    Loop, Parse, Action, |
    {
        If (IniRead("Hotkey", A_LoopField) = Key)
            Return A_LoopField
    }
        Return False
}
CleanAll:
    IniDelete, INIFile.ini, Hotkey
    GuiControl,, Hotkey
    Return

AllView:
    Tip =
    Loop, Parse, Action, |
    {
        Str := IniRead("Hotkey", A_LoopField)
        If (Str <> "")
            Tip .= A_LoopField " = " Str "`n"
    }
    Tip := Tip = "" ? "Ничего не назначено" : Tip
    ToolTip, % Tip, 3, 32
    KeyWait, LButton, D
    ToolTip
    Return
IniRead(Section, Key) {
    IniRead, Var, INIFile.ini, %Section%, %Key%, %A_Space%
    Return Var
}
ToolTip:
    SetTimer, ToolTip, Off
    ToolTip
    Return 
GuiClose:
    Reload
    Return

    ; ------------------- Action ------------------- 

ColdSnap:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
GhostWalk:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
IceWall:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
Emp:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
Tornado:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
Alacrity:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
SunStrike:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
ForgeSpirit:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
Meteor:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return
DeafeningBlast:
    MsgBox % "Действие """ A_ThisLabel """ по кнопке:`n`n" A_ThisHotkey
    Return

Правда не вижу практического применения чего либо основанного на контроле Hotkey, ибо:

...при несоответствующей записи раскладке языка, ГК (горячая клавиша) небудет работать, а при чтении (для отображения в контроле) запись небудет видна....

По вопросам возмездной помощи пишите письма
E-Mail: serzh82saratov@mail.ru
OS: Win7x64, AutoHotkey_L v1.1.26.01 (Unicode 32-bit).

9

Re: AHK: Dоtа 2 Iпvokеr

Файл изображения на хостинге удален. Было бы неплохо перезалить.

10 (изменено: ypppu, 2017-03-22 20:32:23)

Re: AHK: Dоtа 2 Iпvokеr

Я думаю, данный юзверь уже давно забыл/забил на этот форум. Так что не ждите, ибо "Последнее сообщение: 2013-03-30 19:01:37" (с) http://forum.script-coding.com/profile.php?id=29868.