1 Тема от ybill

  • ybill
  • Гость

Тема: VBS: Установить параметры виртуальной памяти на удаленной машине

Привет!

Есть группа серверов win 2008R2 в домене, на которых у меня есть права администратора. На них требуется установить одинаковые параметры виртуальной памяти, к примеру мин=4096, макс=4096, файл на диске С. Соответственно если там были указаны еще какие-нибудь другие диски, то их обнулить.
Хочется делать это скриптом, желательно VBS.

Поможите кто чем может!

2 Ответ от alexii

  • alexii
  • Разработчик
  • Неактивен

Re: VBS: Установить параметры виртуальной памяти на удаленной машине

ybill, пробуйте:

Option Explicit

Dim strComputer

Dim objSWbemLocator
Dim objSWbemServicesEx
Dim objSWbemObjectEx


strComputer = "."

Set objSWbemLocator    = WScript.CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServicesEx = objSWbemLocator.ConnectServer(strComputer, "root\cimv2")

objSWbemServicesEx.Security_.Privileges.AddAsString "SeCreatePagefilePrivilege", True

For Each objSWbemObjectEx In objSWbemServicesEx.InstancesOf("Win32_ComputerSystem")
    With objSWbemObjectEx
        .AutomaticManagedPagefile = False
        .Put_
    End With
Next


For Each objSWbemObjectEx In objSWbemServicesEx.InstancesOf("Win32_PageFileSetting")
    objSWbemObjectEx.Delete_
Next

With objSWbemServicesEx.Get("Win32_PageFileSetting").SpawnInstance_
    .Name = "C:\\pagefile.sys"
    .InitialSize = 4096
    .MaximumSize = 4096
    
    .Put_
End With

Set objSWbemObjectEx   = Nothing
Set objSWbemServicesEx = Nothing
Set objSWbemLocator    = Nothing

WScript.Quit 0