AHK: Поиск и выделение текста в поле Edit

Text =
(
Как можно сделать поиск в поле Edit?
Так что бы при нахождении вводимого текста он выделялся, как например в стандартном блокноте Windows.
)

Gui, +Resize
Gui, Add, Edit, x0 y0 w500 h200 vMainEdit HWNDhMainEdit, %Text%
Gui, 2: +AlwaysOnTop +Owner +ToolWindow
Gui, 2: Add, Edit, x0 y0 w210 h20 vSearchText HWNDhSearchEdit
Gui, 2: Add, Button, x210 y0 w40 h20 gGoSearch, Поиск
Gui, Show, xCenter y125 w500 h200, GuiEdit
Hotkey, IfWinActive, GuiEdit
Hotkey, ^sc021, SearchEdit ;Ctrl+F
EM_SETSEL = 0xB1
EM_SCROLLCARET = 0xB7
return

SearchEdit:
Gui, 2: Show, xCenter y180 w250 h20, Введите текст для поиска
Hotkey, IfWinActive, Введите текст для поиска
Hotkey, Enter, GoSearch ;Enter
return

GoSearch:
ControlGetText, Haystack,, ahk_id %hMainEdit%
ControlGetText, Needle,, ahk_id %hSearchEdit%
If( Pos := InStr( Haystack, Needle ) ) {
    Gui, 2: Hide
    SendMessage, %EM_SETSEL%, % Pos - 1, % Pos - 1 + StrLen( Needle ),, ahk_id %hMainEdit%
    SendMessage, %EM_SCROLLCARET%, 0, 0,, ahk_id %hMainEdit%
}
Else {
    ControlSetText,, Не найдено, ahk_id %hSearchEdit%
}
return

GuiClose:
ExitApp

#SingleInstance Force
#NoEnv
StringCaseSense Locale

ES_NOHIDESEL := 256  ; показывает выделение текста в Edit при неактивном окне
EM_SETSEL := 0x00B1  ; установка выделения
EM_SCROLLCARET := 0xB7  ; сделать видимым выделенный текст
EM_GETSEL := 0xB0  ; извлечь позицию каретки ввода
VarSetCapacity(start, 4), VarSetCapacity(end, 4)

Loop 12
    Text .= "Как можно сделать поиск в поле Edit?`n"

Gui, -DPIScale +HWNDhGUIMain
Gui, Add, Edit, x0 y0 w500 h100 vMainEdit hwndhMainEdit %ES_NOHIDESEL%, %Text%
PostMessage, EM_SETSEL, 0, 0, , ahk_id %hMainEdit%
Gui, Show, w500 h300, Edit find

Gui, 2: +Owner1 -MaximizeBox -MinimizeBox -DPIScale +HWNDhGUIFind
Gui, 2: Add, Text, ym+5, Что:
Gui, 2: Add, Edit, x+25 yp-5 w284 vFind hwndhFind, Можно
Gui, 2: Add, Button, x+10 yp gGoSearch, Найти далее
Gui, 2: Add, Button, xp y+5 wp gCancel, Отмена
Gui, 2: Add, Checkbox, vSens y+0 xm, С учетом регистра
Gui, 2: Add, GroupBox, x+10 yp-25 h50, Направление
Gui, 2: Add, Radio, xp+10 yp+25 vDirectUp, Вверх
Gui, 2: Add, Radio, x+15 Checked, Вниз 

SearchEdit: 
    Gui, 2: Show, , Найти
    Return
    
Cancel:
    Gui, 2: Hide
    Return

GoSearch:
    GuiControlGet, DirectUp, 2:
    GuiControlGet, Sens, 2:
    ControlGetText, MainEdit,, ahk_id %hMainEdit%
    ControlGetText, Find,, ahk_id %hFind%
    SendMessage, EM_GETSEL, &start, &end, , ahk_id %hMainEdit%
    If DirectUp
        f := (f := InStr(SubStr(MainEdit, 1, NumGet(start)), Find, Sens, 0)) ? f : InStr(MainEdit, Find, Sens, 0)
    Else
        f := (f := InStr(MainEdit, Find, Sens, NumGet(end)+1)) ? f : InStr(MainEdit, Find, Sens, 1)
    If !f
    {
        MsgBox, 8256, Edit find, Не удаётся найти "%Find%"
        Return
    }
    PostMessage, EM_SETSEL, f-1, f+StrLen(Find)-1, , ahk_id %hMainEdit%
    PostMessage, EM_SCROLLCARET,,,, ahk_id %hMainEdit%
    Return

#If WinActive("ahk_id" hGUIMain)
F3::
^vk46:: GoSub SearchEdit   ;  "Ctrl+F"
#If WinActive("ahk_id" hGUIFind)
Enter:: GoSub GoSearch
#If

GuiEscape:
GuiClose:
    ExitApp

To send this message, call the SendMessage function as follows. 

lResult = SendMessage(      // returns LRESULT in lResult
   (HWND) hWndControl,      // handle to destination control
   (UINT) EM_SETSEL,        // message ID
   (WPARAM) wParam,         // = (WPARAM) () wParam;
   (LPARAM) lParam          // = (LPARAM) () lParam; );  

#SingleInstance Force
#NoEnv
StringCaseSense Locale

ES_NOHIDESEL := 256  ; показывает выделение текста в Edit при неактивном окне
EM_SETSEL := 0x00B1  ; установка выделения
EM_SCROLLCARET := 0xB7  ; сделать видимым выделенный текст
EM_GETSEL := 0xB0  ; извлечь позицию каретки ввода
VarSetCapacity(start, 4), VarSetCapacity(end, 4)

Loop 12
    Text .= "Как можно сделать поиск в поле Edit?`n"

Gui, -DPIScale +HWNDhGUIMain
Gui, Add, Edit, x0 y0 w500 h100 vMainEdit hwndhMainEdit %ES_NOHIDESEL%, %Text%
SendMessage, EM_SETSEL, 0, 0, , ahk_id %hMainEdit%
Gui, Show, w500 h300, Edit find

Gui, 2: +Owner1 -MaximizeBox -MinimizeBox -DPIScale +HWNDhGUIFind
Gui, 2: Add, Text, ym+5, Что:
Gui, 2: Add, Edit, x+25 yp-5 w284 vFind hwndhFind, Можно
Gui, 2: Add, Button, x+10 yp gGoSearch, Найти далее
Gui, 2: Add, Button, xp y+5 wp gCancel, Отмена
Gui, 2: Add, Checkbox, vLoop y+0 xm Checked, Зациклить поиск
Gui, 2: Add, Checkbox, vSens y+10 xp, С учетом регистра
Gui, 2: Add, GroupBox, x+10 yp-35 h55, Направление
Gui, 2: Add, Radio, xp+10 yp+25 vDirectUp, Вверх
Gui, 2: Add, Radio, x+15 Checked, Вниз 

SearchEdit: 
    Gui, 2: Show, , Найти 
    Return
    
Cancel:
    Gui, 2: Hide
    Return

GoSearch:
    GuiControlGet, DirectUp, 2:
    GuiControlGet, Sens, 2:
    GuiControlGet, Loop, 2:
    ControlGetText, MainEdit,, ahk_id %hMainEdit%
    ControlGetText, Find,, ahk_id %hFind%
    SendMessage, EM_GETSEL, &start, &end, , ahk_id %hMainEdit%
    If DirectUp
        f := (f := InStr(SubStr(MainEdit, 1, NumGet(start)), Find, Sens, 0)) ? f : (Loop ? InStr(MainEdit, Find, Sens, 0) : 0)
    Else
        f := (f := InStr(MainEdit, Find, Sens, NumGet(end)+1)) ? f : (Loop ? InStr(MainEdit, Find, Sens, 1) : 0)
    If !f
    {
        MsgBox, 8256, Edit find, Не удаётся найти "%Find%"
        Return
    }
    SendMessage, EM_SETSEL, f-1, f+StrLen(Find)-1, , ahk_id %hMainEdit%
    SendMessage, EM_SCROLLCARET,,,, ahk_id %hMainEdit%
    Return

#If WinActive("ahk_id" hGUIMain)
F3:: GoSub GoSearch
^vk46:: GoSub SearchEdit   ;  "Ctrl+F"
#If WinActive("ahk_id" hGUIFind)
Enter:: GoSub GoSearch
#If

GuiEscape:
GuiClose:
    ExitApp