VBScript: Помогите модифицировать скрипт слежения за созданием файлов

' Процедура-обработчик события OnObjectReady объекта sWbemSink
Sub Sink_OnObjectReady(oOutParams, oContext)
    strResult = Date & " " & Time & vbCrLf &_
        "Создан файл: " &  oOutParams.TargetInstance.PartComponent
    objRegExp.Pattern = "("".*\"")"
     Set objMatches = objRegExp.Execute(strResult)
    Wscript.Echo objMatches.Item(0)
End Sub

WScript.Echo objService.Get(oOutParams.TargetInstance.PartComponent).Name

strDir = "c:\temp" ' каталог, за которым следим
strComputer = "." ' имя компьютера; "." означает текущий компьютер
'==============================================================================
strDirSlash = Replace(strDir, "\", "\\\\")
strNamespace = "Root\CIMV2"
' Подключаемся к пространству имен
Set objService = GetObject("WinMgmts:\\" & strComputer & "\" & strNamespace)
Set objSink = WScript.CreateObject("WbemScripting.SWbemSink", "Sink_")

objService.ExecNotificationQueryAsync objSink, _
    "SELECT * FROM __InstanceCreationEvent WITHIN 5 WHERE " &_
    "Targetinstance ISA 'CIM_DirectoryContainsFile' and " &_
    "TargetInstance.GroupComponent= " &_
    "'Win32_Directory.Name=""" & strDirSlash & """'"

While 1
    WScript.Sleep 1000
Wend

' Процедура-обработчик события OnObjectReady объекта sWbemSink
Sub Sink_OnObjectReady(oOutParams, oContext)


strMessage = objService.Get(oOutParams.TargetInstance.PartComponent).FileName _
& "." & objService.Get(oOutParams.TargetInstance.PartComponent).Extension

Wscript.Echo strMessage


End Sub

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMv2") 
Set objEvents = objWMIService.ExecNotificationQuery _
("SELECT * FROM __InstanceModificationEvent WITHIN 5 WHERE " & _
    "TargetInstance ISA 'CIM_DataFile'" & _
    " AND TargetInstance.Drive = 'c:'" & _
    " AND TargetInstance.Extension = 'txt'" & _
    " AND TargetInstance.Path = '\\1\\'")
Wscript.Echo "Поиск ..."
Do While(True)
    Set objReceivedEvent = objEvents.NextEvent 
    WScript.Echo "File modifed: " & objReceivedEvent.TargetInstance.FileName
Loop

Option Explicit

Dim objSWbemServicesEx
Dim objSWbemSink

Dim strFolder
Dim boolDone


Set objSWbemServicesEx = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set objSWbemSink = WScript.CreateObject("WbemScripting.SWbemSink", "SINK_")

strFolder = "c:\Temp"

objSWbemServicesEx.ExecNotificationQueryAsync objSWbemSink, _
    "SELECT * FROM __InstanceCreationEvent WITHIN 5 WHERE " & _
    "TargetInstance ISA 'CIM_DirectoryContainsFile' AND " & _
    "TargetInstance.GroupComponent = 'Win32_Directory.Name=""" & Replace(strFolder, "\", "\\\\") & """'"

boolDone = False

Do
    WScript.Sleep 1000
Loop Until boolDone

objSWbemSink.Cancel

Set objSWbemSink       = Nothing
Set objSWbemServicesEx = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub SINK_OnObjectReady(objSWbemObject, objSWbemAsyncContext)
    With objSWbemServicesEx.Get(objSWbemObject.TargetInstance.PartComponent)
        WScript.Echo .FileName & "." & .Extension
    End With
        
    boolDone = True
End Sub
'=============================================================================