OFF: Обновления AutoHotkey

<h3>Parameters</h3>
<dl>

  <dt>Frequency</dt>
  <dd><p>The frequency of the sound, which can be an <a href="../Variables.htm#Expressions">expression</a>. It should be a number between 37 and 32767. If omitted, the frequency will be 523.</p></dd>

  <dt>Duration</dt>
  <dd><p>The duration of the sound, in milliseconds (can be an <a href="../Variables.htm#Expressions">expression</a>). If omitted, the duration will be 150.</p></dd>

</dl>

<h3>Parameters</h3>
<table class="info">
  <tr> 
    <td>Frequency</td>
    <td>The frequency of the sound, which can be an <a href="../Variables.htm#Expressions">expression</a>. It should be a number between 37 and 32767. If omitted, the frequency will be 523. </td>
  </tr>
  <tr> 
    <td width="15%">Duration</td>
    <td width="85%">The duration of the sound, in milliseconds (can be an <a href="../Variables.htm#Expressions">expression</a>). If omitted, the duration will be 150.</td>
  </tr>
</table>

/* table of command parameters */
table.info {
    border: solid 2px #C0C0C0;
    border-collapse: collapse;
    width: 100%;
    /*table-layout: fixed;*/
}

h3 {
    color:  #008800;
}

Dim aFiles()

If WScript.Arguments.Count = 0 then
    MsgBox "Drag'n'Drop folder(s) or file(s) onto script to process"
    WScript.Quit
End If

Set oFSO = CreateObject("Scripting.FileSystemObject")
Redim aFiles(-1)
For Each sSrc In WScript.Arguments
    AddFiles sSrc
Next
If UBound(aFiles) = -1 Then
    MsgBox "No files selected"
    WScript.Quit
End If

lSaved = 0
For Each sSrc In aFiles
    If LCase(oFSO.GetExtensionName(sSrc)) = "htm" Then
        If LCase(oFSO.GetBaseName(sSrc)) <> "license" and instr(ssrc, "-mod.htm") = 0 Then
            sCont = ReadFromFile(sSrc)
            If sCont <> "" then
                bChanged = False
                sRes = ""
                lEnd = 1
                Do
                    If lEnd > Len(sCont) Then Exit Do
                    sCont = Mid(sCont, lEnd)
                    If GetFragment(sCont, "<dl>", "</dl>", sTmp0, lBeg, lEnd) Then
                        bChanged = True
                        sRes = sRes & Left(sCont, lBeg - 1)
                        sRes = sRes & "<table class=""info"">" & vbCrLf
                        lLast = 1
                        Do
                            If lLast > Len(sTmp0) Then Exit Do
                            sTmp0 = Mid(sTmp0, lLast)
                            If Not GetFragment(sTmp0, "<dt>", "</dt>", sTmp1, 0, 0) Then Exit Do
                            If Not GetFragment(sTmp0, "<dd>", "</dd>", sTmp2, 0, lLast) Then Exit Do
                            sRes = sRes & "  <tr>" & vbCrLf
                            sRes = sRes & "    <td width=""15%"">" & sTmp1 & "</td>" & vbCrLf
                            sRes = sRes & "    <td width=""85%"">" & sTmp2 & "</td>" & vbCrLf
                            sRes = sRes & "  </tr>" & vbCrLf
                        Loop
                        sRes = sRes & vbCrLf & "</table>"
                    Else
                        sRes = sRes & sCont
                        Exit Do
                    End If
                Loop
                If bChanged Then
                    WriteToFile sRes, sSrc, lSaved
                End If
            End If
        End If
    ElseIf LCase(oFSO.GetFileName(sSrc)) = "theme.css" Then
        sCont = ReadFromFile(sSrc)
        If sCont <> "" then
            If GetFragment(sCont, vbCrLf & "h3 {", "}", "", lBeg, lEnd) Then
                sCont = Left(sCont, lBeg - 1) & Mid(sCont, lEnd)
            End If
            sCont = sCont & vbCrLf & "h3 {" & vbCrLf & "    color:  #000000;" & vbCrLf & "}" & vbCrLf
            WriteToFile sCont, sSrc, lSaved
        End If
    End If
Next

MsgBox lSaved & " Files saved"

Function ReadFromFile(sPath)
    REM OpenTextFile(<Filename>,<Iomode>,<Create>,<Format>)
    With oFSO.OpenTextFile(sSrc, 1, False, 0)
        ReadFromFile = ""
        If Not .AtEndOfStream Then ReadFromFile = .ReadAll
        .Close
    End With
End Function

Sub WriteToFile(sCont, sPath, lCount)
    With oFSO.OpenTextFile(sPath, 2, True, 0)
        .Write(sCont)
        .Close
    End With
    lCount = lCount + 1
End Sub

Function GetFragment(sText, sBeg, sEnd, sRes, lBeg, lEnd)
    REM InStr([start,] str1, str2[, compare])
    REM Mid(str, start[, len]))
    Dim lBegExcl, lEndExcl
    lBeg = InStr(1, sText, sBeg)
    If lBeg > 0 Then
        lBegExcl = lBeg + Len(sBeg)
        lEndExcl = InStr(lBegExcl, sText, sEnd)
        lEnd = lEndExcl + Len(sEnd)
        If lEndExcl > 0 Then
            sRes = Mid(sText, lBegExcl, lEndExcl - lBegExcl)
            GetFragment = True
            Exit Function
        End If
    End If
    sRes = ""
    GetFragment = False
End Function

Sub AddFiles(sPath)
    Dim oItem
    If oFSO.FileExists(sPath) Then
        AddFile sPath
        Exit Sub
    End If
    If oFSO.FolderExists(sPath) Then
        For Each oItem In oFSO.GetFolder(sPath).Files
            AddFile oItem.Path
        Next
        For Each oItem In oFSO.GetFolder(sPath).SubFolders
            AddFiles oItem.Path
        Next
        
    End If
End Sub

Sub AddFile(sPath)
    Redim Preserve aFiles(UBound(aFiles) + 1)
    aFiles(UBound(aFiles)) = sPath
End Sub

Menu, Tray, Icon , %A_AhkPath%, 6, 1