АНК: При нажатии/отпускании ПКМ нажать заданную клавишу.

2. Suspend добавить.
4. В параметрах KeyWait указываешь 2 секунды.
5. * перед горячей клавишей, чтобы срабатывала даже при зажатых других клавишах.

*$Rbutton::
	Send {key down}
	KeyWait Rbutton, T2
	If ErrorLevel {
		Send {key up}
		KeyWait Rbutton
		Send {key}
	}
	Else {
		KeyWait Rbutton ; сначала ждем отпускания, иначе ожидание нажатия сработает сразу
		KeyWait Rbutton, D
		Send {key up}
	}
return

stealzy
Таже петрушка...
эта подпрограмма(она должна срабатывать если клавиша удерживается)

	If ErrorLevel {
			KeyWait Rbutton ;так тоже не заработало
		Send {key up}
		KeyWait Rbutton
		Send {key}
	}

выполняется только при отпускании клавиши после удержания.

stealzy
Я видимо не правильно объяснил - задержка срабатывания нужна при зажиме:

hotkey := "Space", sendkey := "Shift"

*$Space::
	Sleep, 2000 ;при зажиме нажатие произойдет через 2 сек
    Send {%sendkey%}
	KeyWait % hotkey
	Send {%sendkey%}
return

А хотелось бы изменить поведение подпрограмм для hotkey:
а) при разовом нажатии hotkey - делаем удержания sendkey, при повторном нажатии откл. удержание sendkey
б) при удержании hotkey  - выполнить подпрограмму (Send - KeyWait - Send)

Постараюсь объяснить на примере:
По умолчанию - вид от первого лица, при удержании hotkey - переход в режим прицеливания от бедра, а при разовом нажатии на hotkey - переход в режим прицеливания от мушки, или из прицела, повторное нажатие hotkey - выход из режима прицеливания.
А скриптом нужно изменить на оборот - при удержании hotkey - целимся из прицела, при нажатии hotkey - входим в режим прицеливания от бедра, повторное нажатие - возврат в состояние по умолчанию.

Как реализовать пункт а и б по отдельности я уже понял, а вот как их совместить?
Пока на ум приходит только введение счетчика для определения зажима хоткея.

hotkey := "Space"

*$Space::
    KeyWait, % hotkey, T0.3
    If ErrorLevel
	{
		ToolTip Хоткей зажат - старт выполнения функции_1
		KeyWait, % hotkey
		ToolTip Хоткей отжат - стоп выполнения функции_1
	}
	Else
	{
		If (FirstClick := !FirstClick)
			ToolTip Клик по Хоткею один раз - старт выполнения функции_2
		Else
			ToolTip повторный клик по Хоткею - стоп выполнения функции_2
	}
	Return

Это если как описано, скорее всего требуется так:

hotkey := "Space"

*$Space::
    KeyWait, % hotkey, T0.3
    If ErrorLevel
	{
		ToolTip Хоткей зажат - старт выполнения функции_1
		KeyWait, % hotkey
		ToolTip Хоткей отжат - стоп выполнения функции_1
	}
	Else
	{
		ToolTip Клик по Хоткею один раз - старт выполнения функции_2
		KeyWait, % hotkey, D
		ToolTip повторный клик по Хоткею - стоп выполнения функции_2
		KeyWait, % hotkey
	}
	Return

Разница в том, что в первом варианте, например возможно нажатием (по вашему - клик, как я понял) запустить функцию 2, и после зажатием запустить функцию 1, не останавливая функцию 2. Что формально требуется из вашего описания.

У меня вроде всё работает.

hotkey := "Rbutton"

*$Rbutton::
    KeyWait, % hotkey, T0.3
    If ErrorLevel
	{
		Send {%hotkey%} ;ToolTip Хоткей зажат - старт выполнения функции_1
		ToolTip Хоткей зажат - старт выполнения функции_1
		KeyWait, % hotkey
		Send {%hotkey%} ;ToolTip Хоткей отжат - стоп выполнения функции_1
		ToolTip Хоткей отжат - стоп выполнения функции_1
	}
	Else
	{
		If (FirstClick := !FirstClick)
		{
			Send {%hotkey% Down} ;ToolTip Клик по Хоткею один раз - старт выполнения функции_2
			ToolTip Клик по Хоткею один раз - старт выполнения функции_2
		}
		Else
		{
			Send {%hotkey% Up} ;ToolTip повторный клик по Хоткею - стоп выполнения функции_2
			ToolTip повторный клик по Хоткею - стоп выполнения функции_2
		}
	}
	Return

serzh82saratov
Понял по чему не работает - в оригинале функция_2 выполняется когда клавиша зажата.
Соответственно в скрипте нужно еще доп условие:

1. Хоткей зажат(в скрипте) - старт выполнения функции_1(клик в оригинале)
2. Хоткей отжат(в скрипте) - стоп выполнения функции_1(клик в оригинале)

3. Клик по Хоткею один раз(в скрипте) - старт выполнения функции_2(зажим Хоткея в оригинале)
>>Если после первого клика по Хоткею(в скрипте) - следует зажим(в скрипте) Хоткея(клик в оригинале) -> goto 4. else 5.
4. Тогда повторно клик по Хоткею(в скрипте) - что бы стопнуть выполнение функции_2 (зажим Хоткея в оригинале)
Зажим Хоткея(в скрипте) - старт выполнения функции_1(клик в оригинале)
Ожидание отжима Хоткея
Хоткей отжат(в скрипте) - стоп выполнения функции_1(клик в оригинале)
5. Повторный клик по Хоткею(в скрипте) - стоп выполнения функции_2(отжим Хоткея в оригинале)

UPD.
Вышла путаница из-за того как в оригинале работают клик и зажим, и как правильно реализовать в скрипте.
Вот так вроде все работает как надо:

hotkey := "Rbutton"

*$Rbutton::
    KeyWait, % hotkey, T0.3
    If ErrorLevel  ;подпрограмма зажима Хоткея
	{
		Send {%hotkey% Up} 
		ToolTip отжимаем Хоткей - стоп выполнения функции_2
		Send {%hotkey%}
		ToolTip Клик по Хоткею один раз - старт выполнения функции_1
		KeyWait, % hotkey
		Send {%hotkey%}
		ToolTip Повторный клик по Хоткею - стоп выполнения функции_1
	}
	Else ;подпрограмма клика Хоткея
	{
		If (FirstClick := !FirstClick)
		{
			Send {%hotkey% Down}
			ToolTip Зажим Хоткея - старт выполнения функции_2
		}
		Else
		{
			Send {%hotkey% Up}
			ToolTip Отжимаем Хоткей - стоп выполнения функции_2
		}
	}
	Return

serzh82saratov
Та да, наворотил я с объяснениями как да что

Нужно:
1. Хоткей зажат - выполнить клик по хоткею.
2. Хоткей отжат - выполнить клик по хоткею.
3. Клик по хоткею - выполнить зажатие хоткея.
4. Повторный клик по хоткею - выполнить отжатие хоткея.
5. Если выполнен клик по хоткею, а после хоткей зажат - выполнить сперва отжим хоткея, а потом клик.
6. После отжатия хоткея из п.5  - выполнить повторный клик.
7. При выполнении пунктов 1-2, не должны срабатывать действия из пункта 3-4 и наоборот(завязка скрипта на свои же действия)

Вариант из поста 15 - вроде бы отлично работает.