AHK: Чтение\запись файла по битам\байтам. (криптография)

SetBatchLines, -1
SourseFile := A_Desktop "\test.txt"   ; указать пути к файлам
HexDataFile := A_Desktop "\hex.txt"
TargetFile := A_Desktop "\target.txt"
return

!1::
   GetHexData(SourseFile, HexDataFile)
   MsgBox, Готово!
   return
   
!2::
   WriteFileFromHexData(HexDataFile, TargetFile)
   MsgBox, Готово!
   ExitApp

GetHexData(SourseFile, HexDataFile)
{
   File := FileOpen(SourseFile, "r")
   FileSize := File.Length

   VarSetCapacity(buf, FileSize)
   File.RawRead(buf, FileSize)
   File.Close()

   SetFormat, IntegerFast, H
   Loop % FileSize
      Text .= (A_Index = 1 ? "" : " ") . SubStr("0" . SubStr(NumGet(buf, A_Index - 1, "UChar"), 3), -1)

   FileDelete, % HexDataFile
   FileAppend, % Text, % HexDataFile
}

WriteFileFromHexData(HexDataFile, TargetFile)
{
   FileRead, Text, % HexDataFile

   VarSetCapacity(buf, FileSize := (StrLen(RegExReplace(Text, "\s"))/2))

   Loop, parse, Text, % " "
   {
      Number := "0x" . A_LoopField
      NumPut(Number, buf, A_Index - 1, "UChar")
   }

   File := FileOpen(TargetFile, "w")
   File.RawWrite(buf, FileSize)
   File.Close()
}

SetBatchLines, -1
SourseFile := A_Desktop "\test.txt"   ; указать пути к файлам
HexDataFile := A_Desktop "\hex.txt"
TargetFile := A_Desktop "\target.txt"
return

!1::
   GetHexData(SourseFile, HexDataFile)
   MsgBox, Готово!
   return
   
!2::
   WriteFileFromHexData(HexDataFile, TargetFile)
   MsgBox, Готово!
   ExitApp

GetHexData(SourseFile, HexDataFile)
{
   BinaryStream := ComObjCreate("ADODB.Stream")
   BinaryStream.Type := 1 ; adTypeBinary
   BinaryStream.Open
   BinaryStream.LoadFromFile(SourseFile)
   BinaryArray := BinaryStream.Read
   BinaryStream.Close

   SetFormat, IntegerFast, H
   Loop % BinaryArray.MaxIndex() + 1
      Text .= (A_Index = 1 ? "" : " ") . SubStr("0" . SubStr(BinaryArray[A_Index-1]+0, 3), -1)
   
   File := FileOpen(HexDataFile, "w")
   File.Write(Text)
   File.Close()
}

WriteFileFromHexData(HexDataFile, TargetFile)
{
   FileRead, Text, % HexDataFile

   VarSetCapacity(buf, FileSize := StrLen(RegExReplace(Text, "\s"))/2)
   Loop, parse, Text, % " "
      NumPut("0x" . A_LoopField, buf, A_Index - 1, "UChar")

   File := FileOpen(TargetFile, "w")
   File.RawWrite(buf, FileSize)
   File.Close()
}

/*
В пин коде допустимы цифры, и регистрозависимые буквы латинского алфавита.
Длинна пин кода может быть любой длинны.
Если файл кодируется, то файл-шифр создаётся в той же папке с добавлением ".crypt"
к имени файла. Файл-шифр всегда бинарный. Кодировать можно любые типы файлов,
 с сохранением кодировки.
Если файл декодируется, то файл-шифр должен иметь расширение "crypt",
результат создаётся в той же папке с удалением ".crypt" в конце имени файла.
Файл добавляется путём перетаскивания на окно.
*/
#SingleInstance Force
#Persistent 
#MaxMem 4095  
SetBatchLines -1 
   
Gui, +AlwaysOnTop -DPIScale 
Gui, Add, Text, x10, Pin:
Gui, Add, Edit, x55 yp w220 vPIN 
Gui, Add, Text, x10, File:
Gui, Add, Edit, x55 yp w220 vFile +ReadOnly 
 
Gui, Add, Button, xs y+5 w74 gCode vEnCode, EnCode
Gui, Add, Button, x+115 w74 gCode vDeCode, DeCode
Gui, Show, , Шифрование
Return 
    
GuiDropFiles: 
    If (A_EventInfo > 1)     
        MsgBox, 262192, Ошибка!, Можно выбрать только один файл, 1
    Else
        GuiControl,, File, % RegExReplace(CodeFile := A_GuiControlEvent, ".*\\(.*)", "$1")
    Return
 

Code:  
    Critical
    Gui, Submit, NoHide 
    GuiControl := A_GuiControl
    SplitPath, CodeFile, , Dir, Ext, NameNoExt 
    Error_PIN := (RegExMatch(PIN, "i)[^0-9a-z]") || PIN = "")
    Error_FileExist := (!FileExist(CodeFile) || InStr(FileExist(CodeFile), "D"))
    Error_DeCodeExt := (GuiControl = "DeCode" && Ext != "crypt")
    If (Error_PIN || Error_FileExist || Error_DeCodeExt)
        MsgBox, 262192, Ошибка!
            , % (Error_PIN ? "*** В пин коде допустимы только цифры, и символы латинского алфавита" : "")
            . (Error_FileExist ? "`n`n*** Кодируемый файл несуществует" : "")
            . (Error_DeCodeExt ? "`n`n*** Это не кодированный файл" : "")
    Else   
    {     
        TargetFile := GuiControl = "EnCode" ? CodeFile ".crypt" : Dir "\" NameNoExt 
        GuiControl,, %GuiControl%, 0 `% 
        crypt() 
        GuiControl,, %GuiControl%, %GuiControl%
        Gui, Show
    } 
    Return
    
crypt()   {    
    Global PIN, CodeFile, TargetFile, GuiControl
    File := FileOpen(CodeFile, "r"), File.Pos := 0 
    Size := File.RawRead(Bin, file.length), File.Close()
    VarSetCapacity(buf, Size, 0)  
    maxPin := StrLen(PIN), iPin := Percent := 0, StepPercent := Size // 100
    
    Loop % Size
    {
        NumPut((Abs(((NumGet(Bin, A_Index - 1, "Char")) + (Asc(SubStr(PIN, (iPin := iPin = maxPin ? 1 : iPin + 1), 1)))) - 255)), buf, A_Index - 1, "Char")  
        If !Mod(A_Index, StepPercent)
            GuiControl,, %GuiControl%, % ++Percent " `%"   
    }
    File := FileOpen(TargetFile, "w"), File.Length := 0
    File.RawWrite(buf, Size), File.Close()  
}     
   
GuiClose: 
    ExitApp 

(Error_FileExist ? "`n`n*** Кодируемый файл несуществует" : "")