AHK: Зажать клавишу, если не нажаты остальные

Вам нужны команда while и функция getkeystate. Читайте в справке, но для начала освежите в памяти правила форума.

Во-первых рекомендуется использовать кодовое значение клавиши а не его имя, так мы сразу избавляемся от зависимости активной раскладки клавиатуры (коды можно посмотреть в гугле, либо в KeyHistory во время работы скрипта, однако нужно установить клавиатурный хук соотв. командой). Цикл лучше поместить в секцию автовыполнения (чтобы он выполнялся постоянно), а если необходима возможность отключать/включать цикл можно с помощью горячей клавиши менять значение какой-нибудь переменной на 1 для включения и 0 для выключения, которую будет цикл проверять в самом начале и пропускать итерацию командой continue пока не будет нажата клавиша активации цикла. Кроме того лучше отслеживать физическое состояние клавиши в данный момент параметром P. Чтобы зажать клавишу используйте слово down после имени клавиши (которое тоже лучше указать в виде кода). Вот как это все я смог реализовать:

L_Active := 1


Loop {
    if (!L_Active) {
        continue
    }
    
    if (!getKeyState("vk41", "P")) and (!getKeyState("vk52", "P")) and (!getKeyState("vk54", "P")) {
        SendInput {vk50 down}
    } else if (getKeyState("vk41", "P")) or (getKeyState("vk52", "P")) or (getKeyState("vk54", "P")) {
        SendInput {vk50 up}
    }
}

F3:: L_Active := L_Active = 1 ? 0 : 1

Протестировал в окне блокнота, пока зажата одна из трех клавиш клавиша P сразу отжимается. Иногда в момент зажатия клавиши нажатие клавиши P отправляется ещё один раз после чего прерывается, с чем это связано понять не могу, может товарищи поопытнее подскажут здесь.

serzh82saratov, похоже вы когда в нейтралку переводите, руку не снимаете с рычага, а начинаете бешено теребить его. Интересно, зачем вы это делаете?

Осталось избавиться от ненужного цикла и будет почти как я описал.

Если спам не нужен, то так:

F3::
	Work := 1 
	While Work
	{
		If Pause && GetKeyState("P")
			SendInput {P up}
		Else If !Pause && !GetKeyState("P")
			SendInput {P down}
		Sleep 30
	}
	SendInput {P up}
	Return

Зачем гадать что нужно ТС, пусть сам напишет, варианты предложены.

Хотя нет, зажимать можно только когда все отпущены.

#NoEnv

#If Work

~A::
~R::
~T:: 
	SendInput {Blind}{P up}
	Return

~A Up::
~R Up::
~T Up:: 
	Sleep 50
	If !GetKeyState("A") && !GetKeyState("R") && !GetKeyState("T")
		SendInput {Blind}{P down}
	Return

F3:: 
	Work := 0
	SendInput {Blind}{P up}
	Return

#If !Work

F3::
	Work := 1
	If !GetKeyState("A") && !GetKeyState("R") && !GetKeyState("T")
		SendInput {Blind}{P down}
	Return
	
#If

В 16 не то?

Не, в 16 без учета. Я в первом своем сообщении написал почему. Насчет спама согласен.

Я бы добавил {blind} везде, а то часто потом жалуются на дерганья.

stealzy, дык и в моем коде спама клавишей нет, при чем тут я ?

P.S. Не знал про возможность назначить хоткей на Key Down Key Up, тогда и вправду цикл тут не нужен.

Может и знал но из-за того что не практиковал такой метод применения и не додумался. Но на самом деле и вправду не знал ибо не возникало необходимости в его применении.