VBS: диалоговое окно выбора файла в windows vista & 7

Я правильно понял, что лицензию на «MS Common Dialog Control» можно получить вполне легально и бесплатно, судя по:

Ссылки см. в источнике. Кто-либо может опробовать данный вариант?

Правда, сам я пробовал «Simple HTML editor» непосредственно с установленной с диска MSDN (ничего не зная о вышеизложенном).

Замечание, при использование хост-сервера (cscript, wscript): Ошибка выполнения Microsoft VBScript: Невозможно создание объекта контейнером ActiveX: 'MSComDlg.CommonDialog'
А ежели запустить в PrimalScript, VbsEdit выполняется успешно, все это мне напоминает кол-во сессий RDP в XP...

Да, спасибо, вот запустил.

HTML_Editor.hta (Windows 7):
стока 89
символ 2
Объект не поддерживает это свойство или метод.
var oDropDown = oToolBar.createDropDownListAt("4");

Ну, а если, гм, ручками добавить в реестр как здесь (смотрим постскриптум)?

Да, кстати, а может быть тут дело в пресловутом «запуск от имени администратора»? А то, может быть, mshta.exe пытается писать, а запись идёт в песочницу?!

Нет, Visual Studio отсутствует (ОС — XP). Для XP могу вечером проверить на гольной ОС — только с установленным SP3.

Так, по:

абсолютно Ваша же ситуация. Насколько я понял, сие связано с тем, что кроме самого HTA нужны дополнительные файлы (кроме «html_editor.hta»). Сам на такое когда-то натыкался (да и забыл), из-за чего пришлось загружать пример с MS (который ныне доступен только как часть SDK:

). Позже я его ненароком удалил .

Однако, взять россыпью содержимое примера «HTML Editor Application» всё ещё можно здесь (в принципе, «stepfour.hta», «stepthree_a.htm», «stepthree_b.htm» и «steptwo.htm» — не нужны). Кроме того, естественно, должен наличествовать и быть зарегистрирован сам «MS Common Dialog Control»:

regsvr32.exe comdlg32.ocx

(именно «comdlg32.ocx», а не «comdlg32.dll»!; в «гольной» ОС он отсутствует, может быть взят с машины, где он уже есть, либо — непосредственно отсюда [хоть это и старая версия библиотеки]). После всего этого «html_editor.hta» заработал. А вот:

CreateObject("MSCOMDLG.COMMONDIALOG")

по прежнему требовал лицензии . Вылечился уже дважды упомянутым методом из постскриптума.

Напоминаю, речь шла о «гольной» XP SP3.

Мой примерчик работает нормально (win7 32bit).
(Естественно, вначале comdlg32.ocx зарегистрировал в системе и лицензию в реестр добавил).

Как я понял, основные проблемы:
1. UserAccounts.CommonDialog или SAFRCFileDlg - работает только в XP.
2. MSComDlg.CommonDialog - нужна лицензия.
3. Использование Internet Explorer c полем "input type=file" вызывает не очень настраиваемое окно загрузки - и начиная с IE8 возвращается только имя файла, а вместо пути ерунда (для защищенности).

Предлагаю решение с запуском HTA и вызовом функции из него:

Option Explicit

' Если возвращает True, то strFileName содержит полное имя файла

Private Function OpenFileDlg(strFileName)
  Const SW_HIDE = 0
  Const CUniqueID = "UniqueID" ' Для распознования "своего" окна
  Const CSleepInterval = 100 ' Ожидаем запуска MSHTA.exe циклом в CSleepCount интервалов с засыпанием на CSleepInterval мсек
  Const CSleepCount = 100

  Dim objWshShell, objShell, objShellWindows, objIEItem, objHTA, iCount

  OpenFileDlg = False
  Set objWshShell = CreateObject("WScript.Shell")
  objWshShell.Run "%windir%\system32\MSHTA.EXE " & _
    """javascript:new ActiveXObject('InternetExplorer.Application').PutProperty('" & CUniqueID & "', window);""", SW_HIDE
  Set objWshShell = Nothing
  Set objShell = CreateObject("Shell.Application")
  Set objShellWindows = objShell.Windows
  Set objShell = Nothing
  iCount = 1
  Do Until iCount = CSleepCount
    For Each objIEItem In objShellWindows
      If IsObject(objIEItem.GetProperty(CUniqueID)) Then
        Set objHTA = objIEItem.GetProperty(CUniqueID)
        objIEItem.Quit
        Exit For
      End If
    Next
    WScript.Sleep CSleepInterval
    iCount = iCount + 1
  Loop
  Set objShellWindows = Nothing
  If IsObject(objHTA) Then
    objHTA.document.body.innerHTML = "<OBJECT ID=Dlg CLASSID=CLSID:3050f4e1-98b5-11cf-bb82-00aa00bdce0b></object>"
    strFileName = objHTA.Dlg.object.openfiledlg("", "", "Только текстовые(*.txt)|*.txt|Все(*.*)|*.*", "Выбрать файл")
    objHTA.close
    Set objHTA = Nothing
    OpenFileDlg = (strFileName <> "")
  End If
End Function

Dim strFileName

If OpenFileDlg(strFileName) Then
  WScript.Echo strFileName
End If

У меня XP, там это работает, но надеюсь должно и в Vista/XP.
Проверьте, кто может.

Да, конечно Vista/7

У меня мусора не было, но можно попробовать в виде "Только текстовые(*.txt)|*.txt|Все(*.*)|*.*" & vbNullChar
Да, и если это переменная, а не явная строка, то нужно приводить к типу с помощью CStr. Тоже для всех параметров.
Если нужно несколько расширений, то можно так: "Только текстовые(*.txt;*.lst)|*.txt;*.lst|Все(*.*)|*.*
Первый параметр может содержать начальный путь, но только вместе с именем файла. При этом от имени файла "откусывается" расширение по фильтру. Т.е. можно указать (в моем примере) "c:\......\*.txt" и перейдет в указанный каталог, а в строке останется *