AHK: Как реализовать uninstall

Тема то была, но решения нет... там перешли на использование BAT-файлов.

Плюс вопрос был поставлен так - самоуничтожение откомпилированного файла средствами AHK.

А может проще - выполнить control.exe appwiz.cpl... вот только бы туда параметры передать бы.

Можно обойтись и без TSKILL.EXE

#SingleInstance force
IfEqual 1, /X, ExitApp
/*
. . .
*/
EnvSet A_ScriptFullPath, %A_ScriptFullPath%
Run %ComSpec% /d /v:off /c start "" /wait "`%A_ScriptFullPath`%" /X& del "`%A_ScriptFullPath`%",, Hide
ExitApp

Если в последнем скрипте, то я написал, что написать в первых и последних строках.
Вызывается обработчик командной строки, путь к которому прописан в переменной среды ComSpec, обычно это CMD.EXE, и выполняет две команды, которые следуют за ключом «/c» и разделены знаком «&»…

Да, про папку я и забыл. Значит надо исправить

del "`%A_ScriptFullPath`%"

на

rd /s /q "`%A_ScriptFullPath`%\.."

и  в команде Run установить рабочий каталог отличный от каталога содержащего файл скрипта (например, корневой каталог диска, т.е. указав вторым параметром «\»).

В смысле разделы

HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall
HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall

?
Ну, тогда деинсталлятор нельзя уже будет вызвать из Панели управления.

Кстати, а почему в качестве деинсталлятора не использовать командный файл, прописав путь к нему в UninstallString — это вполне работает.

Зависит от разрядности (32/64) системы.

Ну, прописать все действия по очистке системы от установки в командном файле, который в конце работы самоудалится.

Ради интереса, самоудаляющийся exe без использования сторонних приложений (ну, практически без использования ):

if 0 = 2
{
   ParentPID = %1%
   ParentPath = %2%
   Process, WaitClose, %ParentPID%
   FileDelete, % ParentPath
   CreateProcess("notepad", DEBUG_ONLY_THIS_PROCESS := 2)
   ExitApp
}

if !A_IsCompiled  {
   MsgBox, Скомпилируйте скрипт!
   ExitApp
}

TmpFilePath := A_Temp "\AHK_KILL_" A_TickCount ".exe"
FileCopy, % A_ScriptFullPath, % TmpFilePath, 1

hFile := CreateTmpFile(TmpFilePath)
ChildPID := CreateProcess(TmpFilePath " " DllCall("GetCurrentProcessId") " """ A_ScriptFullPath """", 0)
Process, Wait, % ChildPID
DllCall("CloseHandle", Ptr, hFile)
ExitApp

CreateProcess(CommandLine, flag)
{
   VarSetCapacity(STARTUPINFO, size := 4*A_PtrSize + 8*4 + 5*A_PtrSize, 0)
   NumPut(size, STARTUPINFO)
   VarSetCapacity(PROCESS_INFORMATION, 2*A_PtrSize + 8, 0)
   
   DllCall("CreateProcess", UPtr, 0, Str, CommandLine
                          , UPtr, 0, Ptr, 0
                          , UInt, bInheritHandles := 1, UInt, flag, Ptr, 0, Ptr, 0
                          , UPtr, &STARTUPINFO, Ptr, &PROCESS_INFORMATION)
                          
   DllCall("CloseHandle", Ptr, hThread := NumGet(PROCESS_INFORMATION, "UInt"))
   DllCall("CloseHandle", Ptr, hProcess := NumGet(&PROCESS_INFORMATION + A_PtrSize, "UInt"))
   Return PID := NumGet(&PROCESS_INFORMATION + 2*A_PtrSize, "UInt")
}

CreateTmpFile(FilePath)
{
   static GENERIC_READ := 0x80000000, FILE_SHARE_READ := 1, FILE_SHARE_DELETE := 4
        , OPEN_EXISTING := 3, FILE_FLAG_DELETE_ON_CLOSE := 0x4000000
        , FILE_ATTRIBUTE_TEMPORARY := 0x100
   
   VarSetCapacity(SECURITY_ATTRIBUTES, size := 2*A_PtrSize + 4, 0)
   NumPut(size, SECURITY_ATTRIBUTES), NumPut(bInheritHandle := 1, &SECURITY_ATTRIBUTES + 2*A_PtrSize)
   Return DllCall("CreateFile",  Str, FilePath
                              , UInt, GENERIC_READ
                              , UInt, FILE_SHARE_READ|FILE_SHARE_DELETE
                              , UPtr, &SECURITY_ATTRIBUTES
                              , UInt, OPEN_EXISTING
                              , UInt, FILE_FLAG_DELETE_ON_CLOSE|FILE_ATTRIBUTE_TEMPORARY
                              , UPtr, 0)
}

Так всё-таки, не поняли, зачем блокнот, или зачем приведенный кусок кода?

Если вкратце, здесь происходит следующее.
Сначала проверяется, переданы ли скрипту два параметра. Наш скомпилированный скрипт запускается без параметров, поэтому блок кода в скобках пропускается. Затем мы создаём копию нашего файла в директории A_Temp, и открываем копию файла с флагом FILE_FLAG_DELETE_ON_CLOSE. В этом случае файл будет самоудаляться, как только все его хэндлы будут закрыты, и если он не будет занят каким-либо процессом. Теперь создаём процесс, запускающий копию файла, передав ей в качестве параметров родительский PID и путь к основному файлу. Затем закрываем полученный хэндл копии (при этом ещё одна копия этого хэндла сохраняется, будучи унаследованной при создании нового процесса) и завершаем основной процесс.

Новый процесс запускается с двумя параметрами, поэтому выполняется только первый блок кода. Здесь мы ожидаем, когда родительский процесс завершится и после этого удаляем наш основной файл. Если теперь закрыть процесс копии, то, как я понимаю, его хэндл закроется раньше, чем процесс будет прекращён, и файл не удалится. Чтобы обойти это, мы создаём дочерний процесс, который сохраняет копию хендла родительского (для этого и нужен notepad в качестве "костыля"), завершаем процесс копии, в след за этим завершается дочерний процесс, последняя копия хендла уничтожается, и файл копии самоудаляется.

Как видите, ничего сложного.

Не имел дела с 64-разрядными системами, поэтому могу сказать что знаю понаслышке. Если нужна всеохватность, то скрипт должен компилироваться в 32-разрядный EXE. 32-разрядные приложения как обычно пишут-читают разделы реестра без «Wow6432Node», а уже система их перенаправляет в Wow6432Node и при просмотре 64-разрядным редактором реестра их данные видны там.

Про способ предложенный teadrinker'ом как раз вчера читал, не скажу, что разобрался, но по общим впечатлениям — он самый.
Я только сомневаюсь, что notepad — подходящий костыль для общего случая, — многие (если не все) текстовые редакторы, чтобы не менять сопоставления разных типов файлов по отдельности, предоставляют возможность заменить notepad.exe собой или промежуточным загрузчиком (!), при этом они могут поддерживать многооконный режим, т.е. новый процесс может сразу же завершиться (сопровождаясь созданием новой вкладки в окне ранее запущенного).

Альтернативные варианты — calc, taskmgr, explorer.

В переменной %0% содержится количество параметров, переданных скрипту. Соответственно

if 0 = 2

означает «если передано два параметра». Синтаксис разбора параметров можно здесь посмотреть (Script Parameters). У Indomito по-другому потому, что я позже отредактировал.

Это смотря, как запускать. Проверял, оба работают, даже если уже запущены. rundll32 тоже вполне подойдёт — он есть в Windows 10.

2.1:
HKLM - это для всех пользователей (требует права администратора).
HKCU (CURRENT USER) - только для текущего пользователя, т.е. в других учетных записях, записанной тут информации видно не будет.

Да, тут попутный вопросик.
Я прочёл ЭТО и что использовать NSIS 2.46 rus(Nullsoft Scriptable Install System) или  что иное?

Ведь деинсталятор предполагает наличие инсталятора, а самому писать его с нуля не очень хочется.

У какого ещё колодца? Уколоться и забыться.

Ясно, просто выше написано было.

почему то решил, что это относится к файлу - я ведь не прав?
Это к процессу, верно?

По остальному вопросов нет, только пункты 2.2 и 2.3 мне до конца не ясны, т.е. что на 100% необходимо там иметь место.
Особенно пункт 2.3

Так, с этим я разберусь, а пункт 2.3?

Я сам заполнил только две переменных DisplayName и UninstallString этого достаточно для appwiz.cpl.
Просто я не уверен - первый раз так делаю.

Есть ещё DisplayIcon и ей подобные, ну я просто сомневаюсь что бы "не с глючило" в не подходящий момент... ну как всегда это бывает.

Пароль к архиву — «notepad»:

wisgest спасибо за информацию, я как понимаю свои переменные добавлять можно, т.е. это не вызовет проблем?

teadrinker спасибо за скрипт, а можно его в аттач, а то при копировании кода можно случайно промазать, а кнопки "Выделить код" нет.

YMP Извиняюсь, что то я погорячился.