WSH: пишем COM-серверы в формате Windows Script Component (WSC)

С помощью технологии Windows Script Components можно зарегистрировать в системе COM-объект, написанный на языке JScript или VBScript. Любой сценарий WSH можно упаковать в COM-объект и использовать его в приложениях, написанных на любом языке, который позволяет подключать подобные внешние объекты.

Механизм работы объектов-сценариев базируется на технологии ActiveX Scripting. Основную роль здесь играет динамическая библиотека scrobj.dll, которая является оболочкой компонентов-сценариев и отвечает за функционирование файла-сценария в качестве COM-объекта. Оболочка компонентов-сценариев scrobj.dll отвечает за то, чтобы при вызове из внешнего приложения метода объекта-сценария или обращении к его свойству запускалась соответствующая функция, описанная в этом сценарии.

При регистрации объекта-сценария в разделе реестра HKEY_CLASSES_ROOT\CLSID\ создаётся новый подраздел, название которого совпадает с CLSID регистрируемого объекта. В этом подразделе создаётся подраздел InprocServer32, значением по умолчанию которого является полный путь к библиотеке scrobj.dll. Кроме того, там же создаются подразделы ProgID (программный идентификатор объекта) и ScriptletURL (полный путь к файлу объекта-сценария).

При создании экземпляра объекта из внешнего приложения в разделе реестра HKEY_LOCAL_MACHINE\SOFTWARE\Classes\ ищется подраздел с именем, которое совпадает с программным идентификатором объекта (такой подраздел создаётся при регистрации объекта-сценария). Определяется CLSID объекта (соответствующий параметр найденного подраздела). После этого разыскивается подраздел с именем, которое совпадает с найденным CLSID объекта, в разделе реестра HKEY_CLASSES_ROOT\CLSID\. По значению подраздела InprocServer32 загружается scrobj.dll, которая в свою очередь уже загружает файл самого сценария, используя значение подраздела ScriptletURL.

Компоненты-сценарии, реализованные по технологии Windows Script Components, представляют из себя файлы с расширениями wsc (или sct), которые содержат специальную XML-разметку (объектная модель WSC XML).

Одним из главных преимуществ WSC является возможность повторного использования кода. Такие компоненты могут свободно использоваться в других сценариях, а также в любых языках программирования, поддерживающих технологию COM и способных выступить в роли OLE-клиента.

Элемент <public>

Может содержать один или несколько элементов <property>, <method> или <event>.

Элемент <property>

Объявляет свойство, которое будет доступно для клиентов автоматизации. Атрибут name определяет имя свойства.

Объявляемое свойство может быть доступно только для чтения, только для записи, или для чтения и записи. Это определяется наличием внутри контейнера <property> элементов <get/> и <put/>.

Атрибут internalName в элементах <get/> и <put/> задаёт имена функций, которые будут использоваться для чтения и записи свойства соответственно. Эти функции описываются внутри контейнера <script>. Если атрибут internalName не указан, необходимо задать функции get_PropertyName и/или put_PropertyName, где PropertyName - имя свойства (атрибут name).

Элемент <method>

Объявляет метод, который будет доступен для клиентов автоматизации. Атрибут name определяет имя метода. Если не указан атрибут internalName, внутри контейнера <script> должна быть описана функция или процедура с таким именем.

Список параметров метода (если они есть) задаётся внутри элемента <method> с помощью элементов <parameter>, каждый из которых должен содержать артрибут name.

Элемент <event>

Объявляет событие, которое может обрабатываться клиентами автоматизации. Атрибут name определяет имя события.

Атрибут dispid может содержать числовой идентификатор интерфейса события.

Чтобы вызвать наступление события, внутри элемента <script> используется функция fireEvent(), с именем нужного события в качестве параметра.

Элемент <resource>

Позволяет отделить символьные или числовые константы от остального кода сценария. Для получения значения ресурса нужно вызвать метод getResource, передав в качестве параметра символьный идентификатор ресурса (значение атрибута id). Например:

С помощью элемента <?component?> может быть реализована более углубленная проверка ошибок. Используются два атрибута: error и debug. Установка error="true" позволит выводить более подробные сообщения об ошибках. Например, при невозможности создания объекта вы получите сообщение типа "Невозможно создание объекта контейнером ActiveX". Если же атрибут error не задан, вы получите сообщение типа "Неопознанная ошибка". Установка debug="true" даст возможность пошагового выполнения кода сценария в отладчике - в случае возникновения ошибки будет выдано окно с предложением запустить отладчик (на выбор - из всех отладчиков, установленных в системе). Элемент <?component?> можно задать в начале файла, непосредственно после элемента <?xml?>, например:

Можно использовать в WSC объекты собственных классов, с собственными свойствами и методами, и передавать эти объекты клиентским скриптам. Демонстрация:
C:\Temp\test.wsc

<?xml version="1.0" encoding="windows-1251" standalone="yes"?>
<?component error="true" debug="true"?>
<component>
<registration progid="SomeProgId"/>
<public>
    <method name="Construct"/>
    <method name="Destruct"/>
</public>
<script language="VBScript"><![CDATA[
    ' --------------------------------------------------
    Function Construct()
        Set Construct = New MyClass
    End Function
    ' --------------------------------------------------
    Sub Destruct(ByRef objMyClass)
        Set objMyClass = Nothing
    End Sub
    ' --------------------------------------------------
    Class MyClass
        Private intX1
        Private intX2
        
        Public Property Let x1(intValue)
            intX1 = intValue
        End Property
        
        Public Property Let x2(intValue)
            intX2 = intValue
        End Property
        
        Public Function Add()
            Add = intX1 + intX2
        End Function
    End Class
]]></script>
</component>

Клиентский скрипт:

Set objWSC = GetObject("script:C:\Temp\test.wsc")
Dim objMyClass

WScript.Echo "IsObject(objMyClass): " & IsObject(objMyClass)

Set objMyClass = objWSC.Construct()
boolRes = objMyClass Is Nothing
WScript.Echo "IsObject(objMyClass): " & IsObject(objMyClass), "; objMyClass Is Nothing: " & boolRes

objMyClass.x1 = 2
objMyClass.x2 = 3
WScript.Echo objMyClass.Add()

' Первый путь очистки
'Set objMyClass = Nothing
'boolRes = objMyClass Is Nothing
'WScript.Echo "IsObject(objMyClass): " & IsObject(objMyClass), "; objMyClass Is Nothing: " & boolRes

' Второй путь очистки, через подобие destructor'а
objWSC.Destruct objMyClass
boolResult = objMyClass Is Nothing
WScript.Echo "IsObject(objMyClass): " & IsObject(objMyClass), "; objMyClass Is Nothing: " & boolResult

Благодарность за разъяснения - alexii.

В функциях, которые будут использоваться для чтения и записи объявленного свойства COM-сервера, можно использовать аргументы. Это позволит применять в клиентском скрипте синтаксис "свойств с параметрами". Например, код сервера:

<?xml version='1.0' encoding='windows-1251' standalone='yes'?>
<component>
<registration progid='testWSC'/>
<public>
    <property name='testProperty'><get/><put/></property>
</public>

<script language="JScript"><![CDATA[
var test;

function get_testProperty() {
    return test;
}

function put_testProperty(arg1, arg2) {
    test = arg1 * arg2;
}

]]></script>
</component>

После этого, например, в клиентском JS-скрипте будет вполне допустимо писать что-то вроде:

oTest = new ActiveXObject("testWSC")
oTest.testProperty(5) = 3;
WScript.Echo(oTest.testProperty); // 5 * 3 = 15
oTest.testProperty(5, 4) = 3;
WScript.Echo(oTest.testProperty); // 5 * 4 = 20
oTest.testProperty(5, 8, 6) = 3;
WScript.Echo(oTest.testProperty); // 5 * 8 = 40