1 (изменено: teadrinker, 2017-02-27 16:10:40)

Тема: AutoHotkey для чайников!

Почему не работает моя горячая клавиша?

q::MsgBox, Работает!
й::MsgBox, Работает!

Иногда при при попытке запустить скрипт, в котором в качестве горячих используются буквенные клавиши, выскакивает  ошибка:

Error: Invalid hotkey.

Восприятие скриптом горячих клавиш может зависеть от раскладки (ru-en) активного окна в данный момент, а также от раскладки по умолчанию. Чтобы обойти эту проблему при использовании клавиш, значение которых меняется в зависимости от раскладки, нужно вместо буквенного обозначения писать их виртуальные коды или скан-коды:

vk51::MsgBox, Работает в любой раскладке!   ; vk51 — виртуальный код клавиши Q-Й в шестнадцатеричном формате
sc11::MsgBox, Работает в любой раскладке!   ; sc10 — скан-код клавиши W-Ц в шестнадцатеричном формате

Для определения виртуальных и скан-кодов можно воспользоваться соответствующими таблицами, командой KeyHistory, а также этой программкой.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Skype dmitry_fiveg

2 (изменено: serzh82saratov, 2015-07-19 19:07:33)

Re: AutoHotkey для чайников!

Запись клавиш и их виртуальные коды.
В дополнение к первому посту.
Запись горячей клавиши с помощью виртуального кода имеет смысл только если эта клавиша "буквенно-символьная" (назовём их - КБС), то есть тех которые при печати посылают разные символы, зависящие от текущего языка ввода активного окна. Остальные клавиши имеют свои имена, записывать их через виртуальный код не имеет смысла, и вносит излишние "непонятки" в код.

Использование виртуальных кодов в команде Send.
Например есть цель по клавише F12 нажать "Ctrl+A" (выделение всего текста, "а" - латинская) в активном окне.

F12::Send ^{a}

Если в момент нажатия F12 в окне английский язык ввода, то текст выделится (целевое назначение комбинации сработает), а вот если язык ввода будет например русский, то просто напечатается латинская  "а". Чтобы такого не случилось, и результат нажатия не зависел от языка ввода, КБС необходимо указать через виртуальный код.

F12::Send ^{vk41}    ;  "A"

Для получения виртуального кода или имени клавиши, определения его необходимости (КБС определяются как виртуальный код, остальные пишутся по имени), и получения имени клавиши из виртуального кода, можно воспользоватся AhkSpy.

П.С. Добавляя виртуальный код в свой скрипт, не забывайте в комментарии указывать что он значит, особенно когда его постите на форуме.

По вопросам возмездной помощи пишите в личку
E-Mail: serzh82saratov@mail.ru
OS: Win7x64, AutoHotkey_L v1.1.25.01 (Unicode 32-bit).

3

Re: AutoHotkey для чайников!

Имитация физического зажатия клавиши


Send {vk41}         ; нажатие и отпускание клавиши "a"
Send {vk41 Down}    ; нажатие клавиши "a"
Send {vk41 Up}      ; отпускание клавиши "a"

При физическом «зажатии» клавиши начинает генерироваться «автоповтор нажатий», некоторые программы, для использования в которых вы вероятно и пишете свой скрипт, воспринимают зажатие именно как непрерывную последовательность нажатий.

Например, при нажатии пробела «зажать» клавишу A(Ф), при следующем нажатии пробела — «отпустить»:

Space::
    If isKeyPressed := !isKeyPressed    ; Позволяет чередовать действия при нажатии пробела . При каждой проверке этого условия в переменную isKeyPressed записывается значение обратное её текущему значению.
        SetTimer, SendA, 40             ; Таймер позволяет отправлять нажатия каждые 40мс и не мешает скрипту в паузах «параллельно» выполнять прочие подпрограммы.
    Else
    {
        SetTimer, SendA, Off            ; Если это второе нажатие пробела — выключаем таймер
        Send {vk41 Up}                  ; Чтоб не возникло «залипание» отправляем отпускание клавиши.
    }
    KeyWait Space                       ; ждём физического отпускания пробела чтоб не перезапускать таймер при каждом нажатии пробела во время автоповтора нажатий пробела.
    return

SendA:
    Send {vk41 Down}
    return

4

Re: AutoHotkey для чайников!

Как записать выражение в параметр команды, требующий строчного значения?
Для примера возьмём команду Send. Предположим, нам нужно отправить в активное окно цифру. Всё просто:

Send 5

А если цифра находится в переменной? Тогда можно так:

Var := 5
Send %Var%

Но бывают случаи, когда отправить нужно результат выражения с переменными, например, их сумму, или произведение.
Вот так не получится:

Var1 := 5
Var2 := 10
Send %Var1% + %Var2%

Тем более, что "+" в данном случае будет интерпретироваться командой, как "Shift".
Так тоже не выйдет:

Var1 := 5
Var2 := 10
SendRaw %Var1% + %Var2%

Теперь посылается просто строка "5 + 10", а не сумма. Как же быть? Есть два варианта. Первый, более длинный — сначала отдельно вычислить результат выражения, сохранить его в переменной, и тогда уже отправлять, как в примере выше:

Var1 := 5
Var2 := 10
Var3 := Var1 + Var2
Send %Var3%

Но есть более "продвинутый" способ — если в начале параметра команды первым символом поставить знак процента с пробелом за ним, то дальше можно писать выражение любой длины и сложности, а в параметр будет записан его результат:

Var1 := 5
Var2 := 10
Send % Var1 + Var2

Переменные в таком случае пишутся без обрамления в знаки процента.

Иногда в описании параметров команд специально оговаривается, что параметр может быть выражением. Например, MouseMove:

MouseMove, X, Y [, Speed, R]

X, Y
    The x/y coordinates to move the mouse to, which can be expressions.

В таком случае для записи выражения предварять его знаком процента с пробелом не нужно:

Var1 := 400
Var2 := 200
CoordMode, Mouse, Screen
MouseMove, Var1 + Var2, Var1 - Var2
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Skype dmitry_fiveg

5 (изменено: mozers, Вчера 21:09:46)

Re: AutoHotkey для чайников!

Почему оператор присвоения = не работает так как в других языках?

Оператор присвоения, в других языках программирования выглядящий как = , в AutoHotkey записывается как :=.
Оператор = так же существует, но его использование ограничено рядом правил и условностей. Крайне не рекомендуется использовать в своих скриптах оператор = до тщательного изучения особенностей работы с ним. Тем более что почти не существует случаев когда без применения оператора = нельзя обойтись.
Речь шла о = как операторе присвоения. Как оператор сравнения = используется наряду с другими (<, >, >=, <= и т.п.) самым привычным образом.