1

Тема: AHK: Сокращение клавиатуры до 9 клавиш

Возможно средствами AHK воплотить ниже наведенную идею?
Есть 9 кнопок клавиатуры Q W E A S D Z X C, подскажите какой код нужно что бы при нажатии комбинацыи кнопок QW вводилась буква R ( не сама буква как в раскладке а  vk51+vk57=vk52) ?


q = q

w = w

e = e

qw = r  ;

qe = t

wq = y

we = u

ew = i

eq = o

qd = p 
+ другие примеры
a

s

d

as

ad

sa

sd

da

ds

z

x

c

zx

zc

xz

xc

2 (изменено: HideGenius, 2015-03-24 04:50:00)

Re: AHK: Сокращение клавиатуры до 9 клавиш

Была идея сделать такое на тачпаде но как сделать на тачпаде 8 кубиков виртуальных не знаю, тоесть нажимаешь просто на "кубик" 1 будет буква А нажимаешь на 1 "кубик" и ведешь вверх будет буква Б и так далее.

3

Re: AHK: Сокращение клавиатуры до 9 клавиш


q & w::
w & q::
    Send, r
    Return

q up:: Send, q
w up:: Send, w

4

Re: AHK: Сокращение клавиатуры до 9 клавиш

8 кубиков виртуальных

Думаю такое просто переделать.

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru
Win10x64 v20H2, AutoHotkey_L v1.1.33.09 (Unicode 32-bit). AhkSpy, Hotkey, ClockGui

5

Re: AHK: Сокращение клавиатуры до 9 клавиш

Это мегахитрый интрефейс для незаметного введения паролей?

6

Re: AHK: Сокращение клавиатуры до 9 клавиш

serzh82saratov пишет:

8 кубиков виртуальных

Думаю такое просто переделать.

У вашей ссилки действия на экране, а у моей идеи действия на тачпаде. Тоесть тачпад как средство упрявления курсором уже не будет, а будет как зона сенсора с 8 кубиками.

7 (изменено: HideGenius, 2015-03-27 01:43:39)

Re: AHK: Сокращение клавиатуры до 9 клавиш

ypppu пишет:

Это мегахитрый интрефейс для незаметного введения паролей?

Нет, это средство для ввода текста на частично ( Y U I O G H J K L B N M )< парализованой клавиатуре ноутбука.

8 (изменено: HideGenius, 2015-03-24 16:46:32)

Re: AHK: Сокращение клавиатуры до 9 клавиш

YMP пишет:

q & w::
w & q::
    Send, r
    Return

q up:: Send, q
w up:: Send, w

Появилась проблемка.
При данном коде

vk51 & vk57::
send {vk52}
return
vk57 & vk51::
send {vk59}
return

vk51 up:: Send, {vk51}
return
vk57 up:: Send, {vk57}
return

При нажатии q+w= rw и w+q= yq.

9

Re: AHK: Сокращение клавиатуры до 9 клавиш

YMP пишет:

q & w::
w & q::
    Send, r
    Return

q up:: Send, q
w up:: Send, w

И еще не работают сочетания Ctrl+w и другие сочетания связаные с бинд кнопками.

10

Re: AHK: Сокращение клавиатуры до 9 клавиш

Что никому не интересно? Или просто помочь?

11

Re: AHK: Сокращение клавиатуры до 9 клавиш

Да что так сложно помочь?

12 (изменено: HideGenius, 2015-03-27 01:42:05)

Re: AHK: Сокращение клавиатуры до 9 клавиш

Ну помогите! Не хочу на экранной клавиатуре все время писать!

13

Re: AHK: Сокращение клавиатуры до 9 клавиш

Например так:

q & w::
w & q::
Send, r
return

*q up::
if !GetKeyState("w", "P")
   Send, q
return

*w up::
if !GetKeyState("q", "P")
   Send, w
return

14 (изменено: HideGenius, 2015-03-27 03:41:14)

Re: AHK: Сокращение клавиатуры до 9 клавиш

Malcev, сочетание ctrl+w все равно не работает как и другие.

15 (изменено: Malcev, 2015-03-27 04:40:01)

Re: AHK: Сокращение клавиатуры до 9 клавиш

q & w::
w & q::
Hotkey, *q up, off
Hotkey, *w up, off
if GetKeyState("control", "P")
   send ctrl q w
else if GetKeyState("alt", "P")
      send  alt q w
else
      send  q w
KeyWait q
KeyWait w
Hotkey, *q up, on
Hotkey, *w up, on
return

*q up::
if GetKeyState("control", "P")
      send  ctrl q
else if GetKeyState("alt", "P")
      send  alt q
else
      send  q
return

*w up::
if GetKeyState("control", "P")
      send  ctrl w
else if GetKeyState("alt", "P")
      send  alt w
else
      send  w
return

16 (изменено: serzh82saratov, 2015-03-27 09:51:43)

Re: AHK: Сокращение клавиатуры до 9 клавиш

ТС пишет:

we = u
ew = i

qw = r
wq = y

Тут в Action указаны только эти сочетания, по аналогии надо дописать далее.

#UseHook

Action := {"vk57-vk45":"{vk55}","vk45-vk57":"{vk49}"  ; we = u , ew = i
    , "vk51-vk57":"{vk52}","vk57-vk51":"{vk59}"}   ; qw = r  , wq = y

Keys := "vk51|vk57|vk45|vk41|vk53|vk44|vk5A|vk58|vk43"
   ;   " Q  | W  | E  | A  | S  | D  | Z  | X  | C  "
   
Loop, Parse, Keys, |
{
    Hotkey, %A_LoopField%, Hotkey
    Hotkey, %A_LoopField% Up, Hotkey_Up
}
Return

Hotkey: 
    If (k = "")
        k := A_ThisHotkey, i := 0
    Else If (k != A_ThisHotkey && (i := 1))
        SendInput % Action[k "-" A_ThisHotkey] 
    Return
    
Hotkey_Up:
    If ((TH := SubStr(A_ThisHotkey, 1, -3)) = k && !(k := ""))
        If !i
            SendInput {%TH%}
    Return
По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru
Win10x64 v20H2, AutoHotkey_L v1.1.33.09 (Unicode 32-bit). AhkSpy, Hotkey, ClockGui

17

Re: AHK: Сокращение клавиатуры до 9 клавиш

serzh82saratov, спаисбо все работает. Жаль вот скорости нельзя добавить.

18

Re: AHK: Сокращение клавиатуры до 9 клавиш

Скорости чего?

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru
Win10x64 v20H2, AutoHotkey_L v1.1.33.09 (Unicode 32-bit). AhkSpy, Hotkey, ClockGui

19

Re: AHK: Сокращение клавиатуры до 9 клавиш

serzh82saratov, скорости печати. Сейчас нужно удерживать Q и нажимать W тогда будет буква R  да и если поодиночно нажимать быстро одинарные (Q W E) клавиши то они не печатают ничего.  Быстрее будет если нажимаешь Q, отпускаешь и если в течении милисекунди нажимаешь W то тогда будет буква R.

20

Re: AHK: Сокращение клавиатуры до 9 клавиш

Может будет оптимальней использовать комбинации вроде: Ctrl+Alt+"буква". Да и по скорости не так медленно будет.

Win 7 x64
AHK v1.1.33.02
                       Справка тебе в помощь.

21

Re: AHK: Сокращение клавиатуры до 9 клавиш

Alectric, и как мне с помощю ctrl+alt заменить все буквы клавиатуры?

22

Re: AHK: Сокращение клавиатуры до 9 клавиш

На 27 букв хватит, + ещё сами 9 кнопок. Если добавить Shift то 63+9.

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru
Win10x64 v20H2, AutoHotkey_L v1.1.33.09 (Unicode 32-bit). AhkSpy, Hotkey, ClockGui

23

Re: AHK: Сокращение клавиатуры до 9 клавиш

Купить новую клавиатуру или починить старую не проще, чем запоминать массу комбинаций?

24

Re: AHK: Сокращение клавиатуры до 9 клавиш

Присоединяюсь к вопросу про клавиатуру. Все-таки любые попытки длительно и в больших объемах работать с "усеченными" вариантами отдают мазохизмом. Если мышь работает (что уже хорошо), можно переключение наборов повесить на колесико. Включение/отключение режима - комбинацией Ctrl+Shift+Z.

#NoEnv
Keys:= {"vk51":["vk51","vk52","vk55","vk50"]
       ,"vk57":["vk57","vk54","vk49","vkDB"]
       ,"vk45":["vk45","vk59","vk4F","vkDD"]
       ,"vk41":["vk41","vk46","vk4A","vkBA"]
       ,"vk53":["vk53","vk47","vk4B","vkDE"]
       ,"vk44":["vk44","vk48","vk4C","vkDC"]
       ,"vk5A":["vk5A","vk56","vk4D","vkBF"]
       ,"vk58":["vk58","vk42","vkBC","vk8"]
       ,"vk43":["vk43","vk4E","vkBE","vkD"]}
Set:=1
Tips := {"English":["QWE`nASD`nZXC","RTY`nFGH`nVBN","UIO`nJKL`nM , .","P [ ]`n; ' \`n/B En"]
        ,"Russian":["ЙЦУ`nФЫВ`nЯЧС","КЕН`nАПР`nМИТ","ГШЩ`nОЛД`nЬБЮ","ЗХЪ`nЖЭ\`n.B En"]}
for k, v in Keys {
   HotKey, if, Print
   Hotkey, %k%, MKey
}
SetTimer, Watch, 50
return

^+vk5A:: Print:=!Print ; Ctrl+Shift+Z
#If Print
WheelUp::(Set<4)&&Set++
WheelDown::(Set>1)&&Set--
#If

MKey:
SendInput % "{" . Keys[A_ThisHotkey][Set] . "}"
Return
Watch:
   Tooltip % Print? Tips[InputLayout()][Set] : ""
Return

InputLayout(window := "A") {
   If !(hWnd := WinExist(window))
      return
   WinGetClass, Class
   if (Class == "ConsoleWindowClass"){
       WinGet, consolePID, PID
       DllCall("AttachConsole", Ptr, consolePID)
       VarSetCapacity(buff, 16)
       DllCall("GetConsoleKeyboardLayoutName", Str, buff),
       DllCall("FreeConsole")
       langID := "0x" . SubStr(buff, -3)
   }
   Else langID := DllCall("GetKeyboardLayout", Ptr, DllCall("GetWindowThreadProcessId", Ptr, hWnd, UInt, 0, Ptr), Ptr) & 0xFFFF
   Size := (DllCall("GetLocaleInfo", UInt, langID, UInt, 0x1001, UInt, 0, UInt, 0) * 2)   ; LOCALE_SENGLANGUAGE := 0x1001
   VarSetCapacity(localeSig, Size, 0)
   DllCall("GetLocaleInfo", UInt, langID, UInt, 0x1001, Str, localeSig, UInt, Size)
   return localeSig
}

25

Re: AHK: Сокращение клавиатуры до 9 клавиш

Ну вот опять всё упрощать, Алану Тьюрингу это бы всё понравилось, зуб даю.

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru
Win10x64 v20H2, AutoHotkey_L v1.1.33.09 (Unicode 32-bit). AhkSpy, Hotkey, ClockGui

26

Re: AHK: Сокращение клавиатуры до 9 клавиш

Буду только рад, если можно сделать проще.
Вроде и так до минимума сократил, можно откинуть индикацию русской раскладки - будет веселей набирать на великом и могучем, с подсказкой "QWE...". ))

27

Re: AHK: Сокращение клавиатуры до 9 клавиш

Не, я про то что Ты и так уже упростил до нельзя. По поводу скорости ввода для ТС, я бы в твоей идее, смену вариантов повесил бы на Ctrl,Alt,Shift.

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru
Win10x64 v20H2, AutoHotkey_L v1.1.33.09 (Unicode 32-bit). AhkSpy, Hotkey, ClockGui