AHK: Добавление элементов в чужое контекстное меню

#Persistent
global EVENT_OBJECT_SHOW := 0x8002, WINEVENT_SKIPOWNTHREAD := 1

/*
В функцию передаётся массив.
1-й ключ — название ф-ции, обрабатывающей клик по нашему пункту меню.
2-й ключ — объект, ключи которого должны точно соответствовать названию классов окон, в edit-меню которых добавляем наши пункты,
а значения этих ключей — масиивы со списком названий наших пунктов
*/
AddMyEditMenu( [ "RunMyMenu", { Notepad: ["MyItem1", "MyItem2"], "Notepad++": ["MyItem1", "MyItem2"] } ] )

RunMyMenu(MenuHWND, WindowClass, items)  ; ф-ция, обрабатывающей клик по нашему пункту меню
{
	if ((item := IsMouseOverMyMenu(MenuHWND, items)) = "")
		Return
; здесь должно быть действие в зависимости от класса окна и названия нашего пункта меню
	MsgBox, % WindowClass "`n" item
}

AddMyEditMenu(obj)
{
	Hotkey, ~LButton     , Dummy, On
	Hotkey, ~RButton Up, Dummy, On
	Hotkey, ~AppsKey Up, Dummy, On
	addr := Object(obj)
	OnExit(Func("ReleaseObj").Bind(addr))
	SetWinEventHook(EVENT_OBJECT_SHOW, EVENT_OBJECT_SHOW, 0, RegisterCallback("HookProc", "F", 3, addr), 0, 0, WINEVENT_SKIPOWNTHREAD)
}

HookProc(hWinEventHook, event, hwnd)
{
	static hwnd_prev := 0
	IfWinExist, ahk_id %hwnd_prev%
		Return
	
	if (A_ThisHotkey = "~LButton") && !(A_ThisHotkey = "~RButton Up") && !(A_ThisHotkey = "~AppsKey Up")
		Return
	
	WinGetClass, class, ahk_id %hwnd%
	if !(class = "#32768")
		Return
	
	obj := Object(A_EventInfo)
	WinGetClass, class, A
	for k in obj[2]
		(k == class && match := 1)
	if !match
		Return
	
	ControlGetFocus, focus, A
	if !RegExMatch(focus, "^(Edit|Scintilla)\d+")
		Return
	
	AppEndMyMenu(obj[2][class])
	FuncObj := Func(obj[1]).Bind(hwnd, class, obj[2][class])
	Hotkey, ~LButton, % FuncObj, On
	hwnd_prev := hwnd
}

AppEndMyMenu(items)
{
	static MN_GETHMENU := 0x1E1, MF_STRING := 0, MF_SEPARATOR := 0x800
	SendMessage, MN_GETHMENU,,,, ahk_class #32768
	hMenu := ErrorLevel
	DllCall("AppendMenu", Ptr, hMenu, UInt, MF_SEPARATOR, UInt, 0, Str, "")
	for k, item in items
		DllCall("AppendMenu", Ptr, hMenu, UInt, MF_STRING, UInt, "", Str, item)
}

IsMouseOverMyMenu(MenuHWND, items)
{
	MouseGetPos,,, ID
	if !(ID = MenuHWND)
		Return
	
	AccObj := AccObjectFromPoint(child)
	item := AccObj.AccName(child)
	for k, v in items
		if (v == item)
			Return item
}

AccObjectFromPoint(ByRef _idChild_ = "", x = "", y = "")
{
	static VT_DISPATCH := 9, h := DllCall("LoadLibrary", Str, "oleacc", Ptr)
	
	(x = "" || y = "") ? DllCall("GetCursorPos", Int64P, pt) : pt := x & 0xFFFFFFFF | y << 32

	VarSetCapacity(varChild, 8 + 2*A_PtrSize, 0)
	if	DllCall("oleacc\AccessibleObjectFromPoint", Int64, pt, PtrP, pAcc, Ptr, &varChild) = 0
		Return ComObjEnwrap(VT_DISPATCH, pAcc, 1), _idChild_ := NumGet(varChild, 8, "UInt")
}
	
SetWinEventHook(eventMin, eventMax, hmodWinEventProc, lpfnWinEventProc, idProcess, idThread, dwFlags)
{
   return DllCall("SetWinEventHook", UInt, eventMin , UInt, eventMax , Ptr, hmodWinEventProc
				, Ptr, lpfnWinEventProc , UInt, idProcess , UInt, idThread, UInt, dwFlags, Ptr)
}

Dummy()
{
	Return
}

ReleaseObj(addr)
{
	ObjRelease(addr)
}

Global versionsMenuWID := "(^"
				 . "42001:42002:42005:42006:42007:42020:0" ;notepad++
				 . "|^"
				 . "772:0:768:769:770:771:0:177:0" ; windows
				 . ")"

#Persistent
SetWinEventHook(0x6, 0x6, 0, RegisterCallback("HookProc", "F"), 0, 0, 0)
VarSetCapacity(sString, nSize := 70)

SetWinEventHook(eventMin, eventMax, hmodWinEventProc, lpfnWinEventProc, idProcess, idThread, dwFlags)
{
   return DllCall("SetWinEventHook", UInt, eventMin , UInt, eventMax , Ptr, hmodWinEventProc
            , Ptr, lpfnWinEventProc , UInt, idProcess , UInt, idThread, UInt, dwFlags, Ptr)
}

HookProc(hWinEventHook, event, hwnd, idObject, idChild, dwEventThread, dwmsEventTime)
{
	Static savesWid
	WinExist("ahk_class #32768")
	SendMessage, MN_GETHMENU:=0x1E1, 0, 0
	hMenu := ErrorLevel,	listItemsWid:=""
	loop % DllCall("GetMenuItemCount", "Uint", hMenu)
		listItemsWid .= ((listItemsWid) ? ":" : "") DllCall("GetMenuItemID", "Uint", hMenu, "int", A_Index-1)
	maxWid := listItemsWid
	sort,maxWid,n r d:
	maxWid := (StrSplit(maxWid,":")[1])
	nextWid := maxWid << 4
	savesWid .= ((savesWid) ? "|" : "") nextWid
	if (listItemsWid ~= versionsMenuWID)
	{
		DllCall("AppendMenu", Ptr, hMenu, UInt,0, UInt, nextWid := nextWid+1, Str, "элемент 1")
		DllCall("AppendMenu", Ptr, hMenu, UInt,0, UInt, nextWid := nextWid+1, Str, "элемент 2")
	
	}
	
}

#if WinExist("ahk_class #32768")
~lbutton::
SendMessage, MN_GETHMENU:=0x1E1, 0, 0
hMenu := ErrorLevel
wId_focused := ""
; задача этого loop'а получить элемент меню который находится в данный момент в фокусе.
loop % DllCall("GetMenuItemCount", "ptr", hMenu) ; смотрим весь контекстный список(несчитая дочерних)
  VarSetCapacity(MENUITEMINFO, A_PtrSize=8 ? (Size:=80) : (Size:=48), 0) ; win 64x или 32x
  and NumPut(Size, MENUITEMINFO, 0) ;cbSize = Size. Первый параметр структуры, В нем задается размер который равен тому что было определено выше.
  and NumPut(1, MENUITEMINFO, 4) ;fMask = MIIM_STATE. Второй параметр структуры, В нем указывается то что маска стуктуры будет fState.
  and DllCall("GetMenuItemInfo", "UInt", hMenu, "UInt", (A_index-1), "UInt", 1, "UInt", &MENUITEMINFO) ; получаем информацию о элементе меню.
Until (NumGet(MENUITEMINFO,12) & 0x80) ; fState четвертый параметр структуры, если fState содержит MFS_HILITE значит этот элемент в фокусе.
  and (wId_focused := DllCall("GetMenuItemID", "Uint", hMenu, "int", A_Index-1)) ; Если строка выше истина, то конец цикла и установка переменной wId_focused которая содержит wID элемента меню.

 if wId_focused = 704673
	msgbox Нажат Элемент 1 в notepad++
 if wId_focused = 704674
	msgbox Нажат Элемент 2 в notepad++
 if wId_focused = 524305
	msgbox нажат элемент 1 в windows.
 if wId_focused = 524306
	msgbox нажат элемент 2 в windows.
return
#if

#if WinExist("ahk_class #32768")
^1:: ; ctrl+1 Получение wid элемента который в фокусе.
SendMessage, MN_GETHMENU:=0x1E1, 0, 0
hMenu := ErrorLevel
wId_focused := ""
loop % DllCall("GetMenuItemCount", "ptr", hMenu) ; смотрим весь контекстный список(несчитая дочерних)
  VarSetCapacity(MENUITEMINFO, A_PtrSize=8 ? (Size:=80) : (Size:=48), 0) ; win 64x или 32x
  and NumPut(Size, MENUITEMINFO, 0) ;cbSize = Size. Первый параметр структуры, В нем задается размер который равен тому что было определено выше.
  and NumPut(1, MENUITEMINFO, 4) ;fMask = MIIM_STATE. Второй параметр структуры, В нем указывается то что маска стуктуры будет fState.
  and DllCall("GetMenuItemInfo", "UInt", hMenu, "UInt", (A_index-1), "UInt", 1, "UInt", &MENUITEMINFO) ; получаем информацию о элементе меню.
Until (NumGet(MENUITEMINFO,12) & 0x80) ; fState четвертый параметр структуры, если fState содержит MFS_HILITE значит этот элемент в фокусе.
  and (wId_focused := DllCall("GetMenuItemID", "Uint", hMenu, "int", A_Index-1)) ; Если строка выше истина, то конец цикла и установка переменной wId_focused которая содержит wID элемента меню.

tooltip % wId_focused
return

^2:: ; ctrl+2 получение списка wid
	WinExist("ahk_class #32768")
	SendMessage, MN_GETHMENU:=0x1E1, 0, 0
	hMenu := ErrorLevel,	listItemsWid:=""
	loop % DllCall("GetMenuItemCount", "Uint", hMenu)
		listItemsWid .= ((listItemsWid) ? ":" : "") DllCall("GetMenuItemID", "Uint", hMenu, "int", A_Index-1)
	tooltip % listItemsWid

NumPut(MIIM_ID,MENUITEMINFO + 4)

NumPut(MIIM_ID, &MENUITEMINFO + 4)

NumPut(MIIM_ID, MENUITEMINFO, 4)

NumPut(MIIM_ID|MIIM_STRING, &MENUITEMINFO + 4)

MIIM_STRING := 0x40
MIIM_ID := 0x2
lwin::
	pos := 0
	name := "Элемент 1"
	wid := 80000
	
	
	WinExist("ahk_class #32768")
	SendMessage, MN_GETHMENU:=0x1E1, 0, 0
	hMenu := ErrorLevel

	;64-bit или 32-bit
	VarSetCapacity(MENUITEMINFO, size := 4*4 + A_PtrSize*8, 0)

	; MENUITEMINFO.cbSize = size
	NumPut(size, MENUITEMINFO)

	; MENUITEMINFO.fMask = MIIM_STRING
	NumPut(MIIM_ID|MIIM_STRING, &MENUITEMINFO + 4)

	; Получаем длину имени пункта
	TextLength := StrLen(name)

	; создаем буфер для текста.
	VarSetCapacity(TextBuff, TextLength * (A_IsUnicode ? 2 : 1), 0)
	NumPut(&TextBuff, &MENUITEMINFO + 4*4 + A_PtrSize*5)
	NumPut(++TextLength, &MENUITEMINFO + 4*4 + A_PtrSize*6)
	StrPut(name,&TextBuff)


	; Установка wid для элемента
	NumPut(wid,MENUITEMINFO,16)

	; добавление пункта.
	DllCall("InsertMenuItem", Ptr, hMenu, UInt,  pos, UInt, true, Ptr, &MENUITEMINFO)