Вы не вошли. Пожалуйста, войдите или зарегистрируйтесь.
Страницы 1
Чтобы отправить ответ, вы должны войти или зарегистрироваться
Здравствуйте. Подскажите пожалуйста, каким образом можно подсветить окно по pid процесса.
Вот к примеру открыто большое количество одноимённых окон. Хочется по определённому pid процесса сделать подсветку окна, чтобы впоследствии его открыть. Подсветка нужна именно windows'овская, жёлтая такая, наверняка понимаете о чём я говорю.
Вопрос как сделать такую подсветку? :c
Программа может мигать кнопкой на панели задач, когда она выдаёт диалоговое окно при том, что на переднем плане находится окно другой программы. Такое же поведение бывает при использовании команды GUI, flash.
Возможно, такого эффекта получится добиться оконными сообщениями или стилями. Можно попытаться отследить программой Winspector Spy.
Я и говорю про подсветку кнопки в панели задач. Значок в панели задач является кнопкой, не так ли?
stealzy, нашёл только под windows 7 
Хотя может не там искал... не знаю. Если ты разбираешься, понимаешь что искать, можешь найти? Тебе это куда легче будет.
У меня такой код работает под Windows 10:
Gui, +hwndhGui
Gui, Font, s12 q5, Calibri
Gui, Add, Text,, Кнопка на панели задач будет мигать,`nпока окно не станет активным
Gui, Show, NA w300 h200
FlashTaskBarButton(hGui)
Return
GuiClose:
ExitApp
FlashTaskBarButton(hGui, count := 0) {
static FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC
VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)
NumPut(count, NumPut(FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), NumPut(hGui, NumPut(size, FLASHWINFO)), "UInt"))
DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}
Кстати в классической теме в Win7 кнопки на панели задач не мигают. В классической на WinXP тоже вроде не мигали.
teadrinker, а что делает этот код? Я запустил, и ничего нигде не замигало.
И не совсем понятно, можно ли настроить эту функцию на мигание определённого процесса (определяемого по id или pid или hwnd, как удобнее) ?
ypppu, мне нужно под windows 10. Мигать должны не только окна autohotkey скриптов, но и окна любого другого запущенного процесса (В моём случае процесса игры gta samp)
а что делает этот код?
Обращается к WinAPI:
https://docs.microsoft.com/en-us/window … shwindowex
Malcev, ну хорошо, обращается. Обычно при обращении выходит какой-то ответ. При запуске же этого кода ничего не происходит.
В смысле, ничего не происходит? Окно появляется?
teadrinker, окно то появляется. Только при этом ничего не мигает.
Cделал вот ещё код для проверки, будут ли мигать текущие открытые окна или нет. Также ничего не мигало...
#SingleInstance Force
#Persistent
#NoEnv
text := ""
WinGet, id, list,,, Program Manager
Loop % id
{
this_id := id%A_Index%
WinGetClass, this_class, ahk_id %this_id%
WinGet, pid, PID, ahk_id %this_id%
text .= this_class "`n" pid "`n" this_id "`n`n"
FlashTaskBarButton(this_id)
}
msgbox % text
Return
FlashTaskBarButton(hGui, count := 0) {
static FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC
VarSetCapacity(FLASHWINFO, size := A_PtrSize*2 + 4*4, 0)
NumPut(count, NumPut(FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), NumPut(hGui, NumPut(size, FLASHWINFO)), "UInt"))
DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}
А сама кнопка на панели задач появляется? И не мигает?
Тут ошибка:
VarSetCapacity(FLASHWINFO, size := A_PtrSize*2 + 4*4, 0)Надо так:
VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)
Да, точно.
Во! Сейчас работает. А резонный вопрос, какой манипуляцией кода можно остановить это мигание?))) (Кроме как переключиться к мигающему окну)
Ответ на свой вопрос получите, почитав ссылку из 10 поста.
Во! Сейчас работает.
Неужели 32-битные Windows 10 бывают? 
Malcev, конкретно в той ссылке нет информации, как это мигание останавливать.
Нашёл на вот этой странице https://docs.microsoft.com/ru-ru/window … flashwinfo
похожий на правду параметр. Только как его в коде то применить? Пробовал FLASHWINFO := 0 делать, не помогло.
Вот так удалось порешать.
FlashTaskBarButton(hGui)
sleep 3000
FlashTaskBarButton(hGui,0,0,0)
Return
FlashTaskBarButton(hGui, count := 0, FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC) {
VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)
NumPut(count, NumPut(FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), NumPut(hGui, NumPut(size, FLASHWINFO)), "UInt"))
DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}
FLASHW_TRAY и FLASHW_TIMERNOFG — это константы, им не надо другие значения присваивать.
Лучше так:
Gui, +hwndhGui
Gui, Font, s12 q5, Calibri
Gui, Add, Text,, Кнопка на панели задач мигнёт 3 раза`nпотом будет подсвечена`nпока не пройдёт 5 секунд`nили пока окно не станет активным
Gui, Show, NA w300 h200
FlashTaskBarButton(hGui, 3)
Sleep, 5000
FlashTaskBarButton(hGui,, 1)
Return
GuiClose:
ExitApp
FlashTaskBarButton(hGui, count := 0, stop := 0) {
static FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC
VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)
NumPut(size, FLASHWINFO)
NumPut(hGui, FLASHWINFO, A_PtrSize)
NumPut(stop ? 0 : FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), FLASHWINFO, A_PtrSize*2)
NumPut(count, FLASHWINFO, A_PtrSize*2 + 4)
DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}
kolotilov256 пишет:Во! Сейчас работает.
Неужели 32-битные Windows 10 бывают?
У меня не работало на Win10 64bit, Ahk 32bit.
Страницы 1
Чтобы отправить ответ, вы должны войти или зарегистрироваться
