1 (изменено: alexii, 2014-12-09 03:39:33)

Тема: CMD/BAT: Как прописать все диски?

Подсказали вот такой код, только вот как все диски поставить? О_о
Прошу помогите.

Set FDir="F:\"
Set Maska="*.jpg"
FOR /R %FDir% %%i IN (%Maska%) DO Call :Obrabotka "%%i"

Нашел похожий код

set str=%~1
set alfa=ABCDEFGHIJKLMNOPQRSTUVWXYZ
for /l %%a in (0,1,25) do (set b=!alfa:~%%a,1!&(cd /d "!b!:\" > nul 2> nul && call :dr !b!))
pause
exit
:dr
dir /a:-d /b /s "%1:\%str%" 2> nul
exit /b

.  .  . мозгов не хватило разобрать -_-

2

Re: CMD/BAT: Как прописать все диски?

Проще:

@echo off
setlocal enableextensions enabledelayedexpansion

set sPattern=*.jpg

for %%i in (a b c d e f g h i j k l m n o p r s t u v w x y z) do (
    if exist "%%i:\." (
        pushd "%%i:\"
        for /r %%j in ("%sPattern%") do call :Obrabotka "%%j"
        popd
    )
)

endlocal
exit /b 0

:Obrabotka
    echo %~1
    exit /b 0

3

Re: CMD/BAT: Как прописать все диски?

@echo off
setlocal enableextensions

set "mask=*.jpg"

for /l %%# in (65 1 90) do (
 cmd /c exit /b %%#
 for /f "delims=" %%i in ('
  2^>nul call dir /a-d/b/s "%%=ExitCodeAscii%%:\%mask%"
 ') do call :Obrabotka "%%i"
 )

endlocal
exit /b


:Obrabotka

 ::::::::::::::
 ::::::::::::::
 ::::::::::::::

 exit /b