1

Тема: VBScript: загрузка файлов из Интернет

Скачивание текстового файла с HTTP-ресурса и сохранение его на локальном жёстком диске:

'URL файла в Интернете
sUrlRequest = "http://cbrates.rbc.ru/tsv/cb/840.tsv"
'создание объекта XMLHTTP
Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP")
'подключение
'oXMLHTTP.Open "GET", sUrlRequest, False, MyName, MyPassword
oXMLHTTP.Open "GET", sUrlRequest, False
'получение файла
oXMLHTTP.Send
'создание и открытие текстового файла для сохранения
set fso = CreateObject("Scripting.FileSystemObject")
fso.CreateTextFile "c:\test.txt", True
Set f = fso.OpenTextFile("c:\test.txt", 2, True)
'сохранение
f.WriteLine(oXMLHTTP.Responsetext)
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

2

Re: VBScript: загрузка файлов из Интернет

Закачка файла по FTP:

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.NameSpace("D:\Temp") 'место назначения
objFolder.CopyHere "ftp://User:Password@domen_name.ru/folder/subfolder/filename.zip"
WScript.Sleep 60000 'даём время на скачивание (минута)
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

3

Re: VBScript: загрузка файлов из Интернет

Закачка бинарного (не текстового) файла по HTTP и сохранение его на локальном жёстком диске:

Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP")
'подключение
oXMLHTTP.Open "GET", "http://www.script-coding.com/ocs_last.dos.zip", 0
'получение файла
oXMLHTTP.Send
Set oADOStream = CreateObject("ADODB.Stream")
oADOStream.Mode = 3 'разрешение на чтение и запись
oADOStream.Type = 1 'тип данных - Binary
oADOStream.Open
oADOStream.Write oXMLHTTP.responseBody
'сохранение (с перезаписью файла при необходимости)
oADOStream.SaveToFile "D:\Temp\ocs_last.dos.zip", 2
MsgBox "Файл D:\Temp\ocs_last.dos.zip сохранён."
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

4

Re: VBScript: загрузка файлов из Интернет

Закачка бинарного (не текстового) файла по HTTPS и сохранение его на локальном жёстком диске:

login = "имя"
password = "пароль"
Set x = CreateObject("WinHttp.WinHttpRequest.5.1")
call x.Open("GET", "https://secure.eicar.org/download/eicarcom2.zip", 0, login, password)
x.Send()
Set s = CreateObject("ADODB.Stream")
s.Mode = 3
s.Type = 1
s.Open()
s.Write(x.responseBody)
call s.SaveToFile("C:\eicarcom2.zip", 2)

Информацию опубликовал smaharbA.

Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

5

Re: VBScript: загрузка файлов из Интернет

Закачка html-странички из Интернет, если вы находитесь за Proxy:

Set srvXmlHttp = CreateObject("Msxml2.ServerXMLHTTP.4.0")
srvXmlHttp.Open "GET", "http://script-coding.com", False
srvXmlHttp.setProxy 2, "192.168.100.1:3128"
srvXmlHttp.setProxyCredentials "user", "password"
srvXmlHttp.send
MsgBox srvXmlHttp.responseText
MsgBox srvXmlHttp.Status & "-" & srvXmlHttp.statusText

Используется объект ServerXMLHTTP.
Если неправильно указать логин/пароль, придёт html-страница от прокси с отказом.
Автор примера — ingvar68.

Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.